matita/matita/contribs/lambdadelta/basic_2/rt_transition/cpx_drops.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/xoa/ex_4_5.ma".
  16 include "basic_2/rt_transition/cpg_drops.ma".
  17 include "basic_2/rt_transition/cpx.ma".
  18
  19 (* EXTENDED CONTEXT-SENSITIVE PARALLEL RT-TRANSITION FOR TERMS **************)
  20
  21 (* Advanced properties ******************************************************)
  22
  23 (* Basic_2A1: was: cpx_delta *)
  24 lemma cpx_delta_drops (G) (L):
  25       ∀I,K,V,V2,W2,i.
  26       ⇩[i] L ≘ K.ⓑ[I]V → ❪G,K❫ ⊢ V ⬈ V2 →
  27       ⇧[↑i] V2 ≘ W2 → ❪G,L❫ ⊢ #i ⬈ W2.
  28 #G #L * #K #V #V2 #W2 #i #HLK *
  29 /3 width=7 by cpg_ell_drops, cpg_delta_drops, ex_intro/
  30 qed.
  31
  32 (* Advanced inversion lemmas ************************************************)
  33
  34 (* Basic_2A1: was: cpx_inv_atom1 *)
  35 lemma cpx_inv_atom1_drops (G) (L):
  36       ∀I,T2. ❪G,L❫ ⊢ ⓪[I] ⬈ T2 →
  37       ∨∨ T2 = ⓪[I]
  38        | ∃∃s1,s2. T2 = ⋆s2 & I = Sort s1
  39        | ∃∃J,K,V,V2,i. ⇩[i] L ≘ K.ⓑ[J]V & ❪G,K❫ ⊢ V ⬈ V2 & ⇧[↑i] V2 ≘ T2 & I = LRef i.
  40 #G #L #I #T2 * #c #H elim (cpg_inv_atom1_drops … H) -H *
  41 /4 width=9 by or3_intro0, or3_intro1, or3_intro2, ex4_5_intro, ex2_2_intro, ex_intro/
  42 qed-.
  43
  44 (* Basic_2A1: was: cpx_inv_lref1 *)
  45 lemma cpx_inv_lref1_drops (G) (L):
  46       ∀T2,i. ❪G,L❫ ⊢ #i ⬈ T2 →
  47       ∨∨ T2 = #i
  48        | ∃∃J,K,V,V2. ⇩[i] L ≘ K. ⓑ[J]V & ❪G,K❫ ⊢ V ⬈ V2 & ⇧[↑i] V2 ≘ T2.
  49 #G #L #T1 #i * #c #H elim (cpg_inv_lref1_drops … H) -H *
  50 /4 width=7 by ex3_4_intro, ex_intro, or_introl, or_intror/
  51 qed-.
  52
  53 (* Properties with generic slicing for local environments *******************)
  54
  55 (* Basic_2A1: includes: cpx_lift *)
  56 lemma cpx_lifts_sn (G): d_liftable2_sn … lifts (cpx G).
  57 #G #K #T1 #T2 * #cT #HT12 #b #f #L #HLK #U1 #HTU1
  58 elim (cpg_lifts_sn … HT12 … HLK … HTU1) -K -T1
  59 /3 width=4 by ex2_intro, ex_intro/
  60 qed-.
  61
  62 lemma cpx_lifts_bi (G): d_liftable2_bi … lifts (cpx G).
  63 #G #K #T1 #T2 * /3 width=10 by cpg_lifts_bi, ex_intro/
  64 qed-.
  65
  66 (* Inversion lemmas with generic slicing for local environments *************)
  67
  68 (* Basic_2A1: includes: cpx_inv_lift1 *)
  69 lemma cpx_inv_lifts_sn (G): d_deliftable2_sn … lifts (cpx G).
  70 #G #L #U1 #U2 * #cU #HU12 #b #f #K #HLK #T1 #HTU1
  71 elim (cpg_inv_lifts_sn … HU12 … HLK … HTU1) -L -U1
  72 /3 width=4 by ex2_intro, ex_intro/
  73 qed-.
  74
  75 lemma cpx_inv_lifts_bi (G): d_deliftable2_bi …lifts (cpx G).
  76 #G #L #U1 #U2 * /3 width=10 by cpg_inv_lifts_bi, ex_intro/
  77 qed-.