matita/matita/contribs/lambdadelta/basic_2/rt_transition/cpx_lfxs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/relocation/drops_lexs.ma".
  16 include "basic_2/static/frees_drops.ma".
  17 include "basic_2/static/lsubf_frees.ma".
  18 include "basic_2/static/lfxs.ma".
  19 include "basic_2/rt_transition/cpx_drops.ma".
  20 include "basic_2/rt_transition/cpx_ext.ma".
  21
  22 (* UNCOUNTED CONTEXT-SENSITIVE PARALLEL RT-TRANSITION FOR TERMS *************)
  23
  24 (* Properties with context-sensitive free variables *************************)
  25
  26 (* Basic_2A1: uses: lpx_cpx_frees_trans *)
  27 lemma cpx_frees_conf_lexs: ∀h,G,L1,T1,f1. L1 ⊢ 𝐅*⦃T1⦄ ≡ f1 →
  28                            ∀L2. L1 ⪤*[cpx_ext h G, cfull, f1] L2 →
  29                            ∀T2. ⦃G, L1⦄ ⊢ T1 ⬈[h] T2 →
  30                            ∃∃f2. L2 ⊢ 𝐅*⦃T2⦄ ≡ f2 & f2 ⊆ f1.
  31 #h #G #L1 #T1 @(fqup_wf_ind_eq (Ⓣ) … G L1 T1) -G -L1 -T1
  32 #G0 #L0 #U0 #IH #G #L1 * *
  33 [ -IH #s #HG #HL #HU #g1 #H1 #L2 #_ #U2 #H0 destruct
  34   lapply (frees_inv_sort … H1) -H1 #Hg1
  35   elim (cpx_inv_sort1 … H0) -H0 #H destruct
  36   /3 width=3 by frees_sort, sle_refl, ex2_intro/
  37 | #i #HG #HL #HU #g1 #H1 #L2 #H2 #U2 #H0 destruct
  38   elim (frees_inv_lref_drops … H1) -H1 *
  39   [ -IH #f1 #HL1 #Hf1 #H destruct
  40     elim (cpx_inv_lref1_drops … H0) -H0
  41     [ #H destruct
  42       /4 width=9 by frees_atom_drops, drops_atom2_lexs_conf, sle_refl, ex2_intro/
  43     | * -H2 -Hf1 #I #K1 #V1 #V2 #HLK1
  44       lapply (drops_TF … HLK1) -HLK1 #HLK1
  45       lapply (drops_mono … HLK1 … HL1) -L1 #H destruct
  46     ]
  47   | #f1 #I #K1 #V1 #Hf1 #HLK1 #H destruct
  48     elim (cpx_inv_lref1_drops … H0) -H0
  49     [ #H destruct
  50       elim (lexs_drops_conf_next … H2 … HLK1) -H2 [ |*: // ] #Z #K2 #HLK2 #HK12 #H
  51       elim (ext2_inv_pair_sn … H) -H #V2 #HV12 #H destruct
  52       elim (IH … Hf1 … HK12 … HV12) /2 width=2 by fqup_lref/ -L1 -K1 -V1 #f2 #Hf2 #Hf21
  53       /4 width=7 by frees_lref_pushs, frees_pair_drops, drops_refl, sle_pushs, sle_next, ex2_intro/
  54     | * #Z #Y #X #V2 #H #HV12 #HVU2
  55       lapply (drops_mono … H … HLK1) -H #H destruct
  56       elim (lexs_drops_conf_next … H2 … HLK1) -H2 [ |*: // ] #I2 #K2 #HLK2 #HK12 #H
  57       elim (ext2_inv_pair_sn … H) -H #V0 #_ #H destruct
  58       lapply (drops_isuni_fwd_drop2 … HLK2) // -V0 #HLK2
  59       elim (IH … Hf1 … HK12 … HV12) /2 width=2 by fqup_lref/ -I -L1 -K1 -V1 #f2 #Hf2 #Hf21
  60       lapply (frees_lifts … Hf2 … HLK2 … HVU2 ??) /4 width=7 by sle_weak, ex2_intro, sle_pushs/
  61     ]
  62   | #f1 #I #K1 #HLK1 #Hf1 #H destruct
  63     elim (cpx_inv_lref1_drops … H0) -H0
  64     [ -IH #H destruct
  65       elim (lexs_drops_conf_next … H2 … HLK1) -H2 -HLK1 [ |*: // ] #Z #K2 #HLK2 #_ #H
  66       lapply (ext2_inv_unit_sn … H) -H #H destruct
  67       /3 width=3 by frees_unit_drops, sle_refl, ex2_intro/
  68     | * -H2 -Hf1 #Z #Y1 #X1 #X2 #HLY1
  69       lapply (drops_mono … HLK1 … HLY1) -L1 #H destruct
  70     ]
  71   ]
  72 | -IH #l #HG #HL #HU #g1 #H1 #L2 #_ #U2 #H0 destruct
  73   lapply (frees_inv_gref … H1) -H1 #Hg1
  74   lapply (cpx_inv_gref1 … H0) -H0 #H destruct
  75   /3 width=3 by frees_gref, sle_refl, ex2_intro/
  76 | #p #I #V1 #T1 #HG #HL #HU #g1 #H1 #L2 #H2 #U2 #H0 destruct
  77   elim (frees_inv_bind … H1) -H1 #gV1 #gT1 #HgV1 #HgT1 #Hg1
  78   elim (cpx_inv_bind1 … H0) -H0 *
  79   [ #V2 #T2 #HV12 #HT12 #H destruct
  80     lapply (sle_lexs_trans … H2 gV1 ?) /2 width=2 by sor_inv_sle_sn/ #HL12V
  81     lapply (sle_lexs_trans … H2 (⫱gT1) ?) /2 width=2 by sor_inv_sle_dx/ -H2 #HL12T
  82     lapply (lexs_inv_tl … (BPair I V1) (BPair I V2) … HL12T ??) /2 width=1 by ext2_pair/ -HL12T #HL12T
  83     elim (IH … HgV1 … HL12V … HV12) // -HgV1 -HL12V -HV12 #gV2 #HgV2 #HgV21
  84     elim (IH … HgT1 … HL12T … HT12) // -IH -HgT1 -HL12T -HT12 #gT2 #HgT2 #HgT21
  85     elim (sor_isfin_ex gV2 (⫱gT2)) /3 width=3 by frees_fwd_isfin, isfin_tl/
  86     /4 width=10 by frees_bind, monotonic_sle_sor, sle_tl, ex2_intro/
  87   | #T2 #HT12 #HUT2 #H0 #H1 destruct -HgV1
  88     lapply (sle_lexs_trans … H2 (⫱gT1) ?) /2 width=2 by sor_inv_sle_dx/ -H2 #HL12T
  89     lapply (lexs_inv_tl … (BPair Abbr V1) (BPair Abbr V1) … HL12T ??) /2 width=1 by ext2_pair/ -HL12T #HL12T
  90     elim (IH … HgT1 … HL12T … HT12) // -L1 -T1 #gT2 #HgT2 #HgT21
  91     lapply (frees_inv_lifts_SO (Ⓣ) … HgT2 … L2 … HUT2) [ /3 width=1 by drops_refl, drops_drop/ ] -V1 -T2
  92     /5 width=6 by sor_inv_sle_dx, sle_trans, sle_tl, ex2_intro/
  93   ]
  94 | #I #V1 #T0 #HG #HL #HU #g1 #H1 #L2 #H2 #U2 #H0 destruct
  95   elim (frees_inv_flat … H1) -H1 #gV1 #gT0 #HgV1 #HgT0 #Hg1
  96   elim (cpx_inv_flat1 … H0) -H0 *
  97   [ #V2 #T2 #HV12 #HT12 #H destruct
  98     lapply (sle_lexs_trans … H2 gV1 ?) /2 width=2 by sor_inv_sle_sn/ #HL12V
  99     lapply (sle_lexs_trans … H2 gT0 ?) /2 width=2 by sor_inv_sle_dx/ -H2 #HL12T
 100     elim (IH … HgV1 … HL12V … HV12) // -HgV1 -HL12V -HV12 #gV2 #HgV2 #HgV21
 101     elim (IH … HgT0 … HL12T … HT12) // -IH -HgT0 -HL12T -HT12 #gT2 #HgT2 #HgT21
 102     elim (sor_isfin_ex gV2 gT2) /2 width=3 by frees_fwd_isfin/
 103     /3 width=10 by frees_flat, monotonic_sle_sor, ex2_intro/
 104   | #HU2 #H destruct -HgV1
 105     lapply (sle_lexs_trans … H2 gT0 ?) /2 width=2 by sor_inv_sle_dx/ -H2 #HL12T
 106     elim (IH … HgT0 … HL12T … HU2) // -L1 -T0 -V1
 107     /4 width=6 by sor_inv_sle_dx, sle_trans, ex2_intro/
 108   | #HU2 #H destruct -HgT0
 109     lapply (sle_lexs_trans … H2 gV1 ?) /2 width=2 by sor_inv_sle_sn/ -H2 #HL12V
 110     elim (IH … HgV1 … HL12V … HU2) // -L1 -T0 -V1
 111     /4 width=6 by sor_inv_sle_sn, sle_trans, ex2_intro/
 112   | #p #V2 #W1 #W2 #T1 #T2 #HV12 #HW12 #HT12 #H0 #H1 #H destruct
 113     elim (frees_inv_bind … HgT0) -HgT0 #gW1 #gT1 #HgW1 #HgT1 #HgT0
 114     lapply (sle_lexs_trans … H2 gV1 ?) /2 width=2 by sor_inv_sle_sn/ #HL12V
 115     lapply (sle_lexs_trans … H2 gT0 ?) /2 width=2 by sor_inv_sle_dx/ -H2 #H2
 116     lapply (sle_lexs_trans … H2 gW1 ?) /2 width=2 by sor_inv_sle_sn/ #HL12W
 117     lapply (sle_lexs_trans … H2 (⫱gT1) ?) /2 width=2 by sor_inv_sle_dx/ -H2 #HL12T
 118     lapply (lexs_inv_tl … (BPair Abst W1) (BPair Abst W2) … HL12T ??) /2 width=1 by ext2_pair, I/ -HL12T #HL12T
 119     elim (sor_isfin_ex gV1 gW1) /2 width=3 by frees_fwd_isfin/ #g0 #Hg0 #_
 120     lapply (sor_assoc_sn … Hg1 … HgT0 … Hg0) -Hg1 -HgT0 #Hg1
 121     lapply (sor_comm … Hg0) -Hg0 #Hg0
 122     elim (IH … HgV1 … HL12V … HV12) // -HgV1 -HL12V -HV12 #gV2 #HgV2 #HgV21
 123     elim (IH … HgW1 … HL12W … HW12) // -HgW1 -HL12W -HW12 #gW2 #HgW2 #HgW21
 124     elim (IH … HgT1 … HL12T … HT12) // -IH -HgT1 -HL12T -HT12 #gT2 #HgT2 #HgT21
 125     elim (sor_isfin_ex (⫱gT2) gV2) /3 width=3 by frees_fwd_isfin, isfin_tl/ #gVT2 #HgVT2 #_
 126     elim (lsubf_beta_tl_dx … HgV2 … HgVT2 … W2) [ |*: /1 width=3 by lsubf_refl/ ] #gT0 #HL2 #HgT02
 127     lapply (lsubf_frees_trans … HgT2 … HL2) -HgT2 -HL2 #HgT0
 128     lapply (sor_comm … HgVT2) -HgVT2 #HgVT2 (**) (* this should be removed *)
 129     elim (sor_isfin_ex gW2 gV2) /2 width=3 by frees_fwd_isfin/ #gV0 #HgV0 #H
 130     elim (sor_isfin_ex gV0 (⫱gT0)) /3 width=3 by frees_fwd_isfin, isfin_tl/ -H #g2 #Hg2 #_
 131     @(ex2_intro … g2) /3 width=5 by frees_flat, frees_bind/ -h -p -G -L1 -L2 -V1 -V2 -W1 -W2 -T1 -T2
 132     @(sor_inv_sle … Hg2) -Hg2
 133     [ /3 width=11 by sor_inv_sle_sn_trans, monotonic_sle_sor/
 134     | @(sle_trans … HgT02) -HgT02
 135       /3 width=8 by monotonic_sle_sor, sor_inv_sle_dx_trans, sle_tl/
 136     ] (**) (* full auto too slow *)
 137   | #p #V2 #V #W1 #W2 #T1 #T2 #HV12 #HV2 #HW12 #HT12 #H0 #H1 #H destruct
 138     elim (frees_inv_bind … HgT0) -HgT0 #gW1 #gT1 #HgW1 #HgT1 #HgT0
 139     lapply (sle_lexs_trans … H2 gV1 ?) /2 width=2 by sor_inv_sle_sn/ #HL12V
 140     lapply (sle_lexs_trans … H2 gT0 ?) /2 width=2 by sor_inv_sle_dx/ -H2 #H2
 141     lapply (sle_lexs_trans … H2 gW1 ?) /2 width=2 by sor_inv_sle_sn/ #HL12W
 142     lapply (sle_lexs_trans … H2 (⫱gT1) ?) /2 width=2 by sor_inv_sle_dx/ -H2 #HL12T
 143     lapply (lexs_inv_tl … (BPair Abbr W1) (BPair Abbr W2) … HL12T ??) /2 width=1 by ext2_pair, I/ -HL12T #HL12T
 144     elim (sor_isfin_ex gV1 gW1) /2 width=3 by frees_fwd_isfin/ #g0 #Hg0 #_
 145     lapply (sor_assoc_sn … Hg1 … HgT0 … Hg0) -Hg1 -HgT0 #Hg1
 146     elim (IH … HgV1 … HL12V … HV12) // -HgV1 -HL12V -HV12 #gV2 #HgV2 #HgV21
 147     elim (IH … HgW1 … HL12W … HW12) // -HgW1 -HL12W -HW12 #gW2 #HgW2 #HgW21
 148     elim (IH … HgT1 … HL12T … HT12) // -IH -HgT1 -HL12T -HT12 #gT2 #HgT2 #HgT21
 149     elim (sor_isfin_ex (↑gV2) gT2) /3 width=3 by frees_fwd_isfin, isfin_push/ #gV0 #HgV0 #H
 150     elim (sor_isfin_ex gW2 (⫱gV0)) /3 width=3 by frees_fwd_isfin, isfin_tl/ -H #g2 #Hg2 #_
 151     elim (sor_isfin_ex gW2 gV2) /2 width=3 by frees_fwd_isfin/ #g #Hg #_
 152     lapply (sor_assoc_sn … Hg2 … (⫱gT2) … Hg) /2 width=1 by sor_tl/ #Hg2
 153     lapply (frees_lifts (Ⓣ) … HgV2 … (L2.ⓓW2) … HV2 ??)
 154     [4: lapply (sor_comm … Hg) |*: /3 width=3 by drops_refl, drops_drop/ ] -V2 (**) (* full auto too slow *)
 155     /4 width=10 by frees_flat, frees_bind, monotonic_sle_sor, sle_tl, ex2_intro/
 156   ]
 157 ]
 158 qed-.
 159
 160 (* Basic_2A1: uses: cpx_frees_trans *)
 161 lemma cpx_frees_conf: ∀h,G. R_frees_confluent (cpx h G).
 162 /4 width=7 by cpx_frees_conf_lexs, lexs_refl, ext2_refl/ qed-.
 163
 164 (* Basic_2A1: uses: lpx_frees_trans *)
 165 lemma lfpx_frees_conf: ∀h,G. lexs_frees_confluent (cpx_ext h G) cfull.
 166 /2 width=7 by cpx_frees_conf_lexs/ qed-.
 167
 168 (* Properties with generic extension on referred entries ********************)
 169
 170 (* Note: lemma 1000 *)
 171 (* Basic_2A1: uses: cpx_llpx_sn_conf *)
 172 lemma cpx_lfxs_conf: ∀R,h,G. s_r_confluent1 … (cpx h G) (lfxs R).
 173 #R #h #G #L1 #T1 #T2 #H #L2 * #f1 #Hf1 elim (cpx_frees_conf … Hf1 … H) -T1
 174 /3 width=5 by sle_lexs_trans, ex2_intro/
 175 qed-.