matita/matita/contribs/lambdadelta/basic_2/rt_transition/fpb_reqg.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/static/reqg_fqus.ma".
  16 include "basic_2/rt_transition/cpx_reqg.ma".
  17 include "basic_2/rt_transition/lpx_reqg.ma".
  18 include "basic_2/rt_transition/fpb.ma".
  19
  20 (* PROPER PARALLEL RST-TRANSITION FOR CLOSURES ******************************)
  21
  22 (* Properties with generic equivalence for local environments ***************)
  23
  24 lemma teqg_fpb_trans (S):
  25       reflexive … S → symmetric … S →
  26       ∀U2,U1. U2 ≛[S] U1 →
  27       ∀G1,G2,L1,L2,T1. ❪G1,L1,U1❫ ≻ ❪G2,L2,T1❫ →
  28       ∃∃L,T2. ❪G1,L1,U2❫ ≻ ❪G2,L,T2❫ & T2 ≛[S] T1 & L ≛[S,T1] L2.
  29 #S #H1S #H2S #U2 #U1 #HU21 #G1 #G2 #L1 #L2 #T1 * -G2 -L2 -T1
  30 [ #G2 #L2 #T1 #H
  31   elim (teqg_fqu_trans … H … HU21) -H
  32   /3 width=5 by fpb_fqu, ex3_2_intro/
  33 | #T1 #HUT1 #HnUT1
  34   lapply (teqg_cpx_trans … HU21 … HUT1) -HUT1
  35   /6 width=5 by fpb_cpx, reqg_refl, teqg_teqx, teqg_canc_sn, teqg_refl, ex3_2_intro/
  36 | /5 width=5 by fpb_lpx, teqg_reqg_conf_sn, reqg_refl, ex3_2_intro/
  37 ]
  38 qed-.
  39
  40 (* Basic_2A1: was just: lleq_fpb_trans *)
  41 lemma reqg_fpb_trans (S):
  42       reflexive … S → symmetric … S →
  43       ∀F,K1,K2,T. K1 ≛[S,T] K2 →
  44       ∀G,L2,U. ❪F,K2,T❫ ≻ ❪G,L2,U❫ →
  45       ∃∃L1,U0. ❪F,K1,T❫ ≻ ❪G,L1,U0❫ & U0 ≛[S] U & L1 ≛[S,U] L2.
  46 #S #H1S #H2S #F #K1 #K2 #T #HT #G #L2 #U * -G -L2 -U
  47 [ #G #L2 #U #H2 elim (reqg_fqu_trans … H2 … HT) -K2
  48   /3 width=5 by fpb_fqu, ex3_2_intro/
  49 | #U #HTU #HnTU lapply (reqg_cpx_trans … HT … HTU) -HTU //
  50   /4 width=8 by fpb_cpx, cpx_reqg_conf_sn, teqg_refl, ex3_2_intro/
  51 | #L2 #HKL2 #HnKL2 elim (reqg_lpx_trans … HKL2 … HT) -HKL2 //
  52   /6 width=9 by fpb_lpx, reqg_reqx, reqg_repl, teqg_refl, ex3_2_intro/
  53 ]
  54 qed-.