matita/matita/contribs/lambdadelta/basic_2/rt_transition/fpb_feqx.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/s_transition/fqu_teqx.ma".
  16 include "static_2/static/feqx.ma".
  17 include "basic_2/rt_transition/fpb_reqx.ma".
  18
  19 (* PROPER PARALLEL RST-TRANSITION FOR CLOSURES ******************************)
  20
  21 (* Properties with degree-based equivalence for closures ********************)
  22
  23 (* Basic_2A1: uses: fleq_fpb_trans *)
  24 lemma feqx_fpb_trans:
  25       ∀F1,F2,K1,K2,T1,T2. ❪F1,K1,T1❫ ≛ ❪F2,K2,T2❫ →
  26       ∀G2,L2,U2. ❪F2,K2,T2❫ ≻ ❪G2,L2,U2❫ →
  27       ∃∃G1,L1,U1. ❪F1,K1,T1❫ ≻ ❪G1,L1,U1❫ & ❪G1,L1,U1❫ ≛ ❪G2,L2,U2❫.
  28 #F1 #F2 #K1 #K2 #T1 #T2 * -F2 -K2 -T2
  29 #K2 #T2 #HK12 #HT12 #G2 #L2 #U2 #H12
  30 elim (teqx_fpb_trans … HT12 … H12) -T2 #K0 #T0 #H #HT0 #HK0
  31 elim (reqx_fpb_trans … HK12 … H) -K2 #L0 #U0 #H #HUT0 #HLK0
  32 @(ex2_3_intro … H) -H (**) (* full auto too slow *)
  33 /4 width=3 by feqx_intro_dx, reqx_trans, teqx_reqx_conf, teqx_trans/
  34 qed-.
  35
  36 (* Inversion lemmas with degree-based equivalence for closures **************)
  37
  38 (* Basic_2A1: uses: fpb_inv_fleq *)
  39 lemma fpb_inv_feqx:
  40       ∀G1,G2,L1,L2,T1,T2. ❪G1,L1,T1❫ ≻ ❪G2,L2,T2❫ →
  41       ❪G1,L1,T1❫ ≛ ❪G2,L2,T2❫ → ⊥.
  42 #G1 #G2 #L1 #L2 #T1 #T2 * -G2 -L2 -T2
  43 [ #G2 #L2 #T2 #H12 #H elim (feqx_inv_gen_sn … H) -H
  44   /3 width=11 by reqx_fwd_length, fqu_inv_teqx/
  45 | #T2 #_ #HnT #H elim (feqx_inv_gen_sn … H) -H /2 width=1 by/
  46 | #L2 #_ #HnL #H elim (feqx_inv_gen_sn … H) -H /2 width=1 by/
  47 ]
  48 qed-.