matita/matita/contribs/lambdadelta/basic_2/rt_transition/cpm_aaa.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/rt_transition/cpm_cpx.ma".
  16 include "basic_2/rt_transition/lpx_aaa.ma".
  17
  18 (* T-BOUND CONTEXT-SENSITIVE PARALLEL RT-TRANSITION FOR TERMS ***************)
  19
  20 (* Properties with atomic arity assignment for terms ************************)
  21
  22 (* Basic_2A1: includes: cpr_aaa_conf *)
  23 lemma cpm_aaa_conf (n) (h): ∀G,L. Conf3 … (aaa G L) (cpm h G L n).
  24 /3 width=5 by cpx_aaa_conf, cpm_fwd_cpx/ qed-.
  25
  26 (* Note: one of these U is the inferred type of T *)
  27 lemma aaa_cpm_SO (h) (G) (L) (A):
  28       ∀T. ❪G,L❫ ⊢ T ⁝ A → ∃U. ❪G,L❫ ⊢ T ➡[1,h] U.
  29 #h #G #L #A #T #H elim H -G -L -T -A
  30 [ /3 width=2 by ex_intro/
  31 | * #G #L #V #B #_ * #V0 #HV0
  32   [ elim (lifts_total V0 (𝐔❨1❩)) #W0 #HVW0
  33     /3 width=4 by cpm_delta, ex_intro/
  34   | elim (lifts_total V (𝐔❨1❩)) #W #HVW -V0
  35     /3 width=4 by cpm_ell, ex_intro/
  36   ]
  37 | #I #G #L #A #i #_ * #T0 #HT0
  38   elim (lifts_total T0 (𝐔❨1❩)) #U0 #HTU0
  39   /3 width=4 by cpm_lref, ex_intro/
  40 | #p #G #L #V #T #B #A #_ #_ #_ * #T0 #HT0
  41   /3 width=2 by cpm_bind, ex_intro/
  42 | #p #G #L #V #T #B #A #_ #_ #_  * #T0 #HT0
  43   /3 width=2 by cpm_bind, ex_intro/
  44 | #G #L #V #T #B #A #_ #_ #_ * #T0 #HT0
  45   /3 width=2 by cpm_appl, ex_intro/
  46 | #G #L #U #T #A #_ #_ * #U0 #HU0 * #T0 #HT0
  47   /3 width=2 by cpm_cast, ex_intro/
  48 ]
  49 qed-.