matita/matita/contribs/lambdadelta/basic_2/rt_transition/cpx_feqg.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/static/feqg.ma".
  16 include "basic_2/rt_transition/cpx_reqg.ma".
  17 include "basic_2/rt_transition/rpx_reqg.ma".
  18
  19 (* EXTENDED CONTEXT-SENSITIVE PARALLEL RT-TRANSITION FOR TERMS **************)
  20
  21 (* Properties with generic equivalence for closures *************************)
  22
  23 lemma feqg_cpx_trans_cpx (S):
  24       reflexive … S → symmetric … S →
  25       ∀G1,G2,L1,L2,T1,T. ❪G1,L1,T1❫ ≛[S] ❪G2,L2,T❫ →
  26       ∀T2. ❪G2,L2❫ ⊢ T ⬈ T2 → ❪G1,L1❫ ⊢ T1 ⬈ T2.
  27 #S #H1S #H2S #G1 #G2 #L1 #L2 #T1 #T #H #T2 #HT2
  28 elim (feqg_inv_gen_dx … H) -H // #H #HL12 #HT1 destruct
  29 @(cpx_teqg_repl_reqg … HT2)
  30 /2 width=7 by reqg_sym, teqg_sym, teqg_refl/
  31 qed-.
  32
  33 lemma feqg_cpx_trans_feqg (S):
  34       reflexive … S → symmetric … S →
  35       ∀G1,G2,L1,L2,T1,T. ❪G1,L1,T1❫ ≛[S] ❪G2,L2,T❫ →
  36       ∀T2. ❪G2,L2❫ ⊢ T ⬈ T2 → ❪G1,L1,T2❫ ≛[S] ❪G2,L2,T2❫.
  37 #S #H1S #H2S #G1 #G2 #L1 #L2 #T1 #T #H #T2 #HT2
  38 elim (feqg_inv_gen_dx … H) -H // #H #HL12 #_ destruct
  39 lapply (cpx_reqg_conf_dx … HT2 … HL12) -HT2 -HL12 // #HL12
  40 /3 width=1 by feqg_intro_sn, teqg_refl/
  41 qed-.