matita/matita/contribs/lambdadelta/basic_2/rt_transition/fpb.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/predsubty_6.ma".
  16 include "static_2/s_transition/fquq.ma".
  17 include "basic_2/rt_transition/rpx.ma".
  18
  19 (* PARALLEL RST-TRANSITION FOR CLOSURES *************************************)
  20
  21 (* Basic_2A1: uses: fpbq *)
  22 definition fpb (G1) (L1) (T1) (G2) (L2) (T2): Prop ≝
  23            ∃∃L,T. ❪G1,L1,T1❫ ⬂⸮ ❪G2,L,T❫ & ❪G2,L❫ ⊢ T ⬈ T2 & ❪G2,L❫ ⊢ ⬈[T] L2.
  24
  25 interpretation
  26   "parallel rst-transition (closure)"
  27   'PRedSubTy G1 L1 T1 G2 L2 T2 = (fpb G1 L1 T1 G2 L2 T2).
  28
  29 (* Basic properties *********************************************************)
  30
  31 lemma fpb_intro (G1) (L1) (T1) (G2) (L2) (T2):
  32       ∀L,T. ❪G1,L1,T1❫ ⬂⸮ ❪G2,L,T❫ → ❪G2,L❫ ⊢ T ⬈ T2 →
  33       ❪G2,L❫ ⊢ ⬈[T] L2 → ❪G1,L1,T1❫ ≽ ❪G2,L2,T2❫.
  34 /2 width=5 by ex3_2_intro/ qed.
  35
  36 lemma rpx_fpb (G) (T):
  37       ∀L1,L2. ❪G,L1❫ ⊢ ⬈[T] L2 → ❪G,L1,T❫ ≽ ❪G,L2,T❫.
  38 /2 width=5 by fpb_intro/ qed.
  39
  40 (* Basic inversion lemmas ***************************************************)
  41
  42 lemma fpb_inv_gen (G1) (L1) (T1) (G2) (L2) (T2):
  43       ❪G1,L1,T1❫ ≽ ❪G2,L2,T2❫ →
  44       ∃∃L,T. ❪G1,L1,T1❫ ⬂⸮ ❪G2,L,T❫ & ❪G2,L❫ ⊢ T ⬈ T2 & ❪G2,L❫ ⊢ ⬈[T] L2.
  45 // qed-.
  46
  47 (* Basic_2A1: removed theorems 2:
  48               fpbq_fpbqa fpbqa_inv_fpbq
  49 *)