matita/matita/contribs/lambdadelta/basic_2/rt_transition/fpbq.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/predsubty_7.ma".
  16 include "static_2/static/feqx.ma".
  17 include "static_2/s_transition/fquq.ma".
  18 include "basic_2/rt_transition/lpr_lpx.ma".
  19
  20 (* PARALLEL RST-TRANSITION FOR CLOSURES *************************************)
  21
  22 (* Basic_2A1: includes: fleq_fpbq fpbq_lleq *)
  23 inductive fpbq (h) (G1) (L1) (T1): relation3 genv lenv term ≝
  24 | fpbq_fquq: ∀G2,L2,T2. ❪G1,L1,T1❫ ⬂⸮ ❪G2,L2,T2❫ → fpbq h G1 L1 T1 G2 L2 T2
  25 | fpbq_cpx : ∀T2. ❪G1,L1❫ ⊢ T1 ⬈[h] T2 → fpbq h G1 L1 T1 G1 L1 T2
  26 | fpbq_lpx : ∀L2. ❪G1,L1❫ ⊢ ⬈[h] L2 → fpbq h G1 L1 T1 G1 L2 T1
  27 | fpbq_feqx: ∀G2,L2,T2. ❪G1,L1,T1❫ ≛ ❪G2,L2,T2❫ → fpbq h G1 L1 T1 G2 L2 T2
  28 .
  29
  30 interpretation
  31    "parallel rst-transition (closure)"
  32    'PRedSubTy h G1 L1 T1 G2 L2 T2 = (fpbq h G1 L1 T1 G2 L2 T2).
  33
  34 (* Basic properties *********************************************************)
  35
  36 lemma fpbq_refl (h): tri_reflexive … (fpbq h).
  37 /2 width=1 by fpbq_cpx/ qed.
  38
  39 (* Basic_2A1: includes: cpr_fpbq *)
  40 lemma cpm_fpbq (n) (h) (G) (L): ∀T1,T2. ❪G,L❫ ⊢ T1 ➡[n,h] T2 → ❪G,L,T1❫ ≽[h] ❪G,L,T2❫.
  41 /3 width=2 by fpbq_cpx, cpm_fwd_cpx/ qed.
  42
  43 lemma lpr_fpbq (h) (G) (T): ∀L1,L2. ❪G,L1❫ ⊢ ➡[h] L2 → ❪G,L1,T❫ ≽[h] ❪G,L2,T❫.
  44 /3 width=1 by fpbq_lpx, lpr_fwd_lpx/ qed.
  45
  46 (* Basic_2A1: removed theorems 2:
  47               fpbq_fpbqa fpbqa_inv_fpbq
  48 *)