matita/matita/contribs/lambdadelta/basic_2/rt_transition/fpb_lpx.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/rt_transition/rpx_lpx.ma".
  16 include "basic_2/rt_transition/fpb.ma".
  17
  18 (* PARALLEL RST-TRANSITION FOR CLOSURES *************************************)
  19
  20 (* Properties with extended rt-transition for full local envs ***************)
  21
  22 (* Basic_2A1: uses: fpbq_lpx *)
  23 lemma lpx_fpb (G) (T):
  24       ∀L1,L2. ❪G,L1❫ ⊢ ⬈ L2 → ❪G,L1,T❫ ≽ ❪G,L2,T❫.
  25 /3 width=1 by rpx_fpb, lpx_rpx/ qed.
  26
  27 lemma fpb_intro_req (G1) (G2) (L1) (L2) (T1) (T2):
  28       ∀L0,L,T. ❪G1,L1,T1❫ ⬂⸮ ❪G2,L,T❫ → ❪G2,L❫ ⊢ T ⬈ T2 →
  29       L ≡[T] L0 → ❪G2,L0❫ ⊢ ⬈ L2 → ❪G1,L1,T1❫ ≽ ❪G2,L2,T2❫.
  30 /4 width=10 by fpb_intro, lpx_rpx, reqg_rpx_trans/ qed.
  31
  32 (* Inversion lemmas with extended rt-transition for full local envs *********)
  33
  34 lemma fpb_inv_req (G1) (G2) (L1) (L2) (T1) (T2):
  35       ❪G1,L1,T1❫ ≽ ❪G2,L2,T2❫ →
  36       ∃∃L0,L,T. ❪G1,L1,T1❫ ⬂⸮ ❪G2,L,T❫ & ❪G2,L❫ ⊢ T ⬈ T2 & L ≡[T] L0 & ❪G2,L0❫ ⊢ ⬈ L2.
  37 #G1 #G2 #L1 #L2 #T1 #T2 * #L #T #H1 #HT2 #HL2
  38 elim (rpx_inv_req_lpx … HL2) -HL2 #L0 #HL0 #HL02
  39 /2 width=7 by ex4_3_intro/
  40 qed-.
  41
  42 (* Forward lemmas with extended rt-transition for full local envs ***********)
  43
  44 lemma fpb_fwd_req (G1) (G2) (L1) (L2) (T1) (T2):
  45       ❪G1,L1,T1❫ ≽ ❪G2,L2,T2❫ →
  46       ∃∃L0,L,T. ❪G1,L1,T1❫ ⬂⸮ ❪G2,L,T❫ & ❪G2,L❫ ⊢ T ⬈ T2 & ❪G2,L❫ ⊢ ⬈ L0 & L0 ≡[T] L2.
  47 #G1 #G2 #L1 #L2 #T1 #T2 * #L #T #H1 #HT2 #HL2
  48 elim (rpx_fwd_lpx_req … HL2) -HL2 #L0 #HL0 #HL02
  49 /2 width=7 by ex4_3_intro/
  50 qed-.