matita/matita/contribs/lambdadelta/basic_2/rt_transition/cpx.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/predty_5.ma".
  16 include "basic_2/rt_transition/cpg.ma".
  17
  18 (* UNBOUND CONTEXT-SENSITIVE PARALLEL RT-TRANSITION FOR TERMS ***************)
  19
  20 definition cpx (h): relation4 genv lenv term term ≝
  21                     λG,L,T1,T2. ∃c. ⦃G, L⦄ ⊢ T1 ⬈[eq_f, c, h] T2.
  22
  23 interpretation
  24    "unbound context-sensitive parallel rt-transition (term)"
  25    'PRedTy h G L T1 T2 = (cpx h G L T1 T2).
  26
  27 (* Basic properties *********************************************************)
  28
  29 (* Basic_2A1: was: cpx_st *)
  30 lemma cpx_ess: ∀h,G,L,s. ⦃G, L⦄ ⊢ ⋆s ⬈[h] ⋆(next h s).
  31 /2 width=2 by cpg_ess, ex_intro/ qed.
  32
  33 lemma cpx_delta: ∀h,I,G,K,V1,V2,W2. ⦃G, K⦄ ⊢ V1 ⬈[h] V2 →
  34                  ⬆*[1] V2 ≘ W2 → ⦃G, K.ⓑ{I}V1⦄ ⊢ #0 ⬈[h] W2.
  35 #h * #G #K #V1 #V2 #W2 *
  36 /3 width=4 by cpg_delta, cpg_ell, ex_intro/
  37 qed.
  38
  39 lemma cpx_lref: ∀h,I,G,K,T,U,i. ⦃G, K⦄ ⊢ #i ⬈[h] T →
  40                 ⬆*[1] T ≘ U → ⦃G, K.ⓘ{I}⦄ ⊢ #↑i ⬈[h] U.
  41 #h #I #G #K #T #U #i *
  42 /3 width=4 by cpg_lref, ex_intro/
  43 qed.
  44
  45 lemma cpx_bind: ∀h,p,I,G,L,V1,V2,T1,T2.
  46                 ⦃G, L⦄ ⊢ V1 ⬈[h] V2 → ⦃G, L.ⓑ{I}V1⦄ ⊢ T1 ⬈[h] T2 →
  47                 ⦃G, L⦄ ⊢ ⓑ{p,I}V1.T1 ⬈[h] ⓑ{p,I}V2.T2.
  48 #h #p #I #G #L #V1 #V2 #T1 #T2 * #cV #HV12 *
  49 /3 width=2 by cpg_bind, ex_intro/
  50 qed.
  51
  52 lemma cpx_flat: ∀h,I,G,L,V1,V2,T1,T2.
  53                 ⦃G, L⦄ ⊢ V1 ⬈[h] V2 → ⦃G, L⦄ ⊢ T1 ⬈[h] T2 →
  54                 ⦃G, L⦄ ⊢ ⓕ{I}V1.T1 ⬈[h] ⓕ{I}V2.T2.
  55 #h * #G #L #V1 #V2 #T1 #T2 * #cV #HV12 *
  56 /3 width=5 by cpg_appl, cpg_cast, ex_intro/
  57 qed.
  58
  59 lemma cpx_zeta: ∀h,G,L,V,T1,T,T2. ⦃G, L.ⓓV⦄ ⊢ T1 ⬈[h] T →
  60                 ⬆*[1] T2 ≘ T → ⦃G, L⦄ ⊢ +ⓓV.T1 ⬈[h] T2.
  61 #h #G #L #V #T1 #T #T2 *
  62 /3 width=4 by cpg_zeta, ex_intro/
  63 qed.
  64
  65 lemma cpx_eps: ∀h,G,L,V,T1,T2. ⦃G, L⦄ ⊢ T1 ⬈[h] T2 → ⦃G, L⦄ ⊢ ⓝV.T1 ⬈[h] T2.
  66 #h #G #L #V #T1 #T2 *
  67 /3 width=2 by cpg_eps, ex_intro/
  68 qed.
  69
  70 (* Basic_2A1: was: cpx_ct *)
  71 lemma cpx_ee: ∀h,G,L,V1,V2,T. ⦃G, L⦄ ⊢ V1 ⬈[h] V2 → ⦃G, L⦄ ⊢ ⓝV1.T ⬈[h] V2.
  72 #h #G #L #V1 #V2 #T *
  73 /3 width=2 by cpg_ee, ex_intro/
  74 qed.
  75
  76 lemma cpx_beta: ∀h,p,G,L,V1,V2,W1,W2,T1,T2.
  77                 ⦃G, L⦄ ⊢ V1 ⬈[h] V2 → ⦃G, L⦄ ⊢ W1 ⬈[h] W2 → ⦃G, L.ⓛW1⦄ ⊢ T1 ⬈[h] T2 →
  78                 ⦃G, L⦄ ⊢ ⓐV1.ⓛ{p}W1.T1 ⬈[h] ⓓ{p}ⓝW2.V2.T2.
  79 #h #p #G #L #V1 #V2 #W1 #W2 #T1 #T2 * #cV #HV12 * #cW #HW12 *
  80 /3 width=2 by cpg_beta, ex_intro/
  81 qed.
  82
  83 lemma cpx_theta: ∀h,p,G,L,V1,V,V2,W1,W2,T1,T2.
  84                  ⦃G, L⦄ ⊢ V1 ⬈[h] V → ⬆*[1] V ≘ V2 → ⦃G, L⦄ ⊢ W1 ⬈[h] W2 →
  85                  ⦃G, L.ⓓW1⦄ ⊢ T1 ⬈[h] T2 →
  86                  ⦃G, L⦄ ⊢ ⓐV1.ⓓ{p}W1.T1 ⬈[h] ⓓ{p}W2.ⓐV2.T2.
  87 #h #p #G #L #V1 #V #V2 #W1 #W2 #T1 #T2 * #cV #HV1 #HV2 * #cW #HW12 *
  88 /3 width=4 by cpg_theta, ex_intro/
  89 qed.
  90
  91 (* Basic_2A1: includes: cpx_atom *)
  92 lemma cpx_refl: ∀h,G,L. reflexive … (cpx h G L).
  93 /3 width=2 by cpg_refl, ex_intro/ qed.
  94
  95 (* Advanced properties ******************************************************)
  96
  97 lemma cpx_pair_sn: ∀h,I,G,L,V1,V2. ⦃G, L⦄ ⊢ V1 ⬈[h] V2 →
  98                    ∀T. ⦃G, L⦄ ⊢ ②{I}V1.T ⬈[h] ②{I}V2.T.
  99 #h * /2 width=2 by cpx_flat, cpx_bind/
 100 qed.
 101
 102 (* Basic inversion lemmas ***************************************************)
 103
 104 lemma cpx_inv_atom1: ∀h,J,G,L,T2. ⦃G, L⦄ ⊢ ⓪{J} ⬈[h] T2 →
 105                      ∨∨ T2 = ⓪{J}
 106                       | ∃∃s. T2 = ⋆(next h s) & J = Sort s
 107                       | ∃∃I,K,V1,V2. ⦃G, K⦄ ⊢ V1 ⬈[h] V2 & ⬆*[1] V2 ≘ T2 &
 108                                      L = K.ⓑ{I}V1 & J = LRef 0
 109                       | ∃∃I,K,T,i. ⦃G, K⦄ ⊢ #i ⬈[h] T & ⬆*[1] T ≘ T2 &
 110                                    L = K.ⓘ{I} & J = LRef (↑i).
 111 #h #J #G #L #T2 * #c #H elim (cpg_inv_atom1 … H) -H *
 112 /4 width=8 by or4_intro0, or4_intro1, or4_intro2, or4_intro3, ex4_4_intro, ex2_intro, ex_intro/
 113 qed-.
 114
 115 lemma cpx_inv_sort1: ∀h,G,L,T2,s. ⦃G, L⦄ ⊢ ⋆s ⬈[h] T2 →
 116                      ∨∨ T2 = ⋆s | T2 = ⋆(next h s).
 117 #h #G #L #T2 #s * #c #H elim (cpg_inv_sort1 … H) -H *
 118 /2 width=1 by or_introl, or_intror/
 119 qed-.
 120
 121 lemma cpx_inv_zero1: ∀h,G,L,T2. ⦃G, L⦄ ⊢ #0 ⬈[h] T2 →
 122                      ∨∨ T2 = #0
 123                       | ∃∃I,K,V1,V2. ⦃G, K⦄ ⊢ V1 ⬈[h] V2 & ⬆*[1] V2 ≘ T2 &
 124                                      L = K.ⓑ{I}V1.
 125 #h #G #L #T2 * #c #H elim (cpg_inv_zero1 … H) -H *
 126 /4 width=7 by ex3_4_intro, ex_intro, or_introl, or_intror/
 127 qed-.
 128
 129 lemma cpx_inv_lref1: ∀h,G,L,T2,i. ⦃G, L⦄ ⊢ #↑i ⬈[h] T2 →
 130                      ∨∨ T2 = #(↑i)
 131                       | ∃∃I,K,T. ⦃G, K⦄ ⊢ #i ⬈[h] T & ⬆*[1] T ≘ T2 & L = K.ⓘ{I}.
 132 #h #G #L #T2 #i * #c #H elim (cpg_inv_lref1 … H) -H *
 133 /4 width=6 by ex3_3_intro, ex_intro, or_introl, or_intror/
 134 qed-.
 135
 136 lemma cpx_inv_gref1: ∀h,G,L,T2,l. ⦃G, L⦄ ⊢ §l ⬈[h] T2 → T2 = §l.
 137 #h #G #L #T2 #l * #c #H elim (cpg_inv_gref1 … H) -H //
 138 qed-.
 139
 140 lemma cpx_inv_bind1: ∀h,p,I,G,L,V1,T1,U2. ⦃G, L⦄ ⊢ ⓑ{p,I}V1.T1 ⬈[h] U2 →
 141                      ∨∨ ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ⬈[h] V2 & ⦃G, L.ⓑ{I}V1⦄ ⊢ T1 ⬈[h] T2 &
 142                                  U2 = ⓑ{p,I}V2.T2
 143                       | ∃∃T. ⦃G, L.ⓓV1⦄ ⊢ T1 ⬈[h] T & ⬆*[1] U2 ≘ T &
 144                              p = true & I = Abbr.
 145 #h #p #I #G #L #V1 #T1 #U2 * #c #H elim (cpg_inv_bind1 … H) -H *
 146 /4 width=5 by ex4_intro, ex3_2_intro, ex_intro, or_introl, or_intror/
 147 qed-.
 148
 149 lemma cpx_inv_abbr1: ∀h,p,G,L,V1,T1,U2. ⦃G, L⦄ ⊢ ⓓ{p}V1.T1 ⬈[h] U2 →
 150                      ∨∨ ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ⬈[h] V2 & ⦃G, L.ⓓV1⦄ ⊢ T1 ⬈[h] T2 &
 151                                  U2 = ⓓ{p}V2.T2
 152                       | ∃∃T. ⦃G, L.ⓓV1⦄ ⊢ T1 ⬈[h] T & ⬆*[1] U2 ≘ T & p = true.
 153 #h #p #G #L #V1 #T1 #U2 * #c #H elim (cpg_inv_abbr1 … H) -H *
 154 /4 width=5 by ex3_2_intro, ex3_intro, ex_intro, or_introl, or_intror/
 155 qed-.
 156
 157 lemma cpx_inv_abst1: ∀h,p,G,L,V1,T1,U2. ⦃G, L⦄ ⊢ ⓛ{p}V1.T1 ⬈[h] U2 →
 158                      ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ⬈[h] V2 & ⦃G, L.ⓛV1⦄ ⊢ T1 ⬈[h] T2 &
 159                               U2 = ⓛ{p}V2.T2.
 160 #h #p #G #L #V1 #T1 #U2 * #c #H elim (cpg_inv_abst1 … H) -H
 161 /3 width=5 by ex3_2_intro, ex_intro/
 162 qed-.
 163
 164 lemma cpx_inv_appl1: ∀h,G,L,V1,U1,U2. ⦃G, L⦄ ⊢ ⓐ V1.U1 ⬈[h] U2 →
 165                      ∨∨ ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ⬈[h] V2 & ⦃G, L⦄ ⊢ U1 ⬈[h] T2 &
 166                                  U2 = ⓐV2.T2
 167                       | ∃∃p,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ⬈[h] V2 & ⦃G, L⦄ ⊢ W1 ⬈[h] W2 &
 168                                             ⦃G, L.ⓛW1⦄ ⊢ T1 ⬈[h] T2 &
 169                                             U1 = ⓛ{p}W1.T1 & U2 = ⓓ{p}ⓝW2.V2.T2
 170                       | ∃∃p,V,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ⬈[h] V & ⬆*[1] V ≘ V2 &
 171                                               ⦃G, L⦄ ⊢ W1 ⬈[h] W2 & ⦃G, L.ⓓW1⦄ ⊢ T1 ⬈[h] T2 &
 172                                               U1 = ⓓ{p}W1.T1 & U2 = ⓓ{p}W2.ⓐV2.T2.
 173 #h #G #L #V1 #U1 #U2 * #c #H elim (cpg_inv_appl1 … H) -H *
 174 /4 width=13 by or3_intro0, or3_intro1, or3_intro2, ex6_7_intro, ex5_6_intro, ex3_2_intro, ex_intro/
 175 qed-.
 176
 177 lemma cpx_inv_cast1: ∀h,G,L,V1,U1,U2. ⦃G, L⦄ ⊢ ⓝV1.U1 ⬈[h] U2 →
 178                      ∨∨ ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ⬈[h] V2 & ⦃G, L⦄ ⊢ U1 ⬈[h] T2 &
 179                                  U2 = ⓝV2.T2
 180                       | ⦃G, L⦄ ⊢ U1 ⬈[h] U2
 181                       | ⦃G, L⦄ ⊢ V1 ⬈[h] U2.
 182 #h #G #L #V1 #U1 #U2 * #c #H elim (cpg_inv_cast1 … H) -H *
 183 /4 width=5 by or3_intro0, or3_intro1, or3_intro2, ex3_2_intro, ex_intro/
 184 qed-.
 185
 186 (* Advanced inversion lemmas ************************************************)
 187
 188 lemma cpx_inv_zero1_pair: ∀h,I,G,K,V1,T2. ⦃G, K.ⓑ{I}V1⦄ ⊢ #0 ⬈[h] T2 →
 189                           ∨∨ T2 = #0
 190                            | ∃∃V2. ⦃G, K⦄ ⊢ V1 ⬈[h] V2 & ⬆*[1] V2 ≘ T2.
 191 #h #I #G #L #V1 #T2 * #c #H elim (cpg_inv_zero1_pair … H) -H *
 192 /4 width=3 by ex2_intro, ex_intro, or_intror, or_introl/
 193 qed-.
 194
 195 lemma cpx_inv_lref1_bind: ∀h,I,G,K,T2,i. ⦃G, K.ⓘ{I}⦄ ⊢ #↑i ⬈[h] T2 →
 196                           ∨∨ T2 = #(↑i)
 197                            | ∃∃T. ⦃G, K⦄ ⊢ #i ⬈[h] T & ⬆*[1] T ≘ T2.
 198 #h #I #G #L #T2 #i * #c #H elim (cpg_inv_lref1_bind … H) -H *
 199 /4 width=3 by ex2_intro, ex_intro, or_introl, or_intror/
 200 qed-.
 201
 202 lemma cpx_inv_flat1: ∀h,I,G,L,V1,U1,U2. ⦃G, L⦄ ⊢ ⓕ{I}V1.U1 ⬈[h] U2 →
 203                      ∨∨ ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ⬈[h] V2 & ⦃G, L⦄ ⊢ U1 ⬈[h] T2 &
 204                                  U2 = ⓕ{I}V2.T2
 205                       | (⦃G, L⦄ ⊢ U1 ⬈[h] U2 ∧ I = Cast)
 206                       | (⦃G, L⦄ ⊢ V1 ⬈[h] U2 ∧ I = Cast)
 207                       | ∃∃p,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ⬈[h] V2 & ⦃G, L⦄ ⊢ W1 ⬈[h] W2 &
 208                                             ⦃G, L.ⓛW1⦄ ⊢ T1 ⬈[h] T2 &
 209                                             U1 = ⓛ{p}W1.T1 &
 210                                             U2 = ⓓ{p}ⓝW2.V2.T2 & I = Appl
 211                       | ∃∃p,V,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ⬈[h] V & ⬆*[1] V ≘ V2 &
 212                                               ⦃G, L⦄ ⊢ W1 ⬈[h] W2 & ⦃G, L.ⓓW1⦄ ⊢ T1 ⬈[h] T2 &
 213                                               U1 = ⓓ{p}W1.T1 &
 214                                               U2 = ⓓ{p}W2.ⓐV2.T2 & I = Appl.
 215 #h * #G #L #V1 #U1 #U2 #H
 216 [ elim (cpx_inv_appl1 … H) -H *
 217   /3 width=14 by or5_intro0, or5_intro3, or5_intro4, ex7_7_intro, ex6_6_intro, ex3_2_intro/
 218 | elim (cpx_inv_cast1 … H) -H [ * ]
 219   /3 width=14 by or5_intro0, or5_intro1, or5_intro2, ex3_2_intro, conj/
 220 ]
 221 qed-.
 222
 223 (* Basic forward lemmas *****************************************************)
 224
 225 lemma cpx_fwd_bind1_minus: ∀h,I,G,L,V1,T1,T. ⦃G, L⦄ ⊢ -ⓑ{I}V1.T1 ⬈[h] T → ∀p.
 226                            ∃∃V2,T2. ⦃G, L⦄ ⊢ ⓑ{p,I}V1.T1 ⬈[h] ⓑ{p,I}V2.T2 &
 227                                     T = -ⓑ{I}V2.T2.
 228 #h #I #G #L #V1 #T1 #T * #c #H #p elim (cpg_fwd_bind1_minus … H p) -H
 229 /3 width=4 by ex2_2_intro, ex_intro/
 230 qed-.
 231
 232 (* Basic eliminators ********************************************************)
 233
 234 lemma cpx_ind: ∀h. ∀Q:relation4 genv lenv term term.
 235                (∀I,G,L. Q G L (⓪{I}) (⓪{I})) →
 236                (∀G,L,s. Q G L (⋆s) (⋆(next h s))) →
 237                (∀I,G,K,V1,V2,W2. ⦃G, K⦄ ⊢ V1 ⬈[h] V2 → Q G K V1 V2 →
 238                  ⬆*[1] V2 ≘ W2 → Q G (K.ⓑ{I}V1) (#0) W2
 239                ) → (∀I,G,K,T,U,i. ⦃G, K⦄ ⊢ #i ⬈[h] T → Q G K (#i) T →
 240                  ⬆*[1] T ≘ U → Q G (K.ⓘ{I}) (#↑i) (U)
 241                ) → (∀p,I,G,L,V1,V2,T1,T2. ⦃G, L⦄ ⊢ V1 ⬈[h] V2 → ⦃G, L.ⓑ{I}V1⦄ ⊢ T1 ⬈[h] T2 →
 242                   Q G L V1 V2 → Q G (L.ⓑ{I}V1) T1 T2 → Q G L (ⓑ{p,I}V1.T1) (ⓑ{p,I}V2.T2)
 243                ) → (∀I,G,L,V1,V2,T1,T2. ⦃G, L⦄ ⊢ V1 ⬈[h] V2 → ⦃G, L⦄ ⊢ T1 ⬈[h] T2 →
 244                   Q G L V1 V2 → Q G L T1 T2 → Q G L (ⓕ{I}V1.T1) (ⓕ{I}V2.T2)
 245                ) → (∀G,L,V,T1,T,T2. ⦃G, L.ⓓV⦄ ⊢ T1 ⬈[h] T → Q G (L.ⓓV) T1 T →
 246                   ⬆*[1] T2 ≘ T → Q G L (+ⓓV.T1) T2
 247                ) → (∀G,L,V,T1,T2. ⦃G, L⦄ ⊢ T1 ⬈[h] T2 → Q G L T1 T2 →
 248                   Q G L (ⓝV.T1) T2
 249                ) → (∀G,L,V1,V2,T. ⦃G, L⦄ ⊢ V1 ⬈[h] V2 → Q G L V1 V2 →
 250                   Q G L (ⓝV1.T) V2
 251                ) → (∀p,G,L,V1,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ⬈[h] V2 → ⦃G, L⦄ ⊢ W1 ⬈[h] W2 → ⦃G, L.ⓛW1⦄ ⊢ T1 ⬈[h] T2 →
 252                   Q G L V1 V2 → Q G L W1 W2 → Q G (L.ⓛW1) T1 T2 →
 253                   Q G L (ⓐV1.ⓛ{p}W1.T1) (ⓓ{p}ⓝW2.V2.T2)
 254                ) → (∀p,G,L,V1,V,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ⬈[h] V → ⦃G, L⦄ ⊢ W1 ⬈[h] W2 → ⦃G, L.ⓓW1⦄ ⊢ T1 ⬈[h] T2 →
 255                   Q G L V1 V → Q G L W1 W2 → Q G (L.ⓓW1) T1 T2 →
 256                   ⬆*[1] V ≘ V2 → Q G L (ⓐV1.ⓓ{p}W1.T1) (ⓓ{p}W2.ⓐV2.T2)
 257                ) →
 258                ∀G,L,T1,T2. ⦃G, L⦄ ⊢ T1 ⬈[h] T2 → Q G L T1 T2.
 259 #h #Q #IH1 #IH2 #IH3 #IH4 #IH5 #IH6 #IH7 #IH8 #IH9 #IH10 #IH11 #G #L #T1 #T2
 260 * #c #H elim H -c -G -L -T1 -T2 /3 width=4 by ex_intro/
 261 qed-.