matita/matita/contribs/lambdadelta/basic_2/rt_transition/lfpx_frees.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/relocation/drops_lexs.ma".
  16 include "basic_2/s_computation/fqup_weight.ma".
  17 include "basic_2/static/frees_drops.ma".
  18 include "basic_2/static/lsubf_frees.ma".
  19 include "basic_2/static/lfxs.ma".
  20 include "basic_2/rt_transition/cpx_drops.ma".
  21
  22 (* UNCOUNTED PARALLEL RT-TRANSITION FOR LOCAL ENV.S ON REFERRED ENTRIES *****)
  23
  24 (* Properties with context-sensitive free variables *************************)
  25
  26 axiom pippo: ∀RN,RP,L1,i. ⬇*[Ⓕ, 𝐔❴i❵] L1 ≡ ⋆ →
  27              ∀f,L2. L1 ⦻*[RN, RP, f] L2 →
  28              ⬇*[Ⓕ, 𝐔❴i❵] L2 ≡ ⋆.
  29 (*
  30 #RN #RP #L1 #i #H1 #f #L2 #H2
  31 lapply (lexs_co_dropable_sn … H1 … H2) // -HL1 -H2
  32 *)
  33
  34
  35 axiom frees_inv_lifts_SO: ∀b,f,L,U. L ⊢ 𝐅*⦃U⦄ ≡ f →
  36                           ∀K. ⬇*[b, 𝐔❴1❵] L ≡ K → ∀T. ⬆*[1] T ≡ U →
  37                           K ⊢ 𝐅*⦃T⦄ ≡ ⫱f.
  38
  39 axiom frees_pair_flat: ∀L,T,f1,I1,V1. L.ⓑ{I1}V1 ⊢ 𝐅*⦃T⦄ ≡ f1 →
  40                        ∀f2,I2,V2. L.ⓑ{I2}V2 ⊢ 𝐅*⦃T⦄ ≡ f2 →
  41                        ∀f0. f1 ⋓ f2 ≡ f0 →
  42                        ∀I0,I. L.ⓑ{I0}ⓕ{I}V1.V2 ⊢ 𝐅*⦃T⦄ ≡ f0.
  43
  44 (* Basic_2A1: was: lpx_cpx_frees_trans *)
  45 lemma cpx_frees_conf_lfpx: ∀h,G,L1,T1,f1. L1 ⊢ 𝐅*⦃T1⦄ ≡ f1 →
  46                            ∀L2. L1 ⦻*[cpx h G, cfull, f1] L2 →
  47                            ∀T2. ⦃G, L1⦄ ⊢ T1 ⬈[h] T2 →
  48                            ∃∃f2. L2 ⊢ 𝐅*⦃T2⦄ ≡ f2 & f2 ⊆ f1.
  49 #h #G #L1 #T1 @(fqup_wf_ind_eq … G L1 T1) -G -L1 -T1
  50 #G0 #L0 #U0 #IH #G #L1 * *
  51 [ -IH #s #HG #HL #HU #g1 #H1 #L2 #_ #U2 #H0 destruct
  52   lapply (frees_inv_sort … H1) -H1 #Hg1
  53   elim (cpx_inv_sort1 … H0) -H0 #H destruct
  54   /3 width=3 by frees_sort_gen, sle_refl, ex2_intro/
  55 | #i #HG #HL #HU #g1 #H1 #L2 #H2 #U2 #H0 destruct
  56   elim (frees_inv_lref_drops … H1) -H1 *
  57   [ -IH #HL1 #Hg1
  58     elim (cpx_inv_lref1_drops … H0) -H0
  59     [ #H destruct lapply (pippo … HL1 … H2) -HL1 -H2
  60       /3 width=3 by frees_lref_atom, sle_refl, ex2_intro/
  61     | * -H2 -Hg1 #I #K1 #V1 #V2 #HLK1
  62       lapply (drops_TF … HLK1) -HLK1 #HLK1
  63       lapply (drops_mono … HLK1 … HL1) -L1 #H destruct
  64     ]
  65   | #f1 #I #K1 #V1 #Hf1 #HLK1 #H destruct
  66     elim (cpx_inv_lref1_drops … H0) -H0
  67     [ #H destruct
  68       elim (lexs_drops_conf_next … H2 … HLK1) -H2 [ |*: // ] #K2 #V2 #HLK2 #HK12 #HV12
  69       elim (IH … Hf1 … HK12 … HV12) /2 width=2 by fqup_lref/ -L1 -K1 -V1 #f2 #Hf2 #Hf21
  70       /4 width=7 by frees_lref_pushs, frees_lref_pair, drops_refl, sle_next, ex2_intro, sle_pushs/
  71     | * #J #Y #X #V2 #H #HV12 #HVU2
  72       lapply (drops_mono … H … HLK1) -H #H destruct
  73       elim (lexs_drops_conf_next … H2 … HLK1) -H2 [ |*: // ] #K2 #V0 #HLK2 #HK12 #_
  74       lapply (drops_isuni_fwd_drop2 … HLK2) // -V0 #HLK2
  75       elim (IH … Hf1 … HK12 … HV12) /2 width=2 by fqup_lref/ -I -L1 -K1 -V1 #f2 #Hf2 #Hf21
  76       lapply (frees_lifts … Hf2 … HLK2 … HVU2 ??) /4 width=7 by sle_weak, ex2_intro, sle_pushs/
  77     ]
  78   ]
  79 | -IH #l #HG #HL #HU #g1 #H1 #L2 #_ #U2 #H0 destruct
  80   lapply (frees_inv_gref … H1) -H1 #Hg1
  81   lapply (cpx_inv_gref1 … H0) -H0 #H destruct
  82   /3 width=3 by frees_gref_gen, sle_refl, ex2_intro/
  83 | #p #I #V1 #T1 #HG #HL #HU #g1 #H1 #L2 #H2 #U2 #H0 destruct
  84   elim (frees_inv_bind … H1) -H1 #gV1 #gT1 #HgV1 #HgT1 #Hg1
  85   elim (cpx_inv_bind1 … H0) -H0 *
  86   [ #V2 #T2 #HV12 #HT12 #H destruct
  87     lapply (sle_lexs_trans … H2 gV1 ?) /2 width=2 by sor_inv_sle_sn/ #HL12V
  88     lapply (sle_lexs_trans … H2 (⫱gT1) ?) /2 width=2 by sor_inv_sle_dx/ -H2 #HL12T
  89     lapply (lexs_inv_tl … I … HL12T … HV12 ?) // -HL12T #HL12T
  90     elim (IH … HgV1 … HL12V … HV12) // -HgV1 -HL12V -HV12 #gV2 #HgV2 #HgV21
  91     elim (IH … HgT1 … HL12T … HT12) // -IH -HgT1 -HL12T -HT12 #gT2 #HgT2 #HgT21
  92     elim (sor_isfin_ex gV2 (⫱gT2)) /3 width=3 by frees_fwd_isfin, isfin_tl/
  93     /4 width=10 by frees_bind, monotonic_sle_sor, sle_tl, ex2_intro/
  94   | #T2 #HT12 #HUT2 #H0 #H1 destruct -HgV1
  95     lapply (sle_lexs_trans … H2 (⫱gT1) ?) /2 width=2 by sor_inv_sle_dx/ -H2 #HL12T
  96     lapply (lexs_inv_tl … Abbr … V1 V1 HL12T ??) // -HL12T #HL12T
  97     elim (IH … HgT1 … HL12T … HT12) // -L1 -T1 #gT2 #HgT2 #HgT21
  98     lapply (frees_inv_lifts_SO (Ⓣ) … HgT2 … L2 … HUT2) [ /3 width=1 by drops_refl, drops_drop/ ] -V1 -T2
  99     /5 width=6 by sor_inv_sle_dx, sle_trans, sle_tl, ex2_intro/
 100   ]
 101 | #I #V1 #T0 #HG #HL #HU #g1 #H1 #L2 #H2 #U2 #H0 destruct
 102   elim (frees_inv_flat … H1) -H1 #gV1 #gT0 #HgV1 #HgT0 #Hg1
 103   elim (cpx_inv_flat1 … H0) -H0 *
 104   [ #V2 #T2 #HV12 #HT12 #H destruct
 105     lapply (sle_lexs_trans … H2 gV1 ?) /2 width=2 by sor_inv_sle_sn/ #HL12V
 106     lapply (sle_lexs_trans … H2 gT0 ?) /2 width=2 by sor_inv_sle_dx/ -H2 #HL12T
 107     elim (IH … HgV1 … HL12V … HV12) // -HgV1 -HL12V -HV12 #gV2 #HgV2 #HgV21
 108     elim (IH … HgT0 … HL12T … HT12) // -IH -HgT0 -HL12T -HT12 #gT2 #HgT2 #HgT21
 109     elim (sor_isfin_ex gV2 gT2) /2 width=3 by frees_fwd_isfin/
 110     /3 width=10 by frees_flat, monotonic_sle_sor, ex2_intro/
 111   | #HU2 #H destruct -HgV1
 112     lapply (sle_lexs_trans … H2 gT0 ?) /2 width=2 by sor_inv_sle_dx/ -H2 #HL12T
 113     elim (IH … HgT0 … HL12T … HU2) // -L1 -T0 -V1
 114     /4 width=6 by sor_inv_sle_dx, sle_trans, ex2_intro/
 115   | #HU2 #H destruct -HgT0
 116     lapply (sle_lexs_trans … H2 gV1 ?) /2 width=2 by sor_inv_sle_sn/ -H2 #HL12V
 117     elim (IH … HgV1 … HL12V … HU2) // -L1 -T0 -V1
 118     /4 width=6 by sor_inv_sle_sn, sle_trans, ex2_intro/
 119   | #p #V2 #W1 #W2 #T1 #T2 #HV12 #HW12 #HT12 #H0 #H1 #H destruct
 120     elim (frees_inv_bind … HgT0) -HgT0 #gW1 #gT1 #HgW1 #HgT1 #HgT0
 121     lapply (sle_lexs_trans … H2 gV1 ?) /2 width=2 by sor_inv_sle_sn/ #HL12V
 122     lapply (sle_lexs_trans … H2 gT0 ?) /2 width=2 by sor_inv_sle_dx/ -H2 #H2
 123     lapply (sle_lexs_trans … H2 gW1 ?) /2 width=2 by sor_inv_sle_sn/ #HL12W
 124     lapply (sle_lexs_trans … H2 (⫱gT1) ?) /2 width=2 by sor_inv_sle_dx/ -H2 #HL12T
 125     lapply (lexs_inv_tl … Abst … HL12T … HW12 ?) // -HL12T #HL12T
 126     elim (sor_isfin_ex gV1 gW1) /2 width=3 by frees_fwd_isfin/ #g0 #Hg0 #_
 127     lapply (sor_trans2 … Hg1 … HgT0 … Hg0) -Hg1 -HgT0 #Hg1
 128     lapply (sor_sym … Hg0) -Hg0 #Hg0
 129     elim (IH … HgV1 … HL12V … HV12) // -HgV1 -HL12V -HV12 #gV2 #HgV2 #HgV21
 130     elim (IH … HgW1 … HL12W … HW12) // -HgW1 -HL12W -HW12 #gW2 #HgW2 #HgW21
 131     elim (IH … HgT1 … HL12T … HT12) // -IH -HgT1 -HL12T -HT12 #gT2 #HgT2 #HgT21
 132     elim (sor_isfin_ex gV2 (⫱gT2)) /3 width=3 by frees_fwd_isfin, isfin_tl/ #gVT2 #HgVT2 #_
 133     elim (lsubf_frees_trans … HgT2 (⫯gVT2) … (L2.ⓓⓝW2.V2))
 134     [2: /4 width=3 by lsubf_refl, lsubf_beta, sor_inv_sle_dx, sle_inv_tl_sn/ ] -HgT2
 135     #gT0 #HgT0 #HgT20
 136     elim (sor_isfin_ex gW2 gV2) /2 width=3 by frees_fwd_isfin/ #gV0 #HgV0 #H
 137     elim (sor_isfin_ex gV0 (⫱gT0)) /3 width=3 by frees_fwd_isfin, isfin_tl/ -H #g2 #Hg2 #_
 138     @(ex2_intro … g2)
 139     [ @(frees_bind … Hg2) /2 width=5 by frees_flat/
 140     | -L2 @(sor_inv_sle … Hg2) -Hg2
 141       [ /3 width=11 by sor_inv_sle_sn_trans, monotonic_sle_sor/
 142       | @sle_xn_tl [2:|*: // ] @(sle_trans … HgT20) -HgT20
 143         /4 width=8 by monotonic_sle_sor, sor_inv_sle_dx_trans, sle_tl, sle_next/
 144       ] (**) (* full auto too slow *)
 145     ]
 146   | #p #V2 #V #W1 #W2 #T1 #T2 #HV12 #HV2 #HW12 #HT12 #H0 #H1 #H destruct
 147     elim (frees_inv_bind … HgT0) -HgT0 #gW1 #gT1 #HgW1 #HgT1 #HgT0
 148     lapply (sle_lexs_trans … H2 gV1 ?) /2 width=2 by sor_inv_sle_sn/ #HL12V
 149     lapply (sle_lexs_trans … H2 gT0 ?) /2 width=2 by sor_inv_sle_dx/ -H2 #H2
 150     lapply (sle_lexs_trans … H2 gW1 ?) /2 width=2 by sor_inv_sle_sn/ #HL12W
 151     lapply (sle_lexs_trans … H2 (⫱gT1) ?) /2 width=2 by sor_inv_sle_dx/ -H2 #HL12T
 152     lapply (lexs_inv_tl … Abbr … HL12T … HW12 ?) // -HL12T #HL12T
 153     elim (sor_isfin_ex gV1 gW1) /2 width=3 by frees_fwd_isfin/ #g0 #Hg0 #_
 154     lapply (sor_trans2 … Hg1 … HgT0 … Hg0) -Hg1 -HgT0 #Hg1
 155     elim (IH … HgV1 … HL12V … HV12) // -HgV1 -HL12V -HV12 #gV2 #HgV2 #HgV21
 156     elim (IH … HgW1 … HL12W … HW12) // -HgW1 -HL12W -HW12 #gW2 #HgW2 #HgW21
 157     elim (IH … HgT1 … HL12T … HT12) // -IH -HgT1 -HL12T -HT12 #gT2 #HgT2 #HgT21
 158     elim (sor_isfin_ex (↑gV2) gT2) /3 width=3 by frees_fwd_isfin, isfin_push/ #gV0 #HgV0 #H
 159     elim (sor_isfin_ex gW2 (⫱gV0)) /3 width=3 by frees_fwd_isfin, isfin_tl/ -H #g2 #Hg2 #_
 160     elim (sor_isfin_ex gW2 gV2) /2 width=3 by frees_fwd_isfin/ #g #Hg #_
 161     lapply (sor_trans2 … Hg2 … (⫱gT2) … Hg) /2 width=1 by sor_tl/ #Hg2
 162     lapply (frees_lifts (Ⓣ) … HgV2 … (L2.ⓓW2) … HV2 ??) [4: |*: /3 width=3 by drops_refl, drops_drop/ ] -V2 #HgV
 163     lapply (sor_sym … Hg) -Hg #Hg
 164     /4 width=10 by frees_flat, frees_bind, monotonic_sle_sor, sle_tl, ex2_intro/
 165   ]
 166 ]
 167 qed-.
 168
 169 (* Basic_2A1: was: cpx_frees_trans *)
 170 lemma cpx_frees_conf: ∀h,G. R_frees_confluent (cpx h G).
 171 /3 width=7 by cpx_frees_conf_lfpx, lexs_refl/ qed-.
 172
 173 (* Basic_2A1: was: lpx_frees_trans *)
 174 lemma lfpx_frees_conf: ∀h,G. lexs_frees_confluent (cpx h G) cfull.
 175 /2 width=7 by cpx_frees_conf_lfpx/ qed-.