matita/matita/contribs/lambdadelta/basic_2/rt_transition/cpx_lfxs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/syntax/lveq_length.ma".
  16 include "basic_2/relocation/lexs_length.ma".
  17 include "basic_2/relocation/drops_lexs.ma".
  18 include "basic_2/static/frees_drops.ma".
  19 include "basic_2/static/lsubf_frees.ma".
  20 include "basic_2/static/lfxs_fsle.ma".
  21 include "basic_2/rt_transition/cpx_drops.ma".
  22 include "basic_2/rt_transition/cpx_ext.ma".
  23
  24 (* UNCOUNTED CONTEXT-SENSITIVE PARALLEL RT-TRANSITION FOR TERMS *************)
  25
  26 (* Properties with context-sensitive free variables *************************)
  27
  28 (* Basic_2A1: uses: lpx_cpx_frees_trans *)
  29 lemma cpx_frees_conf_lexs: ∀h,G,L1,T1,f1. L1 ⊢ 𝐅*⦃T1⦄ ≡ f1 →
  30                            ∀L2. L1 ⪤*[cpx_ext h G, cfull, f1] L2 →
  31                            ∀T2. ⦃G, L1⦄ ⊢ T1 ⬈[h] T2 →
  32                            ∃∃f2. L2 ⊢ 𝐅*⦃T2⦄ ≡ f2 & f2 ⊆ f1.
  33 #h #G #L1 #T1 @(fqup_wf_ind_eq (Ⓣ) … G L1 T1) -G -L1 -T1
  34 #G0 #L0 #U0 #IH #G #L1 * *
  35 [ -IH #s #HG #HL #HU #g1 #H1 #L2 #_ #U2 #H0 destruct
  36   lapply (frees_inv_sort … H1) -H1 #Hg1
  37   elim (cpx_inv_sort1 … H0) -H0 #H destruct
  38   /3 width=3 by frees_sort, sle_refl, ex2_intro/
  39 | #i #HG #HL #HU #g1 #H1 #L2 #H2 #U2 #H0 destruct
  40   elim (frees_inv_lref_drops … H1) -H1 *
  41   [ -IH #f1 #HL1 #Hf1 #H destruct
  42     elim (cpx_inv_lref1_drops … H0) -H0
  43     [ #H destruct
  44       /4 width=9 by frees_atom_drops, drops_atom2_lexs_conf, sle_refl, ex2_intro/
  45     | * -H2 -Hf1 #I #K1 #V1 #V2 #HLK1
  46       lapply (drops_TF … HLK1) -HLK1 #HLK1
  47       lapply (drops_mono … HLK1 … HL1) -L1 #H destruct
  48     ]
  49   | #f1 #I #K1 #V1 #Hf1 #HLK1 #H destruct
  50     elim (cpx_inv_lref1_drops … H0) -H0
  51     [ #H destruct
  52       elim (lexs_drops_conf_next … H2 … HLK1) -H2 [ |*: // ] #Z #K2 #HLK2 #HK12 #H
  53       elim (ext2_inv_pair_sn … H) -H #V2 #HV12 #H destruct
  54       elim (IH … Hf1 … HK12 … HV12) /2 width=2 by fqup_lref/ -L1 -K1 -V1 #f2 #Hf2 #Hf21
  55       /4 width=7 by frees_lref_pushs, frees_pair_drops, drops_refl, sle_pushs, sle_next, ex2_intro/
  56     | * #Z #Y #X #V2 #H #HV12 #HVU2
  57       lapply (drops_mono … H … HLK1) -H #H destruct
  58       elim (lexs_drops_conf_next … H2 … HLK1) -H2 [ |*: // ] #I2 #K2 #HLK2 #HK12 #H
  59       elim (ext2_inv_pair_sn … H) -H #V0 #_ #H destruct
  60       lapply (drops_isuni_fwd_drop2 … HLK2) // -V0 #HLK2
  61       elim (IH … Hf1 … HK12 … HV12) /2 width=2 by fqup_lref/ -I -L1 -K1 -V1 #f2 #Hf2 #Hf21
  62       lapply (frees_lifts … Hf2 … HLK2 … HVU2 ??) /4 width=7 by sle_weak, ex2_intro, sle_pushs/
  63     ]
  64   | #f1 #I #K1 #HLK1 #Hf1 #H destruct
  65     elim (cpx_inv_lref1_drops … H0) -H0
  66     [ -IH #H destruct
  67       elim (lexs_drops_conf_next … H2 … HLK1) -H2 -HLK1 [ |*: // ] #Z #K2 #HLK2 #_ #H
  68       lapply (ext2_inv_unit_sn … H) -H #H destruct
  69       /3 width=3 by frees_unit_drops, sle_refl, ex2_intro/
  70     | * -H2 -Hf1 #Z #Y1 #X1 #X2 #HLY1
  71       lapply (drops_mono … HLK1 … HLY1) -L1 #H destruct
  72     ]
  73   ]
  74 | -IH #l #HG #HL #HU #g1 #H1 #L2 #_ #U2 #H0 destruct
  75   lapply (frees_inv_gref … H1) -H1 #Hg1
  76   lapply (cpx_inv_gref1 … H0) -H0 #H destruct
  77   /3 width=3 by frees_gref, sle_refl, ex2_intro/
  78 | #p #I #V1 #T1 #HG #HL #HU #g1 #H1 #L2 #H2 #U2 #H0 destruct
  79   elim (frees_inv_bind … H1) -H1 #gV1 #gT1 #HgV1 #HgT1 #Hg1
  80   elim (cpx_inv_bind1 … H0) -H0 *
  81   [ #V2 #T2 #HV12 #HT12 #H destruct
  82     lapply (sle_lexs_trans … H2 gV1 ?) /2 width=2 by sor_inv_sle_sn/ #HL12V
  83     lapply (sle_lexs_trans … H2 (⫱gT1) ?) /2 width=2 by sor_inv_sle_dx/ -H2 #HL12T
  84     lapply (lexs_inv_tl … (BPair I V1) (BPair I V2) … HL12T ??) /2 width=1 by ext2_pair/ -HL12T #HL12T
  85     elim (IH … HgV1 … HL12V … HV12) // -HgV1 -HL12V -HV12 #gV2 #HgV2 #HgV21
  86     elim (IH … HgT1 … HL12T … HT12) // -IH -HgT1 -HL12T -HT12 #gT2 #HgT2 #HgT21
  87     elim (sor_isfin_ex gV2 (⫱gT2)) /3 width=3 by frees_fwd_isfin, isfin_tl/
  88     /4 width=10 by frees_bind, monotonic_sle_sor, sle_tl, ex2_intro/
  89   | #T2 #HT12 #HUT2 #H0 #H1 destruct -HgV1
  90     lapply (sle_lexs_trans … H2 (⫱gT1) ?) /2 width=2 by sor_inv_sle_dx/ -H2 #HL12T
  91     lapply (lexs_inv_tl … (BPair Abbr V1) (BPair Abbr V1) … HL12T ??) /2 width=1 by ext2_pair/ -HL12T #HL12T
  92     elim (IH … HgT1 … HL12T … HT12) // -L1 -T1 #gT2 #HgT2 #HgT21
  93     lapply (frees_inv_lifts_SO (Ⓣ) … HgT2 … L2 … HUT2) [ /3 width=1 by drops_refl, drops_drop/ ] -V1 -T2
  94     /5 width=6 by sor_inv_sle_dx, sle_trans, sle_tl, ex2_intro/
  95   ]
  96 | #I #V1 #T0 #HG #HL #HU #g1 #H1 #L2 #H2 #U2 #H0 destruct
  97   elim (frees_inv_flat … H1) -H1 #gV1 #gT0 #HgV1 #HgT0 #Hg1
  98   elim (cpx_inv_flat1 … H0) -H0 *
  99   [ #V2 #T2 #HV12 #HT12 #H destruct
 100     lapply (sle_lexs_trans … H2 gV1 ?) /2 width=2 by sor_inv_sle_sn/ #HL12V
 101     lapply (sle_lexs_trans … H2 gT0 ?) /2 width=2 by sor_inv_sle_dx/ -H2 #HL12T
 102     elim (IH … HgV1 … HL12V … HV12) // -HgV1 -HL12V -HV12 #gV2 #HgV2 #HgV21
 103     elim (IH … HgT0 … HL12T … HT12) // -IH -HgT0 -HL12T -HT12 #gT2 #HgT2 #HgT21
 104     elim (sor_isfin_ex gV2 gT2) /2 width=3 by frees_fwd_isfin/
 105     /3 width=10 by frees_flat, monotonic_sle_sor, ex2_intro/
 106   | #HU2 #H destruct -HgV1
 107     lapply (sle_lexs_trans … H2 gT0 ?) /2 width=2 by sor_inv_sle_dx/ -H2 #HL12T
 108     elim (IH … HgT0 … HL12T … HU2) // -L1 -T0 -V1
 109     /4 width=6 by sor_inv_sle_dx, sle_trans, ex2_intro/
 110   | #HU2 #H destruct -HgT0
 111     lapply (sle_lexs_trans … H2 gV1 ?) /2 width=2 by sor_inv_sle_sn/ -H2 #HL12V
 112     elim (IH … HgV1 … HL12V … HU2) // -L1 -T0 -V1
 113     /4 width=6 by sor_inv_sle_sn, sle_trans, ex2_intro/
 114   | #p #V2 #W1 #W2 #T1 #T2 #HV12 #HW12 #HT12 #H0 #H1 #H destruct
 115     elim (frees_inv_bind … HgT0) -HgT0 #gW1 #gT1 #HgW1 #HgT1 #HgT0
 116     lapply (sle_lexs_trans … H2 gV1 ?) /2 width=2 by sor_inv_sle_sn/ #HL12V
 117     lapply (sle_lexs_trans … H2 gT0 ?) /2 width=2 by sor_inv_sle_dx/ -H2 #H2
 118     lapply (sle_lexs_trans … H2 gW1 ?) /2 width=2 by sor_inv_sle_sn/ #HL12W
 119     lapply (sle_lexs_trans … H2 (⫱gT1) ?) /2 width=2 by sor_inv_sle_dx/ -H2 #HL12T
 120     lapply (lexs_inv_tl … (BPair Abst W1) (BPair Abst W2) … HL12T ??) /2 width=1 by ext2_pair, I/ -HL12T #HL12T
 121     elim (sor_isfin_ex gV1 gW1) /2 width=3 by frees_fwd_isfin/ #g0 #Hg0 #_
 122     lapply (sor_assoc_sn … Hg1 … HgT0 … Hg0) -Hg1 -HgT0 #Hg1
 123     lapply (sor_comm … Hg0) -Hg0 #Hg0
 124     elim (IH … HgV1 … HL12V … HV12) // -HgV1 -HL12V -HV12 #gV2 #HgV2 #HgV21
 125     elim (IH … HgW1 … HL12W … HW12) // -HgW1 -HL12W -HW12 #gW2 #HgW2 #HgW21
 126     elim (IH … HgT1 … HL12T … HT12) // -IH -HgT1 -HL12T -HT12 #gT2 #HgT2 #HgT21
 127     elim (sor_isfin_ex (⫱gT2) gV2) /3 width=3 by frees_fwd_isfin, isfin_tl/ #gVT2 #HgVT2 #_
 128     elim (lsubf_beta_tl_dx … HgV2 … HgVT2 … W2) [ |*: /1 width=3 by lsubf_refl/ ] #gT0 #HL2 #HgT02
 129     lapply (lsubf_frees_trans … HgT2 … HL2) -HgT2 -HL2 #HgT0
 130     lapply (sor_comm … HgVT2) -HgVT2 #HgVT2 (**) (* this should be removed *)
 131     elim (sor_isfin_ex gW2 gV2) /2 width=3 by frees_fwd_isfin/ #gV0 #HgV0 #H
 132     elim (sor_isfin_ex gV0 (⫱gT0)) /3 width=3 by frees_fwd_isfin, isfin_tl/ -H #g2 #Hg2 #_
 133     @(ex2_intro … g2) /3 width=5 by frees_flat, frees_bind/ -h -p -G -L1 -L2 -V1 -V2 -W1 -W2 -T1 -T2
 134     @(sor_inv_sle … Hg2) -Hg2
 135     [ /3 width=11 by sor_inv_sle_sn_trans, monotonic_sle_sor/
 136     | @(sle_trans … HgT02) -HgT02
 137       /3 width=8 by monotonic_sle_sor, sor_inv_sle_dx_trans, sle_tl/
 138     ] (**) (* full auto too slow *)
 139   | #p #V2 #V #W1 #W2 #T1 #T2 #HV12 #HV2 #HW12 #HT12 #H0 #H1 #H destruct
 140     elim (frees_inv_bind … HgT0) -HgT0 #gW1 #gT1 #HgW1 #HgT1 #HgT0
 141     lapply (sle_lexs_trans … H2 gV1 ?) /2 width=2 by sor_inv_sle_sn/ #HL12V
 142     lapply (sle_lexs_trans … H2 gT0 ?) /2 width=2 by sor_inv_sle_dx/ -H2 #H2
 143     lapply (sle_lexs_trans … H2 gW1 ?) /2 width=2 by sor_inv_sle_sn/ #HL12W
 144     lapply (sle_lexs_trans … H2 (⫱gT1) ?) /2 width=2 by sor_inv_sle_dx/ -H2 #HL12T
 145     lapply (lexs_inv_tl … (BPair Abbr W1) (BPair Abbr W2) … HL12T ??) /2 width=1 by ext2_pair, I/ -HL12T #HL12T
 146     elim (sor_isfin_ex gV1 gW1) /2 width=3 by frees_fwd_isfin/ #g0 #Hg0 #_
 147     lapply (sor_assoc_sn … Hg1 … HgT0 … Hg0) -Hg1 -HgT0 #Hg1
 148     elim (IH … HgV1 … HL12V … HV12) // -HgV1 -HL12V -HV12 #gV2 #HgV2 #HgV21
 149     elim (IH … HgW1 … HL12W … HW12) // -HgW1 -HL12W -HW12 #gW2 #HgW2 #HgW21
 150     elim (IH … HgT1 … HL12T … HT12) // -IH -HgT1 -HL12T -HT12 #gT2 #HgT2 #HgT21
 151     elim (sor_isfin_ex (↑gV2) gT2) /3 width=3 by frees_fwd_isfin, isfin_push/ #gV0 #HgV0 #H
 152     elim (sor_isfin_ex gW2 (⫱gV0)) /3 width=3 by frees_fwd_isfin, isfin_tl/ -H #g2 #Hg2 #_
 153     elim (sor_isfin_ex gW2 gV2) /2 width=3 by frees_fwd_isfin/ #g #Hg #_
 154     lapply (sor_assoc_sn … Hg2 … (⫱gT2) … Hg) /2 width=1 by sor_tl/ #Hg2
 155     lapply (frees_lifts (Ⓣ) … HgV2 … (L2.ⓓW2) … HV2 ??)
 156     [4: lapply (sor_comm … Hg) |*: /3 width=3 by drops_refl, drops_drop/ ] -V2 (**) (* full auto too slow *)
 157     /4 width=10 by frees_flat, frees_bind, monotonic_sle_sor, sle_tl, ex2_intro/
 158   ]
 159 ]
 160 qed-.
 161
 162 (* Basic_2A1: uses: cpx_frees_trans *)
 163 lemma cpx_fsle_comp: ∀h,G. R_fsle_compatible (cpx h G).
 164 #h #G #L #T1 #T2 #HT12
 165 elim (frees_total L T1) #f1 #Hf1
 166 elim (cpx_frees_conf_lexs … Hf1 L … HT12) -HT12
 167 /3 width=8 by lexs_refl, ext2_refl, ex4_4_intro/
 168 qed-.
 169
 170 (* Basic_2A1: uses: lpx_frees_trans *)
 171 lemma lfpx_fsle_comp: ∀h,G. lfxs_fsle_compatible (cpx h G).
 172 #h #G #L1 #L2 #T * #f1 #Hf1 #HL12
 173 elim (cpx_frees_conf_lexs h … Hf1 … HL12 T) // #f2 #Hf2
 174 lapply (lexs_fwd_length … HL12)
 175 /3 width=8 by lveq_length_eq, ex4_4_intro/ (**) (* full auto fails *)
 176 qed-.
 177
 178 (* Properties with generic extension on referred entries ********************)
 179
 180 (* Note: lemma 1000 *)
 181 (* Basic_2A1: uses: cpx_llpx_sn_conf *)
 182 lemma cpx_lfxs_conf: ∀R,h,G. s_r_confluent1 … (cpx h G) (lfxs R).
 183 #R #h #G #L1 #T1 #T2 #H #L2 * #f1 #Hf1 elim (cpx_frees_conf_lexs … Hf1 L1 … H) -T1
 184 /3 width=5 by lexs_refl, ext2_refl, sle_lexs_trans, ex2_intro/
 185 qed-.