matita/matita/contribs/lambdadelta/basic_2/rt_transition/cpx_drops_basic.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/relocation/lifts_basic.ma".
  16 include "basic_2/rt_transition/cpx_drops.ma".
  17
  18 (* UNBOUND CONTEXT-SENSITIVE PARALLEL RT-TRANSITION FOR TERMS ***************)
  19
  20 (* Properties with basic relocation *****************************************)
  21
  22 lemma cpx_subst (h) (G) (L) (U1) (i):
  23                 ∀I,K,V. ⇩[i] L ≘ K.ⓑ[I]V →
  24                 ∃∃U2,T2. ❪G,L❫ ⊢ U1 ⬈[h] U2 & ⇧[i,1] T2 ≘ U2.
  25 #h #G #L #U1 @(fqup_wf_ind_eq (Ⓣ) … G L U1) -G -L -U1
  26 #G0 #L0 #U0 #IH #G #L * *
  27 [ #s #HG #HL #HT #i #I #K #V #_ destruct -IH
  28   /2 width=4 by lifts_sort, ex2_2_intro/
  29 | #j #HG #HL #HT #i #I #K #V #HLK destruct -IH
  30   elim (lt_or_eq_or_gt i j) #Hij
  31   [ /3 width=4 by lifts_lref_ge_minus, cpx_refl, ex2_2_intro/
  32   | elim (lifts_total V (𝐔❨↑i❩)) #U2 #HU2
  33     elim (lifts_split_trans … HU2 (𝐔❨i❩) (𝐁❨i,1❩)) [2: @(after_basic_rc i 0) ]
  34     /3 width=7 by cpx_delta_drops, ex2_2_intro/
  35   | /3 width=4 by lifts_lref_lt, cpx_refl, ex2_2_intro/
  36   ]
  37 | #l #HG #HL #HT #i #I #K #V #_ destruct -IH
  38   /2 width=4 by lifts_gref, ex2_2_intro/
  39 | #p #J #W1 #U1 #HG #HL #HT #i #I #K #V #HLK destruct
  40   elim (IH G L W1 … HLK) [| // ] #W2 #V2 #HW12 #HVW2
  41   elim (IH G (L.ⓑ[J]W1) U1 … (↑i)) [|*: /3 width=4 by drops_drop/ ] #U2 #T2 #HU12 #HTU2
  42   /3 width=9 by cpx_bind, lifts_bind, ex2_2_intro/
  43 | #J #W1 #U1 #HG #HL #HT #i #I #K #V #HLK destruct
  44   elim (IH G L W1 … HLK) [| // ] #W2 #V2 #HW12 #HVW2
  45   elim (IH G L U1 … HLK) [| // ] #U2 #T2 #HU12 #HTU2
  46   /3 width=8 by cpx_flat, lifts_flat, ex2_2_intro/
  47 ]
  48 qed-.