matita/matita/contribs/lambdadelta/basic_2/rt_transition/cpr.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/insert_eq/insert_eq_0.ma".
  16 include "basic_2/rt_transition/cpm.ma".
  17
  18 (* CONTEXT-SENSITIVE PARALLEL R-TRANSITION FOR TERMS ************************)
  19
  20 (* Basic properties *********************************************************)
  21
  22 (* Note: cpr_flat: does not hold in basic_1 *)
  23 (* Basic_1: includes: pr2_thin_dx *)
  24 lemma cpr_flat: ∀h,I,G,L,V1,V2,T1,T2.
  25                 ⦃G, L⦄ ⊢ V1 ➡[h] V2 → ⦃G, L⦄ ⊢ T1 ➡[h] T2 →
  26                 ⦃G, L⦄ ⊢ ⓕ{I}V1.T1 ➡[h] ⓕ{I}V2.T2.
  27 #h * /2 width=1 by cpm_cast, cpm_appl/
  28 qed.
  29
  30 (* Basic_1: was: pr2_head_1 *)
  31 lemma cpr_pair_sn: ∀h,I,G,L,V1,V2. ⦃G, L⦄ ⊢ V1 ➡[h] V2 →
  32                    ∀T. ⦃G, L⦄ ⊢ ②{I}V1.T ➡[h] ②{I}V2.T.
  33 #h * /2 width=1 by cpm_bind, cpr_flat/
  34 qed.
  35
  36 (* Basic inversion properties ***********************************************)
  37
  38 lemma cpr_inv_atom1: ∀h,J,G,L,T2. ⦃G, L⦄ ⊢ ⓪{J} ➡[h] T2 →
  39                      ∨∨ T2 = ⓪{J}
  40                       | ∃∃K,V1,V2. ⦃G, K⦄ ⊢ V1 ➡[h] V2 & ⬆*[1] V2 ≘ T2 &
  41                                    L = K.ⓓV1 & J = LRef 0
  42                       | ∃∃I,K,T,i. ⦃G, K⦄ ⊢ #i ➡[h] T & ⬆*[1] T ≘ T2 &
  43                                    L = K.ⓘ{I} & J = LRef (↑i).
  44 #h #J #G #L #T2 #H elim (cpm_inv_atom1 … H) -H *
  45 /3 width=8 by tri_lt, or3_intro0, or3_intro1, or3_intro2, ex4_4_intro, ex4_3_intro/
  46 #n #_ #_ #H destruct
  47 qed-.
  48
  49 (* Basic_1: includes: pr0_gen_sort pr2_gen_sort *)
  50 lemma cpr_inv_sort1: ∀h,G,L,T2,s. ⦃G, L⦄ ⊢ ⋆s ➡[h] T2 → T2 = ⋆s.
  51 #h #G #L #T2 #s #H elim (cpm_inv_sort1 … H) -H * // #_ #H destruct
  52 qed-.
  53
  54 lemma cpr_inv_zero1: ∀h,G,L,T2. ⦃G, L⦄ ⊢ #0 ➡[h] T2 →
  55                      ∨∨ T2 = #0
  56                       | ∃∃K,V1,V2. ⦃G, K⦄ ⊢ V1 ➡[h] V2 & ⬆*[1] V2 ≘ T2 &
  57                                    L = K.ⓓV1.
  58 #h #G #L #T2 #H elim (cpm_inv_zero1 … H) -H *
  59 /3 width=6 by ex3_3_intro, or_introl, or_intror/
  60 #n #K #V1 #V2 #_ #_ #_ #H destruct
  61 qed-.
  62
  63 lemma cpr_inv_lref1: ∀h,G,L,T2,i. ⦃G, L⦄ ⊢ #↑i ➡[h] T2 →
  64                      ∨∨ T2 = #(↑i)
  65                       | ∃∃I,K,T. ⦃G, K⦄ ⊢ #i ➡[h] T & ⬆*[1] T ≘ T2 & L = K.ⓘ{I}.
  66 #h #G #L #T2 #i #H elim (cpm_inv_lref1 … H) -H *
  67 /3 width=6 by ex3_3_intro, or_introl, or_intror/
  68 qed-.
  69
  70 lemma cpr_inv_gref1: ∀h,G,L,T2,l. ⦃G, L⦄ ⊢ §l ➡[h] T2 → T2 = §l.
  71 #h #G #L #T2 #l #H elim (cpm_inv_gref1 … H) -H //
  72 qed-.
  73
  74 (* Basic_1: includes: pr0_gen_cast pr2_gen_cast *)
  75 lemma cpr_inv_cast1: ∀h,G,L,V1,U1,U2. ⦃G, L⦄ ⊢ ⓝ V1.U1 ➡[h] U2 →
  76                      ∨∨ ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡[h] V2 & ⦃G, L⦄ ⊢ U1 ➡[h] T2 &
  77                                  U2 = ⓝV2.T2
  78                       | ⦃G, L⦄ ⊢ U1 ➡[h] U2.
  79 #h #G #L #V1 #U1 #U2 #H elim (cpm_inv_cast1 … H) -H
  80 /2 width=1 by or_introl, or_intror/ * #n #_ #H destruct
  81 qed-.
  82
  83 lemma cpr_inv_flat1: ∀h,I,G,L,V1,U1,U2. ⦃G, L⦄ ⊢ ⓕ{I}V1.U1 ➡[h] U2 →
  84                      ∨∨ ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡[h] V2 & ⦃G, L⦄ ⊢ U1 ➡[h] T2 &
  85                                  U2 = ⓕ{I}V2.T2
  86                       | (⦃G, L⦄ ⊢ U1 ➡[h] U2 ∧ I = Cast)
  87                       | ∃∃p,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡[h] V2 & ⦃G, L⦄ ⊢ W1 ➡[h] W2 &
  88                                             ⦃G, L.ⓛW1⦄ ⊢ T1 ➡[h] T2 & U1 = ⓛ{p}W1.T1 &
  89                                             U2 = ⓓ{p}ⓝW2.V2.T2 & I = Appl
  90                       | ∃∃p,V,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡[h] V & ⬆*[1] V ≘ V2 &
  91                                               ⦃G, L⦄ ⊢ W1 ➡[h] W2 & ⦃G, L.ⓓW1⦄ ⊢ T1 ➡[h] T2 &
  92                                               U1 = ⓓ{p}W1.T1 &
  93                                               U2 = ⓓ{p}W2.ⓐV2.T2 & I = Appl.
  94 #h * #G #L #V1 #U1 #U2 #H
  95 [ elim (cpm_inv_appl1 … H) -H *
  96   /3 width=13 by or4_intro0, or4_intro2, or4_intro3, ex7_7_intro, ex6_6_intro, ex3_2_intro/
  97 | elim (cpr_inv_cast1 … H) -H [ * ]
  98   /3 width=5 by or4_intro0, or4_intro1, ex3_2_intro, conj/
  99 ]
 100 qed-.
 101
 102 (* Basic eliminators ********************************************************)
 103
 104 lemma cpr_ind (h): ∀R:relation4 genv lenv term term.
 105                    (∀I,G,L. R G L (⓪{I}) (⓪{I})) →
 106                    (∀G,K,V1,V2,W2. ⦃G, K⦄ ⊢ V1 ➡[h] V2 → R G K V1 V2 →
 107                      ⬆*[1] V2 ≘ W2 → R G (K.ⓓV1) (#0) W2
 108                    ) → (∀I,G,K,T,U,i. ⦃G, K⦄ ⊢ #i ➡[h] T → R G K (#i) T →
 109                      ⬆*[1] T ≘ U → R G (K.ⓘ{I}) (#↑i) (U)
 110                    ) → (∀p,I,G,L,V1,V2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡[h] V2 → ⦃G, L.ⓑ{I}V1⦄ ⊢ T1 ➡[h] T2 →
 111                      R G L V1 V2 → R G (L.ⓑ{I}V1) T1 T2 → R G L (ⓑ{p,I}V1.T1) (ⓑ{p,I}V2.T2)
 112                    ) → (∀I,G,L,V1,V2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡[h] V2 → ⦃G, L⦄ ⊢ T1 ➡[h] T2 →
 113                      R G L V1 V2 → R G L T1 T2 → R G L (ⓕ{I}V1.T1) (ⓕ{I}V2.T2)
 114                    ) → (∀G,L,V,T1,T,T2. ⦃G, L.ⓓV⦄ ⊢ T1 ➡[h] T → R G (L.ⓓV) T1 T →
 115                      ⬆*[1] T2 ≘ T → R G L (+ⓓV.T1) T2
 116                    ) → (∀G,L,V,T1,T2. ⦃G, L⦄ ⊢ T1 ➡[h] T2 → R G L T1 T2 →
 117                      R G L (ⓝV.T1) T2
 118                    ) → (∀p,G,L,V1,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡[h] V2 → ⦃G, L⦄ ⊢ W1 ➡[h] W2 → ⦃G, L.ⓛW1⦄ ⊢ T1 ➡[h] T2 →
 119                      R G L V1 V2 → R G L W1 W2 → R G (L.ⓛW1) T1 T2 →
 120                      R G L (ⓐV1.ⓛ{p}W1.T1) (ⓓ{p}ⓝW2.V2.T2)
 121                    ) → (∀p,G,L,V1,V,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡[h] V → ⦃G, L⦄ ⊢ W1 ➡[h] W2 → ⦃G, L.ⓓW1⦄ ⊢ T1 ➡[h] T2 →
 122                      R G L V1 V → R G L W1 W2 → R G (L.ⓓW1) T1 T2 →
 123                      ⬆*[1] V ≘ V2 → R G L (ⓐV1.ⓓ{p}W1.T1) (ⓓ{p}W2.ⓐV2.T2)
 124                    ) →
 125                    ∀G,L,T1,T2. ⦃G, L⦄ ⊢ T1 ➡[h] T2 → R G L T1 T2.
 126 #h #R #IH1 #IH2 #IH3 #IH4 #IH5 #IH6 #IH7 #IH8 #IH9 #G #L #T1 #T2
 127 @(insert_eq_0 … 0) #n #H
 128 @(cpm_ind … H) -G -L -T1 -T2 -n /3 width=4 by/
 129 [ #G #L #s #H destruct
 130 | #n #G #K #V1 #V2 #W2 #_ #_ #_ #H destruct
 131 | #n #G #L #U1 #U2 #T #_ #_ #H destruct
 132 ]
 133 qed-.
 134
 135 (* Basic_1: removed theorems 12:
 136             pr0_subst0_back pr0_subst0_fwd pr0_subst0
 137             pr0_delta1
 138             pr2_head_2 pr2_cflat clear_pr2_trans
 139             pr2_gen_csort pr2_gen_cflat pr2_gen_cbind
 140             pr2_gen_ctail pr2_ctail
 141 *)