matita/matita/contribs/lambdadelta/basic_2/rt_transition/lfpx_lfdeq.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/relocation/lifts_tdeq.ma".
  16 include "basic_2/static/lfxs_lfxs.ma".
  17 include "basic_2/static/lfdeq_fqup.ma".
  18 include "basic_2/static/lfdeq_lfdeq.ma".
  19 include "basic_2/rt_transition/cpx_lfxs.ma".
  20 include "basic_2/rt_transition/lfpx.ma".
  21
  22 (* UNCOUNTED PARALLEL RT-TRANSITION FOR LOCAL ENV.S ON REFERRED ENTRIES *****)
  23
  24 (* Properties with degree-based equivalence for local environments **********)
  25
  26 lemma lfpx_pair_sn_split: ∀h,G,L1,L2,V. ⦃G, L1⦄ ⊢ ⬈[h, V] L2 → ∀o,I,T.
  27                           ∃∃L. ⦃G, L1⦄ ⊢ ⬈[h, ②{I}V.T] L & L ≛[h, o, V] L2.
  28 /3 width=5 by lfpx_fsle_comp, lfxs_pair_sn_split/ qed-.
  29
  30 lemma lfpx_flat_dx_split: ∀h,G,L1,L2,T. ⦃G, L1⦄ ⊢ ⬈[h, T] L2 → ∀o,I,V.
  31                           ∃∃L. ⦃G, L1⦄ ⊢ ⬈[h, ⓕ{I}V.T] L & L ≛[h, o, T] L2.
  32 /3 width=5 by lfpx_fsle_comp, lfxs_flat_dx_split/ qed-.
  33
  34 lemma lfpx_bind_dx_split: ∀h,I,G,L1,L2,V1,T. ⦃G, L1.ⓑ{I}V1⦄ ⊢ ⬈[h, T] L2 → ∀o,p.
  35                           ∃∃L,V. ⦃G, L1⦄ ⊢ ⬈[h, ⓑ{p,I}V1.T] L & L.ⓑ{I}V ≛[h, o, T] L2 & ⦃G, L1⦄ ⊢ V1 ⬈[h] V.
  36 /3 width=5 by lfpx_fsle_comp, lfxs_bind_dx_split/ qed-.
  37
  38 lemma lfpx_bind_dx_split_void: ∀h,G,K1,L2,T. ⦃G, K1.ⓧ⦄ ⊢ ⬈[h, T] L2 → ∀o,p,I,V.
  39                                ∃∃K2. ⦃G, K1⦄ ⊢ ⬈[h, ⓑ{p,I}V.T] K2 & K2.ⓧ ≛[h, o, T] L2.
  40 /3 width=5 by lfpx_fsle_comp, lfxs_bind_dx_split_void/ qed-.
  41
  42 lemma cpx_tdeq_conf_lexs: ∀h,o,G. R_confluent2_lfxs … (cpx h G) (cdeq h o) (cpx h G) (cdeq h o).
  43 #h #o #G #L0 #T0 #T1 #H @(cpx_ind … H) -G -L0 -T0 -T1 /2 width=3 by ex2_intro/
  44 [ #G #L0 #s0 #X0 #H0 #L1 #HL01 #L2 #HL02
  45   elim (tdeq_inv_sort1 … H0) -H0 #s1 #d1 #Hs0 #Hs1 #H destruct
  46   /4 width=3 by tdeq_sort, deg_next, ex2_intro/
  47 | #I #G #K0 #V0 #V1 #W1 #_ #IH #HVW1 #T2 #H0 #L1 #H1 #L2 #H2
  48   >(tdeq_inv_lref1 … H0) -H0
  49   elim (lfpx_inv_zero_pair_sn … H1) -H1 #K1 #X1 #HK01 #HX1 #H destruct
  50   elim (lfdeq_inv_zero_pair_sn … H2) -H2 #K2 #X2 #HK02 #HX2 #H destruct
  51   elim (IH X2 … HK01 … HK02) // -K0 -V0 #V #HV1 #HV2
  52   elim (tdeq_lifts_sn … HV1 … HVW1) -V1 /3 width=5 by cpx_delta, ex2_intro/
  53 | #I0 #G #K0 #V1 #W1 #i #_ #IH #HVW1 #T2 #H0 #L1 #H1 #L2 #H2
  54   >(tdeq_inv_lref1 … H0) -H0
  55   elim (lfpx_inv_lref_bind_sn … H1) -H1 #I1 #K1 #HK01 #H destruct
  56   elim (lfdeq_inv_lref_bind_sn … H2) -H2 #I2 #K2 #HK02 #H destruct
  57   elim (IH … HK01 … HK02) [|*: //] -K0 #V #HV1 #HV2
  58   elim (tdeq_lifts_sn … HV1 … HVW1) -V1 /3 width=5 by cpx_lref, ex2_intro/
  59 | #p #I #G #L0 #V0 #V1 #T0 #T1 #_ #_ #IHV #IHT #X0 #H0 #L1 #H1 #L2 #H2
  60   elim (tdeq_inv_pair1 … H0) -H0 #V2 #T2 #HV02 #HT02 #H destruct
  61   elim (lfpx_inv_bind … H1) -H1 #HL01 #H1
  62   elim (lfdeq_inv_bind … H2) -H2 #HL02 #H2
  63   lapply (lfdeq_bind_repl_dx … H2 (BPair I V2) ?) -H2 /2 width=1 by ext2_pair/ #H2
  64   elim (IHV … HV02 … HL01 … HL02) -IHV -HV02 -HL01 -HL02
  65   elim (IHT … HT02 … H1 … H2) -L0 -T0
  66   /3 width=5 by cpx_bind, tdeq_pair, ex2_intro/
  67 | #I #G #L0 #V0 #V1 #T0 #T1 #_ #_ #IHV #IHT #X0 #H0 #L1 #H1 #L2 #H2
  68   elim (tdeq_inv_pair1 … H0) -H0 #V2 #T2 #HV02 #HT02 #H destruct
  69   elim (lfpx_inv_flat … H1) -H1 #HL01 #H1
  70   elim (lfdeq_inv_flat … H2) -H2 #HL02 #H2
  71   elim (IHV … HV02 … HL01 … HL02) -IHV -HV02 -HL01 -HL02
  72   elim (IHT … HT02 … H1 … H2) -L0 -V0 -T0
  73   /3 width=5 by cpx_flat, tdeq_pair, ex2_intro/
  74 | #G #L0 #V0 #T0 #T1 #U1 #_ #IH #HUT1 #X0 #H0 #L1 #H1 #L2 #H2
  75   elim (tdeq_inv_pair1 … H0) -H0 #V2 #T2 #HV02 #HT02 #H destruct
  76   elim (lfpx_inv_bind … H1) -H1 #HL01 #H1
  77   elim (lfdeq_inv_bind … H2) -H2 #HL02 #H2
  78   lapply (lfdeq_bind_repl_dx … H2 (BPair Abbr V2) ?) -H2 /2 width=1 by ext2_pair/ -HV02 #H2
  79   elim (IH … HT02 … H1 … H2) -L0 -T0 #T #HT1
  80   elim (tdeq_inv_lifts_sn … HT1 … HUT1) -T1
  81   /3 width=5 by cpx_zeta, ex2_intro/
  82 | #G #L0 #V0 #T0 #T1 #_ #IH #X0 #H0 #L1 #H1 #L2 #H2
  83   elim (tdeq_inv_pair1 … H0) -H0 #V2 #T2 #_ #HT02 #H destruct
  84   elim (lfpx_inv_flat … H1) -H1 #HL01 #H1
  85   elim (lfdeq_inv_flat … H2) -H2 #HL02 #H2
  86   elim (IH … HT02 … H1 … H2) -L0 -V0 -T0
  87   /3 width=3 by cpx_eps, ex2_intro/
  88 | #G #L0 #V0 #T0 #T1 #_ #IH #X0 #H0 #L1 #H1 #L2 #H2
  89   elim (tdeq_inv_pair1 … H0) -H0 #V2 #T2 #HV02 #_ #H destruct
  90   elim (lfpx_inv_flat … H1) -H1 #HL01 #H1
  91   elim (lfdeq_inv_flat … H2) -H2 #HL02 #H2
  92   elim (IH … HV02 … HL01 … HL02) -L0 -V0 -T1
  93   /3 width=3 by cpx_ee, ex2_intro/
  94 | #p #G #L0 #V0 #V1 #W0 #W1 #T0 #T1 #_ #_ #_ #IHV #IHW #IHT #X0 #H0 #L1 #H1 #L2 #H2
  95   elim (tdeq_inv_pair1 … H0) -H0 #V2 #X #HV02 #H0 #H destruct
  96   elim (tdeq_inv_pair1 … H0) -H0 #W2 #T2 #HW02 #HT02 #H destruct
  97   elim (lfpx_inv_flat … H1) -H1 #H1LV0 #H1
  98   elim (lfpx_inv_bind … H1) -H1 #H1LW0 #H1LT0
  99   elim (lfdeq_inv_flat … H2) -H2 #H2LV0 #H2
 100   elim (lfdeq_inv_bind … H2) -H2 #H2LW0 #H2LT0
 101   lapply (lfdeq_bind_repl_dx … H2LT0 (BPair Abst W2) ?) -H2LT0 /2 width=1 by ext2_pair/ #H2LT0
 102   elim (IHV … HV02 … H1LV0 … H2LV0) -IHV -HV02 -H1LV0 -H2LV0
 103   elim (IHW … HW02 … H1LW0 … H2LW0) -IHW -HW02 -H1LW0 -H2LW0
 104   elim (IHT … HT02 … H1LT0 … H2LT0) -L0 -V0 -T0
 105   /4 width=7 by cpx_beta, tdeq_pair, ex2_intro/ (* note: 2 tdeq_pair *)
 106 | #p #G #L0 #V0 #V1 #U1 #W0 #W1 #T0 #T1 #_ #_ #_ #IHV #IHW #IHT #HVU1 #X0 #H0 #L1 #H1 #L2 #H2
 107   elim (tdeq_inv_pair1 … H0) -H0 #V2 #X #HV02 #H0 #H destruct
 108   elim (tdeq_inv_pair1 … H0) -H0 #W2 #T2 #HW02 #HT02 #H destruct
 109   elim (lfpx_inv_flat … H1) -H1 #H1LV0 #H1
 110   elim (lfpx_inv_bind … H1) -H1 #H1LW0 #H1LT0
 111   elim (lfdeq_inv_flat … H2) -H2 #H2LV0 #H2
 112   elim (lfdeq_inv_bind … H2) -H2 #H2LW0 #H2LT0
 113   lapply (lfdeq_bind_repl_dx … H2LT0 (BPair Abbr W2) ?) -H2LT0 /2 width=1 by ext2_pair/ #H2LT0
 114   elim (IHV … HV02 … H1LV0 … H2LV0) -IHV -HV02 -H1LV0 -H2LV0 #V #HV1
 115   elim (IHW … HW02 … H1LW0 … H2LW0) -IHW -HW02 -H1LW0 -H2LW0
 116   elim (IHT … HT02 … H1LT0 … H2LT0) -L0 -V0 -T0
 117   elim (tdeq_lifts_sn … HV1 … HVU1) -V1
 118   /4 width=9 by cpx_theta, tdeq_pair, ex2_intro/ (* note: 2 tdeq_pair *)
 119 ]
 120 qed-.
 121
 122 lemma cpx_tdeq_conf: ∀h,o,G,L. ∀T0:term. ∀T1. ⦃G, L⦄ ⊢ T0 ⬈[h] T1 →
 123                      ∀T2. T0 ≛[h, o] T2 →
 124                      ∃∃T. T1 ≛[h, o] T & ⦃G, L⦄ ⊢ T2 ⬈[h] T.
 125 #h #o #G #L #T0 #T1 #HT01 #T2 #HT02
 126 elim (cpx_tdeq_conf_lexs … HT01 … HT02 L … L) -HT01 -HT02
 127 /2 width=3 by lfxs_refl, ex2_intro/
 128 qed-.
 129
 130 lemma tdeq_cpx_trans: ∀h,o,G,L,T2. ∀T0:term. T2 ≛[h, o] T0 →
 131                       ∀T1. ⦃G, L⦄ ⊢ T0 ⬈[h] T1 →
 132                       ∃∃T. ⦃G, L⦄ ⊢ T2 ⬈[h] T & T ≛[h, o] T1.
 133 #h #o #G #L #T2 #T0 #HT20 #T1 #HT01
 134 elim (cpx_tdeq_conf … HT01 T2) -HT01 /3 width=3 by tdeq_sym, ex2_intro/
 135 qed-.
 136
 137 (* Basic_2A1: uses: cpx_lleq_conf *)
 138 lemma cpx_lfdeq_conf: ∀h,o,G,L0,T0,T1. ⦃G, L0⦄ ⊢ T0 ⬈[h] T1 →
 139                       ∀L2. L0 ≛[h, o, T0] L2 →
 140                       ∃∃T. ⦃G, L2⦄ ⊢ T0 ⬈[h] T & T1 ≛[h, o] T.
 141 #h #o #G #L0 #T0 #T1 #HT01 #L2 #HL02
 142 elim (cpx_tdeq_conf_lexs … HT01 T0 … L0 … HL02) -HT01 -HL02
 143 /2 width=3 by lfxs_refl, ex2_intro/
 144 qed-.
 145
 146 (* Basic_2A1: uses: lleq_cpx_trans *)
 147 lemma lfdeq_cpx_trans: ∀h,o,G,L2,L0,T0. L2 ≛[h, o, T0] L0 →
 148                        ∀T1. ⦃G, L0⦄ ⊢ T0 ⬈[h] T1 →
 149                        ∃∃T. ⦃G, L2⦄ ⊢ T0 ⬈[h] T & T ≛[h, o] T1.
 150 #h #o #G #L2 #L0 #T0 #HL20 #T1 #HT01
 151 elim (cpx_lfdeq_conf … o … HT01 L2) -HT01
 152 /3 width=3 by lfdeq_sym, tdeq_sym, ex2_intro/
 153 qed-.
 154
 155 lemma lfpx_lfdeq_conf: ∀h,o,G,T. confluent2 … (lfpx h G T) (lfdeq h o T).
 156 /3 width=6 by lfpx_fsle_comp, lfdeq_fsle_comp, cpx_tdeq_conf_lexs, lfxs_conf/ qed-.
 157
 158 (* Basic_2A1: uses: lleq_lpx_trans *)
 159 lemma lfdeq_lfpx_trans: ∀h,o,G,T,L2,K2. ⦃G, L2⦄ ⊢ ⬈[h, T] K2 →
 160                         ∀L1. L1 ≛[h, o, T] L2 →
 161                         ∃∃K1. ⦃G, L1⦄ ⊢ ⬈[h, T] K1 & K1 ≛[h, o, T] K2.
 162 #h #o #G #T #L2 #K2 #HLK2 #L1 #HL12
 163 elim (lfpx_lfdeq_conf … o … HLK2 L1)
 164 /3 width=3 by lfdeq_sym, ex2_intro/
 165 qed-.