matita/matita/contribs/lambdadelta/basic_2/rt_transition/cpr.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/pred_4.ma".
  16 include "basic_2/static/lsubr.ma".
  17 include "basic_2/unfold/lstas.ma".
  18
  19 (* CONTEXT-SENSITIVE PARALLEL REDUCTION FOR TERMS ***************************)
  20
  21 (* activate genv *)
  22 (* Basic_1: includes: pr0_delta1 pr2_delta1 pr2_thin_dx *)
  23 (* Note: cpr_flat: does not hold in basic_1 *)
  24 inductive cpr: relation4 genv lenv term term ≝
  25 | cpr_atom : ∀I,G,L. cpr G L (⓪{I}) (⓪{I})
  26 | cpr_delta: ∀G,L,K,V,V2,W2,i.
  27              ⬇[i] L ≡ K. ⓓV → cpr G K V V2 →
  28              ⬆[0, i + 1] V2 ≡ W2 → cpr G L (#i) W2
  29 | cpr_bind : ∀a,I,G,L,V1,V2,T1,T2.
  30              cpr G L V1 V2 → cpr G (L.ⓑ{I}V1) T1 T2 →
  31              cpr G L (ⓑ{a,I}V1.T1) (ⓑ{a,I}V2.T2)
  32 | cpr_flat : ∀I,G,L,V1,V2,T1,T2.
  33              cpr G L V1 V2 → cpr G L T1 T2 →
  34              cpr G L (ⓕ{I}V1.T1) (ⓕ{I}V2.T2)
  35 | cpr_zeta : ∀G,L,V,T1,T,T2. cpr G (L.ⓓV) T1 T →
  36              ⬆[0, 1] T2 ≡ T → cpr G L (+ⓓV.T1) T2
  37 | cpr_eps  : ∀G,L,V,T1,T2. cpr G L T1 T2 → cpr G L (ⓝV.T1) T2
  38 | cpr_beta : ∀a,G,L,V1,V2,W1,W2,T1,T2.
  39              cpr G L V1 V2 → cpr G L W1 W2 → cpr G (L.ⓛW1) T1 T2 →
  40              cpr G L (ⓐV1.ⓛ{a}W1.T1) (ⓓ{a}ⓝW2.V2.T2)
  41 | cpr_theta: ∀a,G,L,V1,V,V2,W1,W2,T1,T2.
  42              cpr G L V1 V → ⬆[0, 1] V ≡ V2 → cpr G L W1 W2 → cpr G (L.ⓓW1) T1 T2 →
  43              cpr G L (ⓐV1.ⓓ{a}W1.T1) (ⓓ{a}W2.ⓐV2.T2)
  44 .
  45
  46 interpretation "context-sensitive parallel reduction (term)"
  47    'PRed G L T1 T2 = (cpr G L T1 T2).
  48
  49 (* Basic properties *********************************************************)
  50
  51 lemma cpr_cpx: ∀h,G,L,T1,T2. ⦃G, L⦄ ⊢ T1 ➡ T2 → ⦃G, L⦄ ⊢ T1 ➡[h] T2.
  52 #h #o #G #L #T1 #T2 #H elim H -L -T1 -T2
  53 /2 width=7 by cpx_delta, cpx_bind, cpx_flat, cpx_zeta, cpx_eps, cpx_beta, cpx_theta/
  54 qed.
  55
  56 lemma lsubr_cpr_trans: ∀G. lsub_trans … (cpr G) lsubr.
  57 #G #L1 #T1 #T2 #H elim H -G -L1 -T1 -T2
  58 [ //
  59 | #G #L1 #K1 #V1 #V2 #W2 #i #HLK1 #_ #HVW2 #IHV12 #L2 #HL12
  60   elim (lsubr_fwd_drop2_abbr … HL12 … HLK1) -L1 *
  61   /3 width=6 by cpr_delta/
  62 |3,7: /4 width=1 by lsubr_pair, cpr_bind, cpr_beta/
  63 |4,6: /3 width=1 by cpr_flat, cpr_eps/
  64 |5,8: /4 width=3 by lsubr_pair, cpr_zeta, cpr_theta/
  65 ]
  66 qed-.
  67
  68 (* Basic_1: was by definition: pr2_free *)
  69 lemma tpr_cpr: ∀G,T1,T2. ⦃G, ⋆⦄ ⊢ T1 ➡ T2 → ∀L. ⦃G, L⦄ ⊢ T1 ➡ T2.
  70 #G #T1 #T2 #HT12 #L
  71 lapply (lsubr_cpr_trans … HT12 L ?) //
  72 qed.
  73
  74 (* Basic_1: includes by definition: pr0_refl *)
  75 lemma cpr_refl: ∀G,T,L. ⦃G, L⦄ ⊢ T ➡ T.
  76 #G #T elim T -T // * /2 width=1 by cpr_bind, cpr_flat/
  77 qed.
  78
  79 (* Basic_1: was: pr2_head_1 *)
  80 lemma cpr_pair_sn: ∀I,G,L,V1,V2. ⦃G, L⦄ ⊢ V1 ➡ V2 →
  81                    ∀T. ⦃G, L⦄ ⊢ ②{I}V1.T ➡ ②{I}V2.T.
  82 * /2 width=1 by cpr_bind, cpr_flat/ qed.
  83
  84 lemma cpr_delift: ∀G,K,V,T1,L,l. ⬇[l] L ≡ (K.ⓓV) →
  85                   ∃∃T2,T. ⦃G, L⦄ ⊢ T1 ➡ T2 & ⬆[l, 1] T ≡ T2.
  86 #G #K #V #T1 elim T1 -T1
  87 [ * /2 width=4 by cpr_atom, lift_sort, lift_gref, ex2_2_intro/
  88   #i #L #l #HLK elim (lt_or_eq_or_gt i l)
  89   #Hil [1,3: /4 width=4 by lift_lref_ge_minus, lift_lref_lt, ylt_inj, yle_inj, ex2_2_intro/ ]
  90   destruct
  91   elim (lift_total V 0 (i+1)) #W #HVW
  92   elim (lift_split … HVW i i) /3 width=6 by cpr_delta, ex2_2_intro/
  93 | * [ #a ] #I #W1 #U1 #IHW1 #IHU1 #L #l #HLK
  94   elim (IHW1 … HLK) -IHW1 #W2 #W #HW12 #HW2
  95   [ elim (IHU1 (L. ⓑ{I}W1) (l+1)) -IHU1 /3 width=9 by drop_drop, cpr_bind, lift_bind, ex2_2_intro/
  96   | elim (IHU1 … HLK) -IHU1 -HLK /3 width=8 by cpr_flat, lift_flat, ex2_2_intro/
  97   ]
  98 ]
  99 qed-.
 100
 101 fact lstas_cpr_aux: ∀h,G,L,T1,T2,d. ⦃G, L⦄ ⊢ T1 •*[h, d] T2 →
 102                     d = 0 → ⦃G, L⦄ ⊢ T1 ➡ T2.
 103 #h #G #L #T1 #T2 #d #H elim H -G -L -T1 -T2 -d
 104 /3 width=1 by cpr_eps, cpr_flat, cpr_bind/
 105 [ #G #L #K #V1 #V2 #W2 #i #d #HLK #_ #HVW2 #IHV12 #H destruct
 106   /3 width=6 by cpr_delta/
 107 | #G #L #K #V1 #V2 #W2 #i #d #_ #_ #_ #_ <plus_n_Sm #H destruct
 108 ]
 109 qed-.
 110
 111 lemma lstas_cpr: ∀h,G,L,T1,T2. ⦃G, L⦄ ⊢ T1 •*[h, 0] T2 → ⦃G, L⦄ ⊢ T1 ➡ T2.
 112 /2 width=4 by lstas_cpr_aux/ qed.
 113
 114 (* Basic inversion lemmas ***************************************************)
 115
 116 fact cpr_inv_atom1_aux: ∀G,L,T1,T2. ⦃G, L⦄ ⊢ T1 ➡ T2 → ∀I. T1 = ⓪{I} →
 117                         T2 = ⓪{I} ∨
 118                         ∃∃K,V,V2,i. ⬇[i] L ≡ K. ⓓV & ⦃G, K⦄ ⊢ V ➡ V2 &
 119                                     ⬆[O, i + 1] V2 ≡ T2 & I = LRef i.
 120 #G #L #T1 #T2 * -G -L -T1 -T2
 121 [ #I #G #L #J #H destruct /2 width=1 by or_introl/
 122 | #L #G #K #V #V2 #T2 #i #HLK #HV2 #HVT2 #J #H destruct /3 width=8 by ex4_4_intro, or_intror/
 123 | #a #I #G #L #V1 #V2 #T1 #T2 #_ #_ #J #H destruct
 124 | #I #G #L #V1 #V2 #T1 #T2 #_ #_ #J #H destruct
 125 | #G #L #V #T1 #T #T2 #_ #_ #J #H destruct
 126 | #G #L #V #T1 #T2 #_ #J #H destruct
 127 | #a #G #L #V1 #V2 #W1 #W2 #T1 #T2 #_ #_ #_ #J #H destruct
 128 | #a #G #L #V1 #V #V2 #W1 #W2 #T1 #T2 #_ #_ #_ #_ #J #H destruct
 129 ]
 130 qed-.
 131
 132 lemma cpr_inv_atom1: ∀I,G,L,T2. ⦃G, L⦄ ⊢ ⓪{I} ➡ T2 →
 133                      T2 = ⓪{I} ∨
 134                      ∃∃K,V,V2,i. ⬇[i] L ≡ K. ⓓV & ⦃G, K⦄ ⊢ V ➡ V2 &
 135                                  ⬆[O, i + 1] V2 ≡ T2 & I = LRef i.
 136 /2 width=3 by cpr_inv_atom1_aux/ qed-.
 137
 138 (* Basic_1: includes: pr0_gen_sort pr2_gen_sort *)
 139 lemma cpr_inv_sort1: ∀G,L,T2,s. ⦃G, L⦄ ⊢ ⋆s ➡ T2 → T2 = ⋆s.
 140 #G #L #T2 #s #H
 141 elim (cpr_inv_atom1 … H) -H //
 142 * #K #V #V2 #i #_ #_ #_ #H destruct
 143 qed-.
 144
 145 (* Basic_1: includes: pr0_gen_lref pr2_gen_lref *)
 146 lemma cpr_inv_lref1: ∀G,L,T2,i. ⦃G, L⦄ ⊢ #i ➡ T2 →
 147                      T2 = #i ∨
 148                      ∃∃K,V,V2. ⬇[i] L ≡ K. ⓓV & ⦃G, K⦄ ⊢ V ➡ V2 &
 149                                ⬆[O, i + 1] V2 ≡ T2.
 150 #G #L #T2 #i #H
 151 elim (cpr_inv_atom1 … H) -H /2 width=1 by or_introl/
 152 * #K #V #V2 #j #HLK #HV2 #HVT2 #H destruct /3 width=6 by ex3_3_intro, or_intror/
 153 qed-.
 154
 155 lemma cpr_inv_gref1: ∀G,L,T2,p. ⦃G, L⦄ ⊢ §p ➡ T2 → T2 = §p.
 156 #G #L #T2 #p #H
 157 elim (cpr_inv_atom1 … H) -H //
 158 * #K #V #V2 #i #_ #_ #_ #H destruct
 159 qed-.
 160
 161 fact cpr_inv_bind1_aux: ∀G,L,U1,U2. ⦃G, L⦄ ⊢ U1 ➡ U2 →
 162                         ∀a,I,V1,T1. U1 = ⓑ{a,I}V1. T1 → (
 163                         ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡ V2 & ⦃G, L.ⓑ{I}V1⦄ ⊢ T1 ➡ T2 &
 164                                  U2 = ⓑ{a,I}V2.T2
 165                         ) ∨
 166                         ∃∃T. ⦃G, L.ⓓV1⦄ ⊢ T1 ➡ T & ⬆[0, 1] U2 ≡ T &
 167                              a = true & I = Abbr.
 168 #G #L #U1 #U2 * -L -U1 -U2
 169 [ #I #G #L #b #J #W1 #U1 #H destruct
 170 | #L #G #K #V #V2 #W2 #i #_ #_ #_ #b #J #W #U1 #H destruct
 171 | #a #I #G #L #V1 #V2 #T1 #T2 #HV12 #HT12 #b #J #W #U1 #H destruct /3 width=5 by ex3_2_intro, or_introl/
 172 | #I #G #L #V1 #V2 #T1 #T2 #_ #_ #b #J #W #U1 #H destruct
 173 | #G #L #V #T1 #T #T2 #HT1 #HT2 #b #J #W #U1 #H destruct /3 width=3 by ex4_intro, or_intror/
 174 | #G #L #V #T1 #T2 #_ #b #J #W #U1 #H destruct
 175 | #a #G #L #V1 #V2 #W1 #W2 #T1 #T2 #_ #_ #_ #b #J #W #U1 #H destruct
 176 | #a #G #L #V1 #V #V2 #W1 #W2 #T1 #T2 #_ #_ #_ #_ #b #J #W #U1 #H destruct
 177 ]
 178 qed-.
 179
 180 lemma cpr_inv_bind1: ∀a,I,G,L,V1,T1,U2. ⦃G, L⦄ ⊢ ⓑ{a,I}V1.T1 ➡ U2 → (
 181                      ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡ V2 & ⦃G, L.ⓑ{I}V1⦄ ⊢ T1 ➡ T2 &
 182                               U2 = ⓑ{a,I}V2.T2
 183                      ) ∨
 184                      ∃∃T. ⦃G, L.ⓓV1⦄ ⊢ T1 ➡ T & ⬆[0, 1] U2 ≡ T &
 185                           a = true & I = Abbr.
 186 /2 width=3 by cpr_inv_bind1_aux/ qed-.
 187
 188 (* Basic_1: includes: pr0_gen_abbr pr2_gen_abbr *)
 189 lemma cpr_inv_abbr1: ∀a,G,L,V1,T1,U2. ⦃G, L⦄ ⊢ ⓓ{a}V1.T1 ➡ U2 → (
 190                      ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡ V2 & ⦃G, L. ⓓV1⦄ ⊢ T1 ➡ T2 &
 191                               U2 = ⓓ{a}V2.T2
 192                      ) ∨
 193                      ∃∃T. ⦃G, L.ⓓV1⦄ ⊢ T1 ➡ T & ⬆[0, 1] U2 ≡ T & a = true.
 194 #a #G #L #V1 #T1 #U2 #H
 195 elim (cpr_inv_bind1 … H) -H *
 196 /3 width=5 by ex3_2_intro, ex3_intro, or_introl, or_intror/
 197 qed-.
 198
 199 (* Basic_1: includes: pr0_gen_abst pr2_gen_abst *)
 200 lemma cpr_inv_abst1: ∀a,G,L,V1,T1,U2. ⦃G, L⦄ ⊢ ⓛ{a}V1.T1 ➡ U2 →
 201                      ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡ V2 & ⦃G, L.ⓛV1⦄ ⊢ T1 ➡ T2 &
 202                               U2 = ⓛ{a}V2.T2.
 203 #a #G #L #V1 #T1 #U2 #H
 204 elim (cpr_inv_bind1 … H) -H *
 205 [ /3 width=5 by ex3_2_intro/
 206 | #T #_ #_ #_ #H destruct
 207 ]
 208 qed-.
 209
 210 fact cpr_inv_flat1_aux: ∀G,L,U,U2. ⦃G, L⦄ ⊢ U ➡ U2 →
 211                         ∀I,V1,U1. U = ⓕ{I}V1.U1 →
 212                         ∨∨ ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡ V2 & ⦃G, L⦄ ⊢ U1 ➡ T2 &
 213                                     U2 = ⓕ{I} V2. T2
 214                          | (⦃G, L⦄ ⊢ U1 ➡ U2 ∧ I = Cast)
 215                          | ∃∃a,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡ V2 & ⦃G, L⦄ ⊢ W1 ➡ W2 &
 216                                                ⦃G, L.ⓛW1⦄ ⊢ T1 ➡ T2 & U1 = ⓛ{a}W1.T1 &
 217                                                U2 = ⓓ{a}ⓝW2.V2.T2 & I = Appl
 218                          | ∃∃a,V,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡ V & ⬆[0,1] V ≡ V2 &
 219                                                  ⦃G, L⦄ ⊢ W1 ➡ W2 & ⦃G, L.ⓓW1⦄ ⊢ T1 ➡ T2 &
 220                                                  U1 = ⓓ{a}W1.T1 &
 221                                                  U2 = ⓓ{a}W2.ⓐV2.T2 & I = Appl.
 222 #G #L #U #U2 * -L -U -U2
 223 [ #I #G #L #J #W1 #U1 #H destruct
 224 | #G #L #K #V #V2 #W2 #i #_ #_ #_ #J #W #U1 #H destruct
 225 | #a #I #G #L #V1 #V2 #T1 #T2 #_ #_ #J #W #U1 #H destruct
 226 | #I #G #L #V1 #V2 #T1 #T2 #HV12 #HT12 #J #W #U1 #H destruct /3 width=5 by or4_intro0, ex3_2_intro/
 227 | #G #L #V #T1 #T #T2 #_ #_ #J #W #U1 #H destruct
 228 | #G #L #V #T1 #T2 #HT12 #J #W #U1 #H destruct /3 width=1 by or4_intro1, conj/
 229 | #a #G #L #V1 #V2 #W1 #W2 #T1 #T2 #HV12 #HW12 #HT12 #J #W #U1 #H destruct /3 width=11 by or4_intro2, ex6_6_intro/
 230 | #a #G #L #V1 #V #V2 #W1 #W2 #T1 #T2 #HV1 #HV2 #HW12 #HT12 #J #W #U1 #H destruct /3 width=13 by or4_intro3, ex7_7_intro/
 231 ]
 232 qed-.
 233
 234 lemma cpr_inv_flat1: ∀I,G,L,V1,U1,U2. ⦃G, L⦄ ⊢ ⓕ{I}V1.U1 ➡ U2 →
 235                      ∨∨ ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡ V2 & ⦃G, L⦄ ⊢ U1 ➡ T2 &
 236                                  U2 = ⓕ{I}V2.T2
 237                       | (⦃G, L⦄ ⊢ U1 ➡ U2 ∧ I = Cast)
 238                       | ∃∃a,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡ V2 & ⦃G, L⦄ ⊢ W1 ➡ W2 &
 239                                             ⦃G, L.ⓛW1⦄ ⊢ T1 ➡ T2 & U1 = ⓛ{a}W1.T1 &
 240                                             U2 = ⓓ{a}ⓝW2.V2.T2 & I = Appl
 241                       | ∃∃a,V,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡ V & ⬆[0,1] V ≡ V2 &
 242                                               ⦃G, L⦄ ⊢ W1 ➡ W2 & ⦃G, L.ⓓW1⦄ ⊢ T1 ➡ T2 &
 243                                               U1 = ⓓ{a}W1.T1 &
 244                                               U2 = ⓓ{a}W2.ⓐV2.T2 & I = Appl.
 245 /2 width=3 by cpr_inv_flat1_aux/ qed-.
 246
 247 (* Basic_1: includes: pr0_gen_appl pr2_gen_appl *)
 248 lemma cpr_inv_appl1: ∀G,L,V1,U1,U2. ⦃G, L⦄ ⊢ ⓐV1.U1 ➡ U2 →
 249                      ∨∨ ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡ V2 & ⦃G, L⦄ ⊢ U1 ➡ T2 &
 250                                  U2 = ⓐV2.T2
 251                       | ∃∃a,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡ V2 & ⦃G, L⦄ ⊢ W1 ➡ W2 &
 252                                             ⦃G, L.ⓛW1⦄ ⊢ T1 ➡ T2 &
 253                                             U1 = ⓛ{a}W1.T1 & U2 = ⓓ{a}ⓝW2.V2.T2
 254                       | ∃∃a,V,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡ V & ⬆[0,1] V ≡ V2 &
 255                                               ⦃G, L⦄ ⊢ W1 ➡ W2 & ⦃G, L.ⓓW1⦄ ⊢ T1 ➡ T2 &
 256                                               U1 = ⓓ{a}W1.T1 & U2 = ⓓ{a}W2.ⓐV2.T2.
 257 #G #L #V1 #U1 #U2 #H elim (cpr_inv_flat1 … H) -H *
 258 [ /3 width=5 by or3_intro0, ex3_2_intro/
 259 | #_ #H destruct
 260 | /3 width=11 by or3_intro1, ex5_6_intro/
 261 | /3 width=13 by or3_intro2, ex6_7_intro/
 262 ]
 263 qed-.
 264
 265 (* Note: the main property of simple terms *)
 266 lemma cpr_inv_appl1_simple: ∀G,L,V1,T1,U. ⦃G, L⦄ ⊢ ⓐV1. T1 ➡ U → 𝐒⦃T1⦄ →
 267                             ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡ V2 & ⦃G, L⦄ ⊢ T1 ➡ T2 &
 268                                      U = ⓐV2. T2.
 269 #G #L #V1 #T1 #U #H #HT1
 270 elim (cpr_inv_appl1 … H) -H *
 271 [ /2 width=5 by ex3_2_intro/
 272 | #a #V2 #W1 #W2 #U1 #U2 #_ #_ #_ #H #_ destruct
 273   elim (simple_inv_bind … HT1)
 274 | #a #V #V2 #W1 #W2 #U1 #U2 #_ #_ #_ #_ #H #_ destruct
 275   elim (simple_inv_bind … HT1)
 276 ]
 277 qed-.
 278
 279 (* Basic_1: includes: pr0_gen_cast pr2_gen_cast *)
 280 lemma cpr_inv_cast1: ∀G,L,V1,U1,U2. ⦃G, L⦄ ⊢ ⓝ V1. U1 ➡ U2 → (
 281                      ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡ V2 & ⦃G, L⦄ ⊢ U1 ➡ T2 &
 282                               U2 = ⓝ V2. T2
 283                      ) ∨ ⦃G, L⦄ ⊢ U1 ➡ U2.
 284 #G #L #V1 #U1 #U2 #H elim (cpr_inv_flat1 … H) -H *
 285 [ /3 width=5 by ex3_2_intro, or_introl/
 286 | /2 width=1 by or_intror/
 287 | #a #V2 #W1 #W2 #T1 #T2 #_ #_ #_ #_ #_ #H destruct
 288 | #a #V #V2 #W1 #W2 #T1 #T2 #_ #_ #_ #_ #_ #_ #H destruct
 289 ]
 290 qed-.
 291
 292 (* Basic forward lemmas *****************************************************)
 293
 294 lemma cpr_fwd_bind1_minus: ∀I,G,L,V1,T1,T. ⦃G, L⦄ ⊢ -ⓑ{I}V1.T1 ➡ T → ∀b.
 295                            ∃∃V2,T2. ⦃G, L⦄ ⊢ ⓑ{b,I}V1.T1 ➡ ⓑ{b,I}V2.T2 &
 296                                     T = -ⓑ{I}V2.T2.
 297 #I #G #L #V1 #T1 #T #H #b
 298 elim (cpr_inv_bind1 … H) -H *
 299 [ #V2 #T2 #HV12 #HT12 #H destruct /3 width=4 by cpr_bind, ex2_2_intro/
 300 | #T2 #_ #_ #H destruct
 301 ]
 302 qed-.
 303
 304 (* Basic_1: removed theorems 11:
 305             pr0_subst0_back pr0_subst0_fwd pr0_subst0
 306             pr2_head_2 pr2_cflat clear_pr2_trans
 307             pr2_gen_csort pr2_gen_cflat pr2_gen_cbind
 308             pr2_gen_ctail pr2_ctail
 309 *)
 310 (* Basic_1: removed local theorems 4:
 311             pr0_delta_eps pr0_cong_delta
 312             pr2_free_free pr2_free_delta
 313 *)