matita/matita/contribs/lambdadelta/basic_2/rt_transition/lfpx.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/predtysn_5.ma".
  16 include "basic_2/static/lfxs.ma".
  17 include "basic_2/rt_transition/cpx.ma".
  18
  19 (* UNCOUNTED PARALLEL RT-TRANSITION FOR LOCAL ENV.S ON REFERRED ENTRIES *****)
  20
  21 definition lfpx: sh → genv → relation3 term lenv lenv ≝
  22                  λh,G. lfxs (cpx h G).
  23
  24 interpretation
  25    "uncounted parallel rt-transition on referred entries (local environment)"
  26    'PRedTySn h T G L1 L2 = (lfpx h G T L1 L2).
  27
  28 (* Basic properties ***********************************************************)
  29
  30 lemma lfpx_atom: ∀h,I,G. ⦃G, ⋆⦄ ⊢ ⬈[h, ⓪{I}] ⋆.
  31 /2 width=1 by lfxs_atom/ qed.
  32
  33 lemma lfpx_sort: ∀h,I,G,L1,L2,V1,V2,s.
  34                  ⦃G, L1⦄ ⊢ ⬈[h, ⋆s] L2 → ⦃G, L1.ⓑ{I}V1⦄ ⊢ ⬈[h, ⋆s] L2.ⓑ{I}V2.
  35 /2 width=1 by lfxs_sort/ qed.
  36
  37 lemma lfpx_zero: ∀h,I,G,L1,L2,V.
  38                  ⦃G, L1⦄ ⊢ ⬈[h, V] L2 → ⦃G, L1.ⓑ{I}V⦄ ⊢ ⬈[h, #0] L2.ⓑ{I}V.
  39 /2 width=1 by lfxs_zero/ qed.
  40
  41 lemma lfpx_lref: ∀h,I,G,L1,L2,V1,V2,i.
  42                  ⦃G, L1⦄ ⊢ ⬈[h, #i] L2 → ⦃G, L1.ⓑ{I}V1⦄ ⊢ ⬈[h, #⫯i] L2.ⓑ{I}V2.
  43 /2 width=1 by lfxs_lref/ qed.
  44
  45 lemma lfpx_gref: ∀h,I,G,L1,L2,V1,V2,l.
  46                  ⦃G, L1⦄ ⊢ ⬈[h, §l] L2 → ⦃G, L1.ⓑ{I}V1⦄ ⊢ ⬈[h, §l] L2.ⓑ{I}V2.
  47 /2 width=1 by lfxs_gref/ qed.
  48
  49 lemma lfpx_pair_repl_dx: ∀h,I,G,L1,L2,T,V,V1.
  50                          ⦃G, L1.ⓑ{I}V⦄ ⊢ ⬈[h, T] L2.ⓑ{I}V1 →
  51                          ∀V2. ⦃G, L1⦄ ⊢ V ⬈[h] V2 →
  52                          ⦃G, L1.ⓑ{I}V⦄ ⊢ ⬈[h, T] L2.ⓑ{I}V2.
  53 /2 width=2 by lfxs_pair_repl_dx/ qed-.
  54
  55 (* Basic inversion lemmas ***************************************************)
  56
  57 lemma lfpx_inv_atom_sn: ∀h,I,G,Y2. ⦃G, ⋆⦄ ⊢ ⬈[h, ⓪{I}] Y2 → Y2 = ⋆.
  58 /2 width=3 by lfxs_inv_atom_sn/ qed-.
  59
  60 lemma lfpx_inv_atom_dx: ∀h,I,G,Y1. ⦃G, Y1⦄ ⊢ ⬈[h, ⓪{I}] ⋆ → Y1 = ⋆.
  61 /2 width=3 by lfxs_inv_atom_dx/ qed-.
  62
  63 lemma lfpx_inv_zero: ∀h,G,Y1,Y2. ⦃G, Y1⦄ ⊢ ⬈[h, #0] Y2 →
  64                      (Y1 = ⋆ ∧ Y2 = ⋆) ∨
  65                      ∃∃I,L1,L2,V1,V2. ⦃G, L1⦄ ⊢ ⬈[h, V1] L2 &
  66                                       ⦃G, L1⦄ ⊢ V1 ⬈[h] V2 &
  67                                       Y1 = L1.ⓑ{I}V1 & Y2 = L2.ⓑ{I}V2.
  68 /2 width=1 by lfxs_inv_zero/ qed-.
  69
  70 lemma lfpx_inv_lref: ∀h,G,Y1,Y2,i. ⦃G, Y1⦄ ⊢ ⬈[h, #⫯i] Y2 →
  71                      (Y1 = ⋆ ∧ Y2 = ⋆) ∨
  72                      ∃∃I,L1,L2,V1,V2. ⦃G, L1⦄ ⊢ ⬈[h, #i] L2 &
  73                                       Y1 = L1.ⓑ{I}V1 & Y2 = L2.ⓑ{I}V2.
  74 /2 width=1 by lfxs_inv_lref/ qed-.
  75
  76 lemma lfpx_inv_bind: ∀h,p,I,G,L1,L2,V,T. ⦃G, L1⦄ ⊢ ⬈[h, ⓑ{p,I}V.T] L2 →
  77                      ⦃G, L1⦄ ⊢ ⬈[h, V] L2 ∧ ⦃G, L1.ⓑ{I}V⦄ ⊢ ⬈[h, T] L2.ⓑ{I}V.
  78 /2 width=2 by lfxs_inv_bind/ qed-.
  79
  80 lemma lfpx_inv_flat: ∀h,I,G,L1,L2,V,T. ⦃G, L1⦄ ⊢ ⬈[h, ⓕ{I}V.T] L2 →
  81                      ⦃G, L1⦄ ⊢ ⬈[h, V] L2 ∧ ⦃G, L1⦄ ⊢ ⬈[h, T] L2.
  82 /2 width=2 by lfxs_inv_flat/ qed-.
  83
  84 (* Advanced inversion lemmas ************************************************)
  85
  86 lemma lfpx_inv_zero_pair_sn: ∀h,I,G,Y2,L1,V1. ⦃G, L1.ⓑ{I}V1⦄ ⊢ ⬈[h, #0] Y2 →
  87                              ∃∃L2,V2. ⦃G, L1⦄ ⊢ ⬈[h, V1] L2 & ⦃G, L1⦄ ⊢ V1 ⬈[h] V2 &
  88                                       Y2 = L2.ⓑ{I}V2.
  89 /2 width=1 by lfxs_inv_zero_pair_sn/ qed-.
  90
  91 lemma lfpx_inv_zero_pair_dx: ∀h,I,G,Y1,L2,V2. ⦃G, Y1⦄ ⊢ ⬈[h, #0] L2.ⓑ{I}V2 →
  92                              ∃∃L1,V1. ⦃G, L1⦄ ⊢ ⬈[h, V1] L2 & ⦃G, L1⦄ ⊢ V1 ⬈[h] V2 &
  93                                       Y1 = L1.ⓑ{I}V1.
  94 /2 width=1 by lfxs_inv_zero_pair_dx/ qed-.
  95
  96 lemma lfpx_inv_lref_pair_sn: ∀h,I,G,Y2,L1,V1,i. ⦃G, L1.ⓑ{I}V1⦄ ⊢ ⬈[h, #⫯i] Y2 →
  97                              ∃∃L2,V2. ⦃G, L1⦄ ⊢ ⬈[h, #i] L2 & Y2 = L2.ⓑ{I}V2.
  98 /2 width=2 by lfxs_inv_lref_pair_sn/ qed-.
  99
 100 lemma lfpx_inv_lref_pair_dx: ∀h,I,G,Y1,L2,V2,i. ⦃G, Y1⦄ ⊢ ⬈[h, #⫯i] L2.ⓑ{I}V2 →
 101                              ∃∃L1,V1. ⦃G, L1⦄ ⊢ ⬈[h, #i] L2 & Y1 = L1.ⓑ{I}V1.
 102 /2 width=2 by lfxs_inv_lref_pair_dx/ qed-.
 103
 104 (* Basic forward lemmas *****************************************************)
 105
 106 lemma lfpx_fwd_bind_sn: ∀h,p,I,G,L1,L2,V,T.
 107                         ⦃G, L1⦄ ⊢ ⬈[h, ⓑ{p,I}V.T] L2 → ⦃G, L1⦄ ⊢ ⬈[h, V] L2.
 108 /2 width=4 by lfxs_fwd_bind_sn/ qed-.
 109
 110 lemma lfpx_fwd_bind_dx: ∀h,p,I,G,L1,L2,V,T.
 111                         ⦃G, L1⦄ ⊢ ⬈[h, ⓑ{p,I}V.T] L2 → ⦃G, L1.ⓑ{I}V⦄ ⊢ ⬈[h, T] L2.ⓑ{I}V.
 112 /2 width=2 by lfxs_fwd_bind_dx/ qed-.
 113
 114 lemma lfpx_fwd_flat_sn: ∀h,I,G,L1,L2,V,T.
 115                         ⦃G, L1⦄ ⊢ ⬈[h, ⓕ{I}V.T] L2 → ⦃G, L1⦄ ⊢ ⬈[h, V] L2.
 116 /2 width=3 by lfxs_fwd_flat_sn/ qed-.
 117
 118 lemma lfpx_fwd_flat_dx: ∀h,I,G,L1,L2,V,T.
 119                         ⦃G, L1⦄ ⊢ ⬈[h, ⓕ{I}V.T] L2 → ⦃G, L1⦄ ⊢ ⬈[h, T] L2.
 120 /2 width=3 by lfxs_fwd_flat_dx/ qed-.
 121
 122 lemma lfpx_fwd_pair_sn: ∀h,I,G,L1,L2,V,T.
 123                         ⦃G, L1⦄ ⊢ ⬈[h, ②{I}V.T] L2 → ⦃G, L1⦄ ⊢ ⬈[h, V] L2.
 124 /2 width=3 by lfxs_fwd_pair_sn/ qed-.
 125
 126 (* Basic_2A1: removed theorems 14:
 127               lpx_refl lpx_pair lpx_fwd_length
 128               lpx_inv_atom1 lpx_inv_pair1 lpx_inv_atom2 lpx_inv_pair2 lpx_inv_pair
 129               lpx_drop_conf drop_lpx_trans lpx_drop_trans_O1
 130               lpx_cpx_frees_trans cpx_frees_trans lpx_frees_trans
 131 *)