matita/matita/contribs/lambdadelta/basic_2/rt_transition/lfpx_lfdeq.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/static/lfdeq_fqup.ma".
  16 include "basic_2/static/lfdeq_lfdeq.ma".
  17 include "basic_2/rt_transition/lfpx_fsle.ma".
  18
  19 (* UNCOUNTED PARALLEL RT-TRANSITION FOR LOCAL ENV.S ON REFERRED ENTRIES *****)
  20
  21 (* Properties with degree-based equivalence for local environments **********)
  22
  23 lemma lfpx_pair_sn_split: ∀h,G,L1,L2,V. ⦃G, L1⦄ ⊢ ⬈[h, V] L2 → ∀o,I,T.
  24                           ∃∃L. ⦃G, L1⦄ ⊢ ⬈[h, ②{I}V.T] L & L ≛[h, o, V] L2.
  25 /3 width=5 by lfpx_fsge_comp, lfxs_pair_sn_split/ qed-.
  26
  27 lemma lfpx_flat_dx_split: ∀h,G,L1,L2,T. ⦃G, L1⦄ ⊢ ⬈[h, T] L2 → ∀o,I,V.
  28                           ∃∃L. ⦃G, L1⦄ ⊢ ⬈[h, ⓕ{I}V.T] L & L ≛[h, o, T] L2.
  29 /3 width=5 by lfpx_fsge_comp, lfxs_flat_dx_split/ qed-.
  30
  31 lemma lfpx_bind_dx_split: ∀h,I,G,L1,L2,V1,T. ⦃G, L1.ⓑ{I}V1⦄ ⊢ ⬈[h, T] L2 → ∀o,p.
  32                           ∃∃L,V. ⦃G, L1⦄ ⊢ ⬈[h, ⓑ{p,I}V1.T] L & L.ⓑ{I}V ≛[h, o, T] L2 & ⦃G, L1⦄ ⊢ V1 ⬈[h] V.
  33 /3 width=5 by lfpx_fsge_comp, lfxs_bind_dx_split/ qed-.
  34
  35 lemma lfpx_bind_dx_split_void: ∀h,G,K1,L2,T. ⦃G, K1.ⓧ⦄ ⊢ ⬈[h, T] L2 → ∀o,p,I,V.
  36                                ∃∃K2. ⦃G, K1⦄ ⊢ ⬈[h, ⓑ{p,I}V.T] K2 & K2.ⓧ ≛[h, o, T] L2.
  37 /3 width=5 by lfpx_fsge_comp, lfxs_bind_dx_split_void/ qed-.
  38
  39 lemma cpx_tdeq_conf_lexs: ∀h,o,G. R_confluent2_lfxs … (cpx h G) (cdeq h o) (cpx h G) (cdeq h o).
  40 #h #o #G #L0 #T0 #T1 #H @(cpx_ind … H) -G -L0 -T0 -T1 /2 width=3 by ex2_intro/
  41 [ #G #L0 #s0 #X0 #H0 #L1 #HL01 #L2 #HL02
  42   elim (tdeq_inv_sort1 … H0) -H0 #s1 #d1 #Hs0 #Hs1 #H destruct
  43   /4 width=3 by tdeq_sort, deg_next, ex2_intro/
  44 | #I #G #K0 #V0 #V1 #W1 #_ #IH #HVW1 #T2 #H0 #L1 #H1 #L2 #H2
  45   >(tdeq_inv_lref1 … H0) -H0
  46   elim (lfpx_inv_zero_pair_sn … H1) -H1 #K1 #X1 #HK01 #HX1 #H destruct
  47   elim (lfdeq_inv_zero_pair_sn … H2) -H2 #K2 #X2 #HK02 #HX2 #H destruct
  48   elim (IH X2 … HK01 … HK02) // -K0 -V0 #V #HV1 #HV2
  49   elim (tdeq_lifts_sn … HV1 … HVW1) -V1 /3 width=5 by cpx_delta, ex2_intro/
  50 | #I0 #G #K0 #V1 #W1 #i #_ #IH #HVW1 #T2 #H0 #L1 #H1 #L2 #H2
  51   >(tdeq_inv_lref1 … H0) -H0
  52   elim (lfpx_inv_lref_bind_sn … H1) -H1 #I1 #K1 #HK01 #H destruct
  53   elim (lfdeq_inv_lref_bind_sn … H2) -H2 #I2 #K2 #HK02 #H destruct
  54   elim (IH … HK01 … HK02) [|*: //] -K0 #V #HV1 #HV2
  55   elim (tdeq_lifts_sn … HV1 … HVW1) -V1 /3 width=5 by cpx_lref, ex2_intro/
  56 | #p #I #G #L0 #V0 #V1 #T0 #T1 #_ #_ #IHV #IHT #X0 #H0 #L1 #H1 #L2 #H2
  57   elim (tdeq_inv_pair1 … H0) -H0 #V2 #T2 #HV02 #HT02 #H destruct
  58   elim (lfpx_inv_bind … H1) -H1 #HL01 #H1
  59   elim (lfdeq_inv_bind … H2) -H2 #HL02 #H2
  60   lapply (lfdeq_bind_repl_dx … H2 (BPair I V2) ?) -H2 /2 width=1 by ext2_pair/ #H2
  61   elim (IHV … HV02 … HL01 … HL02) -IHV -HV02 -HL01 -HL02
  62   elim (IHT … HT02 … H1 … H2) -L0 -T0
  63   /3 width=5 by cpx_bind, tdeq_pair, ex2_intro/
  64 | #I #G #L0 #V0 #V1 #T0 #T1 #_ #_ #IHV #IHT #X0 #H0 #L1 #H1 #L2 #H2
  65   elim (tdeq_inv_pair1 … H0) -H0 #V2 #T2 #HV02 #HT02 #H destruct
  66   elim (lfpx_inv_flat … H1) -H1 #HL01 #H1
  67   elim (lfdeq_inv_flat … H2) -H2 #HL02 #H2
  68   elim (IHV … HV02 … HL01 … HL02) -IHV -HV02 -HL01 -HL02
  69   elim (IHT … HT02 … H1 … H2) -L0 -V0 -T0
  70   /3 width=5 by cpx_flat, tdeq_pair, ex2_intro/
  71 | #G #L0 #V0 #T0 #T1 #U1 #_ #IH #HUT1 #X0 #H0 #L1 #H1 #L2 #H2
  72   elim (tdeq_inv_pair1 … H0) -H0 #V2 #T2 #HV02 #HT02 #H destruct
  73   elim (lfpx_inv_bind … H1) -H1 #HL01 #H1
  74   elim (lfdeq_inv_bind … H2) -H2 #HL02 #H2
  75   lapply (lfdeq_bind_repl_dx … H2 (BPair Abbr V2) ?) -H2 /2 width=1 by ext2_pair/ -HV02 #H2
  76   elim (IH … HT02 … H1 … H2) -L0 -T0 #T #HT1
  77   elim (tdeq_inv_lifts_sn … HT1 … HUT1) -T1
  78   /3 width=5 by cpx_zeta, ex2_intro/
  79 | #G #L0 #V0 #T0 #T1 #_ #IH #X0 #H0 #L1 #H1 #L2 #H2
  80   elim (tdeq_inv_pair1 … H0) -H0 #V2 #T2 #_ #HT02 #H destruct
  81   elim (lfpx_inv_flat … H1) -H1 #HL01 #H1
  82   elim (lfdeq_inv_flat … H2) -H2 #HL02 #H2
  83   elim (IH … HT02 … H1 … H2) -L0 -V0 -T0
  84   /3 width=3 by cpx_eps, ex2_intro/
  85 | #G #L0 #V0 #T0 #T1 #_ #IH #X0 #H0 #L1 #H1 #L2 #H2
  86   elim (tdeq_inv_pair1 … H0) -H0 #V2 #T2 #HV02 #_ #H destruct
  87   elim (lfpx_inv_flat … H1) -H1 #HL01 #H1
  88   elim (lfdeq_inv_flat … H2) -H2 #HL02 #H2
  89   elim (IH … HV02 … HL01 … HL02) -L0 -V0 -T1
  90   /3 width=3 by cpx_ee, ex2_intro/
  91 | #p #G #L0 #V0 #V1 #W0 #W1 #T0 #T1 #_ #_ #_ #IHV #IHW #IHT #X0 #H0 #L1 #H1 #L2 #H2
  92   elim (tdeq_inv_pair1 … H0) -H0 #V2 #X #HV02 #H0 #H destruct
  93   elim (tdeq_inv_pair1 … H0) -H0 #W2 #T2 #HW02 #HT02 #H destruct
  94   elim (lfpx_inv_flat … H1) -H1 #H1LV0 #H1
  95   elim (lfpx_inv_bind … H1) -H1 #H1LW0 #H1LT0
  96   elim (lfdeq_inv_flat … H2) -H2 #H2LV0 #H2
  97   elim (lfdeq_inv_bind … H2) -H2 #H2LW0 #H2LT0
  98   lapply (lfdeq_bind_repl_dx … H2LT0 (BPair Abst W2) ?) -H2LT0 /2 width=1 by ext2_pair/ #H2LT0
  99   elim (IHV … HV02 … H1LV0 … H2LV0) -IHV -HV02 -H1LV0 -H2LV0
 100   elim (IHW … HW02 … H1LW0 … H2LW0) -IHW -HW02 -H1LW0 -H2LW0
 101   elim (IHT … HT02 … H1LT0 … H2LT0) -L0 -V0 -T0
 102   /4 width=7 by cpx_beta, tdeq_pair, ex2_intro/ (* note: 2 tdeq_pair *)
 103 | #p #G #L0 #V0 #V1 #U1 #W0 #W1 #T0 #T1 #_ #_ #_ #IHV #IHW #IHT #HVU1 #X0 #H0 #L1 #H1 #L2 #H2
 104   elim (tdeq_inv_pair1 … H0) -H0 #V2 #X #HV02 #H0 #H destruct
 105   elim (tdeq_inv_pair1 … H0) -H0 #W2 #T2 #HW02 #HT02 #H destruct
 106   elim (lfpx_inv_flat … H1) -H1 #H1LV0 #H1
 107   elim (lfpx_inv_bind … H1) -H1 #H1LW0 #H1LT0
 108   elim (lfdeq_inv_flat … H2) -H2 #H2LV0 #H2
 109   elim (lfdeq_inv_bind … H2) -H2 #H2LW0 #H2LT0
 110   lapply (lfdeq_bind_repl_dx … H2LT0 (BPair Abbr W2) ?) -H2LT0 /2 width=1 by ext2_pair/ #H2LT0
 111   elim (IHV … HV02 … H1LV0 … H2LV0) -IHV -HV02 -H1LV0 -H2LV0 #V #HV1
 112   elim (IHW … HW02 … H1LW0 … H2LW0) -IHW -HW02 -H1LW0 -H2LW0
 113   elim (IHT … HT02 … H1LT0 … H2LT0) -L0 -V0 -T0
 114   elim (tdeq_lifts_sn … HV1 … HVU1) -V1
 115   /4 width=9 by cpx_theta, tdeq_pair, ex2_intro/ (* note: 2 tdeq_pair *)
 116 ]
 117 qed-.
 118
 119 lemma cpx_tdeq_conf: ∀h,o,G,L. ∀T0:term. ∀T1. ⦃G, L⦄ ⊢ T0 ⬈[h] T1 →
 120                      ∀T2. T0 ≛[h, o] T2 →
 121                      ∃∃T. T1 ≛[h, o] T & ⦃G, L⦄ ⊢ T2 ⬈[h] T.
 122 #h #o #G #L #T0 #T1 #HT01 #T2 #HT02
 123 elim (cpx_tdeq_conf_lexs … HT01 … HT02 L … L) -HT01 -HT02
 124 /2 width=3 by lfxs_refl, ex2_intro/
 125 qed-.
 126
 127 lemma tdeq_cpx_trans: ∀h,o,G,L,T2. ∀T0:term. T2 ≛[h, o] T0 →
 128                       ∀T1. ⦃G, L⦄ ⊢ T0 ⬈[h] T1 →
 129                       ∃∃T. ⦃G, L⦄ ⊢ T2 ⬈[h] T & T ≛[h, o] T1.
 130 #h #o #G #L #T2 #T0 #HT20 #T1 #HT01
 131 elim (cpx_tdeq_conf … HT01 T2) -HT01 /3 width=3 by tdeq_sym, ex2_intro/
 132 qed-.
 133
 134 (* Basic_2A1: uses: cpx_lleq_conf *)
 135 lemma cpx_lfdeq_conf: ∀h,o,G,L0,T0,T1. ⦃G, L0⦄ ⊢ T0 ⬈[h] T1 →
 136                       ∀L2. L0 ≛[h, o, T0] L2 →
 137                       ∃∃T. ⦃G, L2⦄ ⊢ T0 ⬈[h] T & T1 ≛[h, o] T.
 138 #h #o #G #L0 #T0 #T1 #HT01 #L2 #HL02
 139 elim (cpx_tdeq_conf_lexs … HT01 T0 … L0 … HL02) -HT01 -HL02
 140 /2 width=3 by lfxs_refl, ex2_intro/
 141 qed-.
 142
 143 (* Basic_2A1: uses: lleq_cpx_trans *)
 144 lemma lfdeq_cpx_trans: ∀h,o,G,L2,L0,T0. L2 ≛[h, o, T0] L0 →
 145                        ∀T1. ⦃G, L0⦄ ⊢ T0 ⬈[h] T1 →
 146                        ∃∃T. ⦃G, L2⦄ ⊢ T0 ⬈[h] T & T ≛[h, o] T1.
 147 #h #o #G #L2 #L0 #T0 #HL20 #T1 #HT01
 148 elim (cpx_lfdeq_conf … o … HT01 L2) -HT01
 149 /3 width=3 by lfdeq_sym, tdeq_sym, ex2_intro/
 150 qed-.
 151
 152 lemma lfpx_lfdeq_conf: ∀h,o,G,T. confluent2 … (lfpx h G T) (lfdeq h o T).
 153 /3 width=6 by lfpx_fsge_comp, lfdeq_fsge_comp, cpx_tdeq_conf_lexs, lfxs_conf/ qed-.
 154
 155 (* Basic_2A1: uses: lleq_lpx_trans *)
 156 lemma lfdeq_lfpx_trans: ∀h,o,G,T,L2,K2. ⦃G, L2⦄ ⊢ ⬈[h, T] K2 →
 157                         ∀L1. L1 ≛[h, o, T] L2 →
 158                         ∃∃K1. ⦃G, L1⦄ ⊢ ⬈[h, T] K1 & K1 ≛[h, o, T] K2.
 159 #h #o #G #T #L2 #K2 #HLK2 #L1 #HL12
 160 elim (lfpx_lfdeq_conf … o … HLK2 L1)
 161 /3 width=3 by lfdeq_sym, ex2_intro/
 162 qed-.