matita/matita/contribs/lambdadelta/basic_2/rt_transition/cpx_fqus.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 (* UNCOUNTED CONTEXT-SENSITIVE PARALLEL RT-TRANSITION FOR TERMS *************)
  16
  17 (* Properties on supclosure *************************************************)
  18
  19 lemma fqu_cpx_trans: ∀h,o,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐ ⦃G2, L2, T2⦄ →
  20                      ∀U2. ⦃G2, L2⦄ ⊢ T2 ⬈[h, o] U2 →
  21                      ∃∃U1. ⦃G1, L1⦄ ⊢ T1 ⬈[h, o] U1 & ⦃G1, L1, U1⦄ ⊐ ⦃G2, L2, U2⦄.
  22 #h #o #G1 #G2 #L1 #L2 #T1 #T2 #H elim H -G1 -G2 -L1 -L2 -T1 -T2
  23 /3 width=3 by fqu_pair_sn, fqu_bind_dx, fqu_flat_dx, cpx_pair_sn, cpx_bind, cpx_flat, ex2_intro/
  24 [ #I #G #L #V2 #U2 #HVU2
  25   elim (lift_total U2 0 1)
  26   /4 width=7 by fqu_drop, cpx_delta, drop_pair, drop_drop, ex2_intro/
  27 | #G #L #K #T1 #U1 #k #HLK1 #HTU1 #T2 #HTU2
  28   elim (lift_total T2 0 (k+1))
  29   /3 width=11 by cpx_lift, fqu_drop, ex2_intro/
  30 ]
  31 qed-.
  32
  33 lemma fquq_cpx_trans: ∀h,o,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐⸮ ⦃G2, L2, T2⦄ →
  34                       ∀U2. ⦃G2, L2⦄ ⊢ T2 ⬈[h, o] U2 →
  35                       ∃∃U1. ⦃G1, L1⦄ ⊢ T1 ⬈[h, o] U1 & ⦃G1, L1, U1⦄ ⊐⸮ ⦃G2, L2, U2⦄.
  36 #h #o #G1 #G2 #L1 #L2 #T1 #T2 #H #U2 #HTU2 elim (fquq_inv_gen … H) -H
  37 [ #HT12 elim (fqu_cpx_trans … HT12 … HTU2) /3 width=3 by fqu_fquq, ex2_intro/
  38 | * #H1 #H2 #H3 destruct /2 width=3 by ex2_intro/
  39 ]
  40 qed-.
  41
  42 lemma fqup_cpx_trans: ∀h,o,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐+ ⦃G2, L2, T2⦄ →
  43                       ∀U2. ⦃G2, L2⦄ ⊢ T2 ⬈[h, o] U2 →
  44                       ∃∃U1. ⦃G1, L1⦄ ⊢ T1 ⬈[h, o] U1 & ⦃G1, L1, U1⦄ ⊐+ ⦃G2, L2, U2⦄.
  45 #h #o #G1 #G2 #L1 #L2 #T1 #T2 #H @(fqup_ind … H) -G2 -L2 -T2
  46 [ #G2 #L2 #T2 #H12 #U2 #HTU2 elim (fqu_cpx_trans … H12 … HTU2) -T2
  47   /3 width=3 by fqu_fqup, ex2_intro/
  48 | #G #G2 #L #L2 #T #T2 #_ #HT2 #IHT1 #U2 #HTU2
  49   elim (fqu_cpx_trans … HT2 … HTU2) -T2 #T2 #HT2 #HTU2
  50   elim (IHT1 … HT2) -T /3 width=7 by fqup_strap1, ex2_intro/
  51 ]
  52 qed-.
  53
  54 lemma fqus_cpx_trans: ∀h,o,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐* ⦃G2, L2, T2⦄ →
  55                       ∀U2. ⦃G2, L2⦄ ⊢ T2 ⬈[h, o] U2 →
  56                       ∃∃U1. ⦃G1, L1⦄ ⊢ T1 ⬈[h, o] U1 & ⦃G1, L1, U1⦄ ⊐* ⦃G2, L2, U2⦄.
  57 #h #o #G1 #G2 #L1 #L2 #T1 #T2 #H #U2 #HTU2 elim (fqus_inv_gen … H) -H
  58 [ #HT12 elim (fqup_cpx_trans … HT12 … HTU2) /3 width=3 by fqup_fqus, ex2_intro/
  59 | * #H1 #H2 #H3 destruct /2 width=3 by ex2_intro/
  60 ]
  61 qed-.
  62
  63 lemma fqu_cpx_trans_neq: ∀h,o,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐ ⦃G2, L2, T2⦄ →
  64                          ∀U2. ⦃G2, L2⦄ ⊢ T2 ⬈[h, o] U2 → (T2 = U2 → ⊥) →
  65                          ∃∃U1. ⦃G1, L1⦄ ⊢ T1 ⬈[h, o] U1 & T1 = U1 → ⊥ & ⦃G1, L1, U1⦄ ⊐ ⦃G2, L2, U2⦄.
  66 #h #o #G1 #G2 #L1 #L2 #T1 #T2 #H elim H -G1 -G2 -L1 -L2 -T1 -T2
  67 [ #I #G #L #V1 #V2 #HV12 #_ elim (lift_total V2 0 1)
  68   #U2 #HVU2 @(ex3_intro … U2)
  69   [1,3: /3 width=7 by fqu_drop, cpx_delta, drop_pair, drop_drop/
  70   | #H destruct
  71     lapply (lift_inv_lref2_be … HVU2 ? ?) -HVU2 //
  72   ]
  73 | #I #G #L #V1 #T #V2 #HV12 #H @(ex3_intro … (②{I}V2.T))
  74   [1,3: /2 width=4 by fqu_pair_sn, cpx_pair_sn/
  75   | #H0 destruct /2 width=1 by/
  76   ]
  77 | #a #I #G #L #V #T1 #T2 #HT12 #H @(ex3_intro … (ⓑ{a,I}V.T2))
  78   [1,3: /2 width=4 by fqu_bind_dx, cpx_bind/
  79   | #H0 destruct /2 width=1 by/
  80   ]
  81 | #I #G #L #V #T1 #T2 #HT12 #H @(ex3_intro … (ⓕ{I}V.T2))
  82   [1,3: /2 width=4 by fqu_flat_dx, cpx_flat/
  83   | #H0 destruct /2 width=1 by/
  84   ]
  85 | #G #L #K #T1 #U1 #k #HLK #HTU1 #T2 #HT12 #H elim (lift_total T2 0 (k+1))
  86   #U2 #HTU2 @(ex3_intro … U2)
  87   [1,3: /2 width=10 by cpx_lift, fqu_drop/
  88   | #H0 destruct /3 width=5 by lift_inj/
  89 ]
  90 qed-.
  91
  92 lemma fquq_cpx_trans_neq: ∀h,o,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐⸮ ⦃G2, L2, T2⦄ →
  93                           ∀U2. ⦃G2, L2⦄ ⊢ T2 ⬈[h, o] U2 → (T2 = U2 → ⊥) →
  94                           ∃∃U1. ⦃G1, L1⦄ ⊢ T1 ⬈[h, o] U1 & T1 = U1 → ⊥ & ⦃G1, L1, U1⦄ ⊐⸮ ⦃G2, L2, U2⦄.
  95 #h #o #G1 #G2 #L1 #L2 #T1 #T2 #H12 #U2 #HTU2 #H elim (fquq_inv_gen … H12) -H12
  96 [ #H12 elim (fqu_cpx_trans_neq … H12 … HTU2 H) -T2
  97   /3 width=4 by fqu_fquq, ex3_intro/
  98 | * #HG #HL #HT destruct /3 width=4 by ex3_intro/
  99 ]
 100 qed-.
 101
 102 lemma fqup_cpx_trans_neq: ∀h,o,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐+ ⦃G2, L2, T2⦄ →
 103                           ∀U2. ⦃G2, L2⦄ ⊢ T2 ⬈[h, o] U2 → (T2 = U2 → ⊥) →
 104                           ∃∃U1. ⦃G1, L1⦄ ⊢ T1 ⬈[h, o] U1 & T1 = U1 → ⊥ & ⦃G1, L1, U1⦄ ⊐+ ⦃G2, L2, U2⦄.
 105 #h #o #G1 #G2 #L1 #L2 #T1 #T2 #H @(fqup_ind_dx … H) -G1 -L1 -T1
 106 [ #G1 #L1 #T1 #H12 #U2 #HTU2 #H elim (fqu_cpx_trans_neq … H12 … HTU2 H) -T2
 107   /3 width=4 by fqu_fqup, ex3_intro/
 108 | #G #G1 #L #L1 #T #T1 #H1 #_ #IH12 #U2 #HTU2 #H elim (IH12 … HTU2 H) -T2
 109   #U1 #HTU1 #H #H12 elim (fqu_cpx_trans_neq … H1 … HTU1 H) -T1
 110   /3 width=8 by fqup_strap2, ex3_intro/
 111 ]
 112 qed-.
 113
 114 lemma fqus_cpx_trans_neq: ∀h,o,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐* ⦃G2, L2, T2⦄ →
 115                           ∀U2. ⦃G2, L2⦄ ⊢ T2 ⬈[h, o] U2 → (T2 = U2 → ⊥) →
 116                           ∃∃U1. ⦃G1, L1⦄ ⊢ T1 ⬈[h, o] U1 & T1 = U1 → ⊥ & ⦃G1, L1, U1⦄ ⊐* ⦃G2, L2, U2⦄.
 117 #h #o #G1 #G2 #L1 #L2 #T1 #T2 #H12 #U2 #HTU2 #H elim (fqus_inv_gen … H12) -H12
 118 [ #H12 elim (fqup_cpx_trans_neq … H12 … HTU2 H) -T2
 119   /3 width=4 by fqup_fqus, ex3_intro/
 120 | * #HG #HL #HT destruct /3 width=4 by ex3_intro/
 121 ]
 122 qed-.