matita/matita/contribs/lambdadelta/basic_2/rt_transition/cpx.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/predty_5.ma".
  16 include "basic_2/rt_transition/cpg.ma".
  17
  18 (* UNCOUNTED CONTEXT-SENSITIVE PARALLEL RT-TRANSITION FOR TERMS *************)
  19
  20 definition cpx (h): relation4 genv lenv term term ≝
  21                     λG,L,T1,T2. ∃c. ⦃G, L⦄ ⊢ T1 ⬈[eq_f, c, h] T2.
  22
  23 interpretation
  24    "uncounted context-sensitive parallel rt-transition (term)"
  25    'PRedTy h G L T1 T2 = (cpx h G L T1 T2).
  26
  27 (* Basic properties *********************************************************)
  28
  29 (* Basic_2A1: was: cpx_st *)
  30 lemma cpx_ess: ∀h,G,L,s. ⦃G, L⦄ ⊢ ⋆s ⬈[h] ⋆(next h s).
  31 /2 width=2 by cpg_ess, ex_intro/ qed.
  32
  33 lemma cpx_delta: ∀h,I,G,K,V1,V2,W2. ⦃G, K⦄ ⊢ V1 ⬈[h] V2 →
  34                  ⬆*[1] V2 ≡ W2 → ⦃G, K.ⓑ{I}V1⦄ ⊢ #0 ⬈[h] W2.
  35 #h * #G #K #V1 #V2 #W2 *
  36 /3 width=4 by cpg_delta, cpg_ell, ex_intro/
  37 qed.
  38
  39 lemma cpx_lref: ∀h,I,G,K,V,T,U,i. ⦃G, K⦄ ⊢ #i ⬈[h] T →
  40                 ⬆*[1] T ≡ U → ⦃G, K.ⓑ{I}V⦄ ⊢ #⫯i ⬈[h] U.
  41 #h #I #G #K #V #T #U #i *
  42 /3 width=4 by cpg_lref, ex_intro/
  43 qed.
  44
  45 lemma cpx_bind: ∀h,p,I,G,L,V1,V2,T1,T2.
  46                 ⦃G, L⦄ ⊢ V1 ⬈[h] V2 → ⦃G, L.ⓑ{I}V1⦄ ⊢ T1 ⬈[h] T2 →
  47                 ⦃G, L⦄ ⊢ ⓑ{p,I}V1.T1 ⬈[h] ⓑ{p,I}V2.T2.
  48 #h #p #I #G #L #V1 #V2 #T1 #T2 * #cV #HV12 *
  49 /3 width=2 by cpg_bind, ex_intro/
  50 qed.
  51
  52 lemma cpx_flat: ∀h,I,G,L,V1,V2,T1,T2.
  53                 ⦃G, L⦄ ⊢ V1 ⬈[h] V2 → ⦃G, L⦄ ⊢ T1 ⬈[h] T2 →
  54                 ⦃G, L⦄ ⊢ ⓕ{I}V1.T1 ⬈[h] ⓕ{I}V2.T2.
  55 #h * #G #L #V1 #V2 #T1 #T2 * #cV #HV12 *
  56 /3 width=5 by cpg_appl, cpg_cast, ex_intro/
  57 qed.
  58
  59 lemma cpx_zeta: ∀h,G,L,V,T1,T,T2. ⦃G, L.ⓓV⦄ ⊢ T1 ⬈[h] T →
  60                 ⬆*[1] T2 ≡ T → ⦃G, L⦄ ⊢ +ⓓV.T1 ⬈[h] T2.
  61 #h #G #L #V #T1 #T #T2 *
  62 /3 width=4 by cpg_zeta, ex_intro/
  63 qed.
  64
  65 lemma cpx_eps: ∀h,G,L,V,T1,T2. ⦃G, L⦄ ⊢ T1 ⬈[h] T2 → ⦃G, L⦄ ⊢ ⓝV.T1 ⬈[h] T2.
  66 #h #G #L #V #T1 #T2 *
  67 /3 width=2 by cpg_eps, ex_intro/
  68 qed.
  69
  70 (* Basic_2A1: was: cpx_ct *)
  71 lemma cpx_ee: ∀h,G,L,V1,V2,T. ⦃G, L⦄ ⊢ V1 ⬈[h] V2 → ⦃G, L⦄ ⊢ ⓝV1.T ⬈[h] V2.
  72 #h #G #L #V1 #V2 #T *
  73 /3 width=2 by cpg_ee, ex_intro/
  74 qed.
  75
  76 lemma cpx_beta: ∀h,p,G,L,V1,V2,W1,W2,T1,T2.
  77                 ⦃G, L⦄ ⊢ V1 ⬈[h] V2 → ⦃G, L⦄ ⊢ W1 ⬈[h] W2 → ⦃G, L.ⓛW1⦄ ⊢ T1 ⬈[h] T2 →
  78                 ⦃G, L⦄ ⊢ ⓐV1.ⓛ{p}W1.T1 ⬈[h] ⓓ{p}ⓝW2.V2.T2.
  79 #h #p #G #L #V1 #V2 #W1 #W2 #T1 #T2 * #cV #HV12 * #cW #HW12 *
  80 /3 width=2 by cpg_beta, ex_intro/
  81 qed.
  82
  83 lemma cpx_theta: ∀h,p,G,L,V1,V,V2,W1,W2,T1,T2.
  84                  ⦃G, L⦄ ⊢ V1 ⬈[h] V → ⬆*[1] V ≡ V2 → ⦃G, L⦄ ⊢ W1 ⬈[h] W2 →
  85                  ⦃G, L.ⓓW1⦄ ⊢ T1 ⬈[h] T2 →
  86                  ⦃G, L⦄ ⊢ ⓐV1.ⓓ{p}W1.T1 ⬈[h] ⓓ{p}W2.ⓐV2.T2.
  87 #h #p #G #L #V1 #V #V2 #W1 #W2 #T1 #T2 * #cV #HV1 #HV2 * #cW #HW12 *
  88 /3 width=4 by cpg_theta, ex_intro/
  89 qed.
  90
  91 (* Basic_2A1: includes: cpx_atom *)
  92 lemma cpx_refl: ∀h,G,L. reflexive … (cpx h G L).
  93 /3 width=2 by cpg_refl, ex_intro/ qed.
  94
  95 (* Advanced properties ******************************************************)
  96
  97 lemma cpx_pair_sn: ∀h,I,G,L,V1,V2. ⦃G, L⦄ ⊢ V1 ⬈[h] V2 →
  98                    ∀T. ⦃G, L⦄ ⊢ ②{I}V1.T ⬈[h] ②{I}V2.T.
  99 #h * /2 width=2 by cpx_flat, cpx_bind/
 100 qed.
 101
 102 (* Basic inversion lemmas ***************************************************)
 103
 104 lemma cpx_inv_atom1: ∀h,J,G,L,T2. ⦃G, L⦄ ⊢ ⓪{J} ⬈[h] T2 →
 105                      ∨∨ T2 = ⓪{J}
 106                       | ∃∃s. T2 = ⋆(next h s) & J = Sort s
 107                       | ∃∃I,K,V1,V2. ⦃G, K⦄ ⊢ V1 ⬈[h] V2 & ⬆*[1] V2 ≡ T2 &
 108                                      L = K.ⓑ{I}V1 & J = LRef 0
 109                       | ∃∃I,K,V,T,i. ⦃G, K⦄ ⊢ #i ⬈[h] T & ⬆*[1] T ≡ T2 &
 110                                      L = K.ⓑ{I}V & J = LRef (⫯i).
 111 #h #J #G #L #T2 * #c #H elim (cpg_inv_atom1 … H) -H *
 112 /4 width=9 by or4_intro0, or4_intro1, or4_intro2, or4_intro3, ex4_5_intro, ex4_4_intro, ex2_intro, ex_intro/
 113 qed-.
 114
 115 lemma cpx_inv_sort1: ∀h,G,L,T2,s. ⦃G, L⦄ ⊢ ⋆s ⬈[h] T2 →
 116                      T2 = ⋆s ∨ T2 = ⋆(next h s).
 117 #h #G #L #T2 #s * #c #H elim (cpg_inv_sort1 … H) -H *
 118 /2 width=1 by or_introl, or_intror/
 119 qed-.
 120
 121 lemma cpx_inv_zero1: ∀h,G,L,T2. ⦃G, L⦄ ⊢ #0 ⬈[h] T2 →
 122                      T2 = #0 ∨
 123                      ∃∃I,K,V1,V2. ⦃G, K⦄ ⊢ V1 ⬈[h] V2 & ⬆*[1] V2 ≡ T2 &
 124                                   L = K.ⓑ{I}V1.
 125 #h #G #L #T2 * #c #H elim (cpg_inv_zero1 … H) -H *
 126 /4 width=7 by ex3_4_intro, ex_intro, or_introl, or_intror/
 127 qed-.
 128
 129 lemma cpx_inv_lref1: ∀h,G,L,T2,i. ⦃G, L⦄ ⊢ #⫯i ⬈[h] T2 →
 130                      T2 = #(⫯i) ∨
 131                      ∃∃I,K,V,T. ⦃G, K⦄ ⊢ #i ⬈[h] T & ⬆*[1] T ≡ T2 & L = K.ⓑ{I}V.
 132 #h #G #L #T2 #i * #c #H elim (cpg_inv_lref1 … H) -H *
 133 /4 width=7 by ex3_4_intro, ex_intro, or_introl, or_intror/
 134 qed-.
 135
 136 lemma cpx_inv_gref1: ∀h,G,L,T2,l. ⦃G, L⦄ ⊢ §l ⬈[h] T2 → T2 = §l.
 137 #h #G #L #T2 #l * #c #H elim (cpg_inv_gref1 … H) -H //
 138 qed-.
 139
 140 lemma cpx_inv_bind1: ∀h,p,I,G,L,V1,T1,U2. ⦃G, L⦄ ⊢ ⓑ{p,I}V1.T1 ⬈[h] U2 → (
 141                      ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ⬈[h] V2 & ⦃G, L.ⓑ{I}V1⦄ ⊢ T1 ⬈[h] T2 &
 142                               U2 = ⓑ{p,I}V2.T2
 143                      ) ∨
 144                      ∃∃T. ⦃G, L.ⓓV1⦄ ⊢ T1 ⬈[h] T & ⬆*[1] U2 ≡ T &
 145                           p = true & I = Abbr.
 146 #h #p #I #G #L #V1 #T1 #U2 * #c #H elim (cpg_inv_bind1 … H) -H *
 147 /4 width=5 by ex4_intro, ex3_2_intro, ex_intro, or_introl, or_intror/
 148 qed-.
 149
 150 lemma cpx_inv_abbr1: ∀h,p,G,L,V1,T1,U2. ⦃G, L⦄ ⊢ ⓓ{p}V1.T1 ⬈[h] U2 → (
 151                      ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ⬈[h] V2 & ⦃G, L.ⓓV1⦄ ⊢ T1 ⬈[h] T2 &
 152                               U2 = ⓓ{p}V2.T2
 153                      ) ∨
 154                      ∃∃T. ⦃G, L.ⓓV1⦄ ⊢ T1 ⬈[h] T & ⬆*[1] U2 ≡ T & p = true.
 155 #h #p #G #L #V1 #T1 #U2 * #c #H elim (cpg_inv_abbr1 … H) -H *
 156 /4 width=5 by ex3_2_intro, ex3_intro, ex_intro, or_introl, or_intror/
 157 qed-.
 158
 159 lemma cpx_inv_abst1: ∀h,p,G,L,V1,T1,U2. ⦃G, L⦄ ⊢ ⓛ{p}V1.T1 ⬈[h] U2 →
 160                      ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ⬈[h] V2 & ⦃G, L.ⓛV1⦄ ⊢ T1 ⬈[h] T2 &
 161                               U2 = ⓛ{p}V2.T2.
 162 #h #p #G #L #V1 #T1 #U2 * #c #H elim (cpg_inv_abst1 … H) -H
 163 /3 width=5 by ex3_2_intro, ex_intro/
 164 qed-.
 165
 166 lemma cpx_inv_appl1: ∀h,G,L,V1,U1,U2. ⦃G, L⦄ ⊢ ⓐ V1.U1 ⬈[h] U2 →
 167                      ∨∨ ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ⬈[h] V2 & ⦃G, L⦄ ⊢ U1 ⬈[h] T2 &
 168                                  U2 = ⓐV2.T2
 169                       | ∃∃p,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ⬈[h] V2 & ⦃G, L⦄ ⊢ W1 ⬈[h] W2 &
 170                                             ⦃G, L.ⓛW1⦄ ⊢ T1 ⬈[h] T2 &
 171                                             U1 = ⓛ{p}W1.T1 & U2 = ⓓ{p}ⓝW2.V2.T2
 172                       | ∃∃p,V,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ⬈[h] V & ⬆*[1] V ≡ V2 &
 173                                               ⦃G, L⦄ ⊢ W1 ⬈[h] W2 & ⦃G, L.ⓓW1⦄ ⊢ T1 ⬈[h] T2 &
 174                                               U1 = ⓓ{p}W1.T1 & U2 = ⓓ{p}W2.ⓐV2.T2.
 175 #h #G #L #V1 #U1 #U2 * #c #H elim (cpg_inv_appl1 … H) -H *
 176 /4 width=13 by or3_intro0, or3_intro1, or3_intro2, ex6_7_intro, ex5_6_intro, ex3_2_intro, ex_intro/
 177 qed-.
 178
 179 lemma cpx_inv_cast1: ∀h,G,L,V1,U1,U2. ⦃G, L⦄ ⊢ ⓝV1.U1 ⬈[h] U2 →
 180                      ∨∨ ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ⬈[h] V2 & ⦃G, L⦄ ⊢ U1 ⬈[h] T2 &
 181                                  U2 = ⓝV2.T2
 182                       | ⦃G, L⦄ ⊢ U1 ⬈[h] U2
 183                       | ⦃G, L⦄ ⊢ V1 ⬈[h] U2.
 184 #h #G #L #V1 #U1 #U2 * #c #H elim (cpg_inv_cast1 … H) -H *
 185 /4 width=5 by or3_intro0, or3_intro1, or3_intro2, ex3_2_intro, ex_intro/
 186 qed-.
 187
 188 (* Advanced inversion lemmas ************************************************)
 189
 190 lemma cpx_inv_zero1_pair: ∀h,I,G,K,V1,T2. ⦃G, K.ⓑ{I}V1⦄ ⊢ #0 ⬈[h] T2 →
 191                           T2 = #0 ∨
 192                           ∃∃V2. ⦃G, K⦄ ⊢ V1 ⬈[h] V2 & ⬆*[1] V2 ≡ T2.
 193 #h #I #G #L #V1 #T2 * #c #H elim (cpg_inv_zero1_pair … H) -H *
 194 /4 width=3 by ex2_intro, ex_intro, or_intror, or_introl/
 195 qed-.
 196
 197 lemma cpx_inv_lref1_pair: ∀h,I,G,K,V,T2,i. ⦃G, K.ⓑ{I}V⦄ ⊢ #⫯i ⬈[h] T2 →
 198                           T2 = #(⫯i) ∨
 199                           ∃∃T. ⦃G, K⦄ ⊢ #i ⬈[h] T & ⬆*[1] T ≡ T2.
 200 #h #I #G #L #V #T2 #i * #c #H elim (cpg_inv_lref1_pair … H) -H *
 201 /4 width=3 by ex2_intro, ex_intro, or_introl, or_intror/
 202 qed-.
 203
 204 lemma cpx_inv_flat1: ∀h,I,G,L,V1,U1,U2. ⦃G, L⦄ ⊢ ⓕ{I}V1.U1 ⬈[h] U2 →
 205                      ∨∨ ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ⬈[h] V2 & ⦃G, L⦄ ⊢ U1 ⬈[h] T2 &
 206                                  U2 = ⓕ{I}V2.T2
 207                       | (⦃G, L⦄ ⊢ U1 ⬈[h] U2 ∧ I = Cast)
 208                       | (⦃G, L⦄ ⊢ V1 ⬈[h] U2 ∧ I = Cast)
 209                       | ∃∃p,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ⬈[h] V2 & ⦃G, L⦄ ⊢ W1 ⬈[h] W2 &
 210                                             ⦃G, L.ⓛW1⦄ ⊢ T1 ⬈[h] T2 &
 211                                             U1 = ⓛ{p}W1.T1 &
 212                                             U2 = ⓓ{p}ⓝW2.V2.T2 & I = Appl
 213                       | ∃∃p,V,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ⬈[h] V & ⬆*[1] V ≡ V2 &
 214                                               ⦃G, L⦄ ⊢ W1 ⬈[h] W2 & ⦃G, L.ⓓW1⦄ ⊢ T1 ⬈[h] T2 &
 215                                               U1 = ⓓ{p}W1.T1 &
 216                                               U2 = ⓓ{p}W2.ⓐV2.T2 & I = Appl.
 217 #h * #G #L #V1 #U1 #U2 #H
 218 [ elim (cpx_inv_appl1 … H) -H *
 219   /3 width=14 by or5_intro0, or5_intro3, or5_intro4, ex7_7_intro, ex6_6_intro, ex3_2_intro/
 220 | elim (cpx_inv_cast1 … H) -H [ * ]
 221   /3 width=14 by or5_intro0, or5_intro1, or5_intro2, ex3_2_intro, conj/
 222 ]
 223 qed-.
 224
 225 (* Basic forward lemmas *****************************************************)
 226
 227 lemma cpx_fwd_bind1_minus: ∀h,I,G,L,V1,T1,T. ⦃G, L⦄ ⊢ -ⓑ{I}V1.T1 ⬈[h] T → ∀p.
 228                            ∃∃V2,T2. ⦃G, L⦄ ⊢ ⓑ{p,I}V1.T1 ⬈[h] ⓑ{p,I}V2.T2 &
 229                                     T = -ⓑ{I}V2.T2.
 230 #h #I #G #L #V1 #T1 #T * #c #H #p elim (cpg_fwd_bind1_minus … H p) -H
 231 /3 width=4 by ex2_2_intro, ex_intro/
 232 qed-.
 233
 234 (* Basic eliminators ********************************************************)
 235
 236 lemma cpx_ind: ∀h. ∀R:relation4 genv lenv term term.
 237                (∀I,G,L. R G L (⓪{I}) (⓪{I})) →
 238                (∀G,L,s. R G L (⋆s) (⋆(next h s))) →
 239                (∀I,G,K,V1,V2,W2. ⦃G, K⦄ ⊢ V1 ⬈[h] V2 → R G K V1 V2 →
 240                  ⬆*[1] V2 ≡ W2 → R G (K.ⓑ{I}V1) (#0) W2
 241                ) → (∀I,G,K,V,T,U,i. ⦃G, K⦄ ⊢ #i ⬈[h] T → R G K (#i) T →
 242                  ⬆*[1] T ≡ U → R G (K.ⓑ{I}V) (#⫯i) (U)
 243                ) → (∀p,I,G,L,V1,V2,T1,T2. ⦃G, L⦄ ⊢ V1 ⬈[h] V2 → ⦃G, L.ⓑ{I}V1⦄ ⊢ T1 ⬈[h] T2 →
 244                   R G L V1 V2 → R G (L.ⓑ{I}V1) T1 T2 → R G L (ⓑ{p,I}V1.T1) (ⓑ{p,I}V2.T2)
 245                ) → (∀I,G,L,V1,V2,T1,T2. ⦃G, L⦄ ⊢ V1 ⬈[h] V2 → ⦃G, L⦄ ⊢ T1 ⬈[h] T2 →
 246                   R G L V1 V2 → R G L T1 T2 → R G L (ⓕ{I}V1.T1) (ⓕ{I}V2.T2)
 247                ) → (∀G,L,V,T1,T,T2. ⦃G, L.ⓓV⦄ ⊢ T1 ⬈[h] T → R G (L.ⓓV) T1 T →
 248                   ⬆*[1] T2 ≡ T → R G L (+ⓓV.T1) T2
 249                ) → (∀G,L,V,T1,T2. ⦃G, L⦄ ⊢ T1 ⬈[h] T2 → R G L T1 T2 →
 250                   R G L (ⓝV.T1) T2
 251                ) → (∀G,L,V1,V2,T. ⦃G, L⦄ ⊢ V1 ⬈[h] V2 → R G L V1 V2 →
 252                   R G L (ⓝV1.T) V2
 253                ) → (∀p,G,L,V1,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ⬈[h] V2 → ⦃G, L⦄ ⊢ W1 ⬈[h] W2 → ⦃G, L.ⓛW1⦄ ⊢ T1 ⬈[h] T2 →
 254                   R G L V1 V2 → R G L W1 W2 → R G (L.ⓛW1) T1 T2 →
 255                   R G L (ⓐV1.ⓛ{p}W1.T1) (ⓓ{p}ⓝW2.V2.T2)
 256                ) → (∀p,G,L,V1,V,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ⬈[h] V → ⦃G, L⦄ ⊢ W1 ⬈[h] W2 → ⦃G, L.ⓓW1⦄ ⊢ T1 ⬈[h] T2 →
 257                   R G L V1 V → R G L W1 W2 → R G (L.ⓓW1) T1 T2 →
 258                   ⬆*[1] V ≡ V2 → R G L (ⓐV1.ⓓ{p}W1.T1) (ⓓ{p}W2.ⓐV2.T2)
 259                ) →
 260                ∀G,L,T1,T2. ⦃G, L⦄ ⊢ T1 ⬈[h] T2 → R G L T1 T2.
 261 #h #R #IH1 #IH2 #IH3 #IH4 #IH5 #IH6 #IH7 #IH8 #IH9 #IH10 #IH11 #G #L #T1 #T2
 262 * #c #H elim H -c -G -L -T1 -T2 /3 width=4 by ex_intro/
 263 qed-.