matita/matita/contribs/lambdadelta/basic_2/rt_transition/fpb_rdeq.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/static/rdeq_fqus.ma".
  16 include "basic_2/rt_transition/cpx_rdeq.ma".
  17 include "basic_2/rt_transition/lpx_rdeq.ma".
  18 include "basic_2/rt_transition/fpb.ma".
  19
  20 (* PROPER PARALLEL RST-TRANSITION FOR CLOSURES ******************************)
  21
  22 (* Properties with degree-based equivalence for local environments **********)
  23
  24 lemma tdeq_fpb_trans: ∀h,o,U2,U1. U2 ≛[h, o] U1 →
  25                       ∀G1,G2,L1,L2,T1. ⦃G1, L1, U1⦄ ≻[h, o] ⦃G2, L2, T1⦄ →
  26                       ∃∃L,T2. ⦃G1, L1, U2⦄ ≻[h, o] ⦃G2, L, T2⦄ & T2 ≛[h, o] T1 & L ≛[h, o, T1] L2.
  27 #h #o #U2 #U1 #HU21 #G1 #G2 #L1 #L2 #T1 * -G2 -L2 -T1
  28 [ #G2 #L2 #T1 #H
  29   elim (tdeq_fqu_trans … H … HU21) -H
  30   /3 width=5 by fpb_fqu, ex3_2_intro/
  31 | #T1 #HUT1 #HnUT1
  32   elim (tdeq_cpx_trans … HU21 … HUT1) -HUT1
  33   /6 width=5 by fpb_cpx, tdeq_canc_sn, tdeq_trans, ex3_2_intro/
  34 | /6 width=5 by fpb_lpx, rpx_tdeq_div, tdeq_rdeq_conf, ex3_2_intro/
  35 ]
  36 qed-.
  37
  38 (* Basic_2A1: was just: lleq_fpb_trans *)
  39 lemma rdeq_fpb_trans: ∀h,o,F,K1,K2,T. K1 ≛[h, o, T] K2 →
  40                       ∀G,L2,U. ⦃F, K2, T⦄ ≻[h, o] ⦃G, L2, U⦄ →
  41                       ∃∃L1,U0. ⦃F, K1, T⦄ ≻[h, o] ⦃G, L1, U0⦄ & U0 ≛[h, o] U & L1 ≛[h, o, U] L2.
  42 #h #o #F #K1 #K2 #T #HT #G #L2 #U * -G -L2 -U
  43 [ #G #L2 #U #H2 elim (rdeq_fqu_trans … H2 … HT) -K2
  44   /3 width=5 by fpb_fqu, ex3_2_intro/
  45 | #U #HTU #HnTU elim (rdeq_cpx_trans … HT … HTU) -HTU
  46   /5 width=10 by fpb_cpx, cpx_rdeq_conf_sn, tdeq_trans, tdeq_rdeq_conf, ex3_2_intro/
  47 | #L2 #HKL2 #HnKL2 elim (rdeq_lpx_trans … HKL2 … HT) -HKL2
  48   /6 width=5 by fpb_lpx, (* 2x *) rdeq_canc_sn, ex3_2_intro/
  49 ]
  50 qed-.