matita/matita/contribs/lambdadelta/basic_2/rt_transition/fpbq_fpb.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/rt_transition/fpb_feqx.ma".
  16 include "basic_2/rt_transition/fpbq.ma".
  17
  18 (* PARALLEL RST-TRANSITION FOR CLOSURES *************************************)
  19
  20 (* Properties with proper parallel rst-transition for closures **************)
  21
  22 lemma fpb_fpbq:
  23       ∀G1,G2,L1,L2,T1,T2. ❪G1,L1,T1❫ ≻ ❪G2,L2,T2❫ →
  24       ❪G1,L1,T1❫ ≽ ❪G2,L2,T2❫.
  25 #G1 #G2 #L1 #L2 #T1 #T2 * -G2 -L2 -T2
  26 /3 width=1 by fpbq_fquq, fpbq_cpx, fpbq_lpx, fqu_fquq/
  27 qed.
  28
  29 (* Basic_2A1: fpb_fpbq_alt *)
  30 lemma fpb_fpbq_fneqx:
  31       ∀G1,G2,L1,L2,T1,T2. ❪G1,L1,T1❫ ≻ ❪G2,L2,T2❫ →
  32       ∧∧ ❪G1,L1,T1❫ ≽ ❪G2,L2,T2❫ & (❪G1,L1,T1❫ ≛ ❪G2,L2,T2❫ → ⊥).
  33 /3 width=10 by fpb_fpbq, fpb_inv_feqx, conj/ qed-.
  34
  35 (* Inversrion lemmas with proper parallel rst-transition for closures *******)
  36
  37 (* Basic_2A1: uses: fpbq_ind_alt *)
  38 lemma fpbq_inv_fpb:
  39       ∀G1,G2,L1,L2,T1,T2. ❪G1,L1,T1❫ ≽ ❪G2,L2,T2❫ →
  40       ∨∨ ❪G1,L1,T1❫ ≛ ❪G2,L2,T2❫
  41        | ❪G1,L1,T1❫ ≻ ❪G2,L2,T2❫.
  42 #G1 #G2 #L1 #L2 #T1 #T2 * -G2 -L2 -T2
  43 [ #G2 #L2 #T2 * [2: * #H1 #H2 #H3 destruct ]
  44   /3 width=1 by fpb_fqu, feqx_intro_sn, or_intror, or_introl/
  45 | #T2 #H elim (teqx_dec T1 T2)
  46   /4 width=1 by fpb_cpx, feqx_intro_sn, or_intror, or_introl/
  47 | #L2 elim (reqx_dec L1 L2 T1)
  48   /4 width=1 by fpb_lpx, feqx_intro_sn, or_intror, or_introl/
  49 | /2 width=1 by or_introl/
  50 ]
  51 qed-.
  52
  53 (* Basic_2A1: fpbq_inv_fpb_alt *)
  54 lemma fpbq_fneqx_inv_fpb:
  55       ∀G1,G2,L1,L2,T1,T2. ❪G1,L1,T1❫ ≽ ❪G2,L2,T2❫ →
  56       (❪G1,L1,T1❫ ≛ ❪G2,L2,T2❫ → ⊥) → ❪G1,L1,T1❫ ≻ ❪G2,L2,T2❫.
  57 #G1 #G2 #L1 #L2 #T1 #T2 #H #H0
  58 elim (fpbq_inv_fpb … H) -H // #H elim H0 -H0 //
  59 qed-.