matita/matita/contribs/lambdadelta/basic_2/rt_transition/lfpx_lfdeq.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/relocation/lifts_tdeq.ma".
  16 include "basic_2/static/lfxs_lfxs.ma".
  17 include "basic_2/static/lfdeq_fqup.ma".
  18 include "basic_2/rt_transition/lfpx_frees.ma".
  19 include "basic_2/rt_transition/lfpx.ma". (**) (* should be in lfpx_frees.ma *)
  20
  21 (* UNCOUNTED PARALLEL RT-TRANSITION FOR LOCAL ENV.S ON REFERRED ENTRIES *****)
  22
  23 (* Properties with degree-based equivalence for local environments **********)
  24
  25 lemma lfpx_pair_sn_split: ∀h,o,I,G,L1,L2,V,T. ⦃G, L1⦄ ⊢ ⬈[h, V] L2 →
  26                           ∃∃L. ⦃G, L1⦄ ⊢ ⬈[h, ②{I}V.T] L & L ≡[h, o, V] L2.
  27 /3 width=5 by lfpx_frees_conf, lfxs_pair_sn_split/ qed-.
  28
  29 lemma lfpx_flat_dx_split: ∀h,o,I,G,L1,L2,V,T. ⦃G, L1⦄ ⊢ ⬈[h, T] L2 →
  30                           ∃∃L. ⦃G, L1⦄ ⊢ ⬈[h, ⓕ{I}V.T] L & L ≡[h, o, T] L2.
  31 /3 width=5 by lfpx_frees_conf, lfxs_flat_dx_split/ qed-.
  32
  33 lemma lfpx_bind_dx_split: ∀h,o,p,I,G,L1,L2,V1,T. ⦃G, L1.ⓑ{I}V1⦄ ⊢ ⬈[h, T] L2 →
  34                           ∃∃L,V. ⦃G, L1⦄ ⊢ ⬈[h, ⓑ{p,I}V1.T] L & L.ⓑ{I}V ≡[h, o, T] L2 & ⦃G, L1⦄ ⊢ V1 ⬈[h] V.
  35 /3 width=5 by lfpx_frees_conf, lfxs_bind_dx_split/ qed-.
  36
  37 lemma cpx_tdeq_conf_lexs: ∀h,o,G. R_confluent2_lfxs … (cpx h G) (cdeq h o) (cpx h G) (cdeq h o).
  38 #h #o #G #L0 #T0 #T1 #H @(cpx_ind … H) -G -L0 -T0 -T1 /2 width=3 by ex2_intro/
  39 [ #G #L0 #s0 #X0 #H0 #L1 #HL01 #L2 #HL02
  40   elim (tdeq_inv_sort1 … H0) -H0 #s1 #d1 #Hs0 #Hs1 #H destruct
  41   /4 width=3 by tdeq_sort, deg_next, ex2_intro/
  42 | #I #G #K0 #V0 #V1 #W1 #_ #IH #HVW1 #T2 #H0 #L1 #H1 #L2 #H2
  43   >(tdeq_inv_lref1 … H0) -H0
  44   elim (lfpx_inv_zero_pair_sn … H1) -H1 #K1 #X1 #HK01 #HX1 #H destruct
  45   elim (lfdeq_inv_zero_pair_sn … H2) -H2 #K2 #X2 #HK02 #HX2 #H destruct
  46   elim (IH X2 … HK01 … HK02) // -K0 -V0 #V #HV1 #HV2
  47   elim (tdeq_lifts_sn … HV1 … HVW1) -V1 /3 width=5 by cpx_delta, ex2_intro/
  48 | #I0 #G #K0 #V1 #W1 #i #_ #IH #HVW1 #T2 #H0 #L1 #H1 #L2 #H2
  49   >(tdeq_inv_lref1 … H0) -H0
  50   elim (lfpx_inv_lref_bind_sn … H1) -H1 #I1 #K1 #HK01 #H destruct
  51   elim (lfdeq_inv_lref_bind_sn … H2) -H2 #I2 #K2 #HK02 #H destruct
  52   elim (IH … HK01 … HK02) [|*: //] -K0 #V #HV1 #HV2
  53   elim (tdeq_lifts_sn … HV1 … HVW1) -V1 /3 width=5 by cpx_lref, ex2_intro/
  54 | #p #I #G #L0 #V0 #V1 #T0 #T1 #_ #_ #IHV #IHT #X0 #H0 #L1 #H1 #L2 #H2
  55   elim (tdeq_inv_pair1 … H0) -H0 #V2 #T2 #HV02 #HT02 #H destruct
  56   elim (lfpx_inv_bind … H1) -H1 #HL01 #H1
  57   elim (lfdeq_inv_bind … H2) -H2 #HL02 #H2
  58   lapply (lfdeq_bind_repl_dx … H2 (BPair I V2) ?) -H2 /2 width=1 by ext2_pair/ #H2
  59   elim (IHV … HV02 … HL01 … HL02) -IHV -HV02 -HL01 -HL02
  60   elim (IHT … HT02 … H1 … H2) -L0 -T0
  61   /3 width=5 by cpx_bind, tdeq_pair, ex2_intro/
  62 | #I #G #L0 #V0 #V1 #T0 #T1 #_ #_ #IHV #IHT #X0 #H0 #L1 #H1 #L2 #H2
  63   elim (tdeq_inv_pair1 … H0) -H0 #V2 #T2 #HV02 #HT02 #H destruct
  64   elim (lfpx_inv_flat … H1) -H1 #HL01 #H1
  65   elim (lfdeq_inv_flat … H2) -H2 #HL02 #H2
  66   elim (IHV … HV02 … HL01 … HL02) -IHV -HV02 -HL01 -HL02
  67   elim (IHT … HT02 … H1 … H2) -L0 -V0 -T0
  68   /3 width=5 by cpx_flat, tdeq_pair, ex2_intro/
  69 | #G #L0 #V0 #T0 #T1 #U1 #_ #IH #HUT1 #X0 #H0 #L1 #H1 #L2 #H2
  70   elim (tdeq_inv_pair1 … H0) -H0 #V2 #T2 #HV02 #HT02 #H destruct
  71   elim (lfpx_inv_bind … H1) -H1 #HL01 #H1
  72   elim (lfdeq_inv_bind … H2) -H2 #HL02 #H2
  73   lapply (lfdeq_bind_repl_dx … H2 (BPair Abbr V2) ?) -H2 /2 width=1 by ext2_pair/ -HV02 #H2
  74   elim (IH … HT02 … H1 … H2) -L0 -T0 #T #HT1
  75   elim (tdeq_inv_lifts_sn … HT1 … HUT1) -T1
  76   /3 width=5 by cpx_zeta, ex2_intro/
  77 | #G #L0 #V0 #T0 #T1 #_ #IH #X0 #H0 #L1 #H1 #L2 #H2
  78   elim (tdeq_inv_pair1 … H0) -H0 #V2 #T2 #_ #HT02 #H destruct
  79   elim (lfpx_inv_flat … H1) -H1 #HL01 #H1
  80   elim (lfdeq_inv_flat … H2) -H2 #HL02 #H2
  81   elim (IH … HT02 … H1 … H2) -L0 -V0 -T0
  82   /3 width=3 by cpx_eps, ex2_intro/
  83 | #G #L0 #V0 #T0 #T1 #_ #IH #X0 #H0 #L1 #H1 #L2 #H2
  84   elim (tdeq_inv_pair1 … H0) -H0 #V2 #T2 #HV02 #_ #H destruct
  85   elim (lfpx_inv_flat … H1) -H1 #HL01 #H1
  86   elim (lfdeq_inv_flat … H2) -H2 #HL02 #H2
  87   elim (IH … HV02 … HL01 … HL02) -L0 -V0 -T1
  88   /3 width=3 by cpx_ee, ex2_intro/
  89 | #p #G #L0 #V0 #V1 #W0 #W1 #T0 #T1 #_ #_ #_ #IHV #IHW #IHT #X0 #H0 #L1 #H1 #L2 #H2
  90   elim (tdeq_inv_pair1 … H0) -H0 #V2 #X #HV02 #H0 #H destruct
  91   elim (tdeq_inv_pair1 … H0) -H0 #W2 #T2 #HW02 #HT02 #H destruct
  92   elim (lfpx_inv_flat … H1) -H1 #H1LV0 #H1
  93   elim (lfpx_inv_bind … H1) -H1 #H1LW0 #H1LT0
  94   elim (lfdeq_inv_flat … H2) -H2 #H2LV0 #H2
  95   elim (lfdeq_inv_bind … H2) -H2 #H2LW0 #H2LT0
  96   lapply (lfdeq_bind_repl_dx … H2LT0 (BPair Abst W2) ?) -H2LT0 /2 width=1 by ext2_pair/ #H2LT0
  97   elim (IHV … HV02 … H1LV0 … H2LV0) -IHV -HV02 -H1LV0 -H2LV0
  98   elim (IHW … HW02 … H1LW0 … H2LW0) -IHW -HW02 -H1LW0 -H2LW0
  99   elim (IHT … HT02 … H1LT0 … H2LT0) -L0 -V0 -T0
 100   /4 width=7 by cpx_beta, tdeq_pair, ex2_intro/ (* note: 2 tdeq_pair *)
 101 | #p #G #L0 #V0 #V1 #U1 #W0 #W1 #T0 #T1 #_ #_ #_ #IHV #IHW #IHT #HVU1 #X0 #H0 #L1 #H1 #L2 #H2
 102   elim (tdeq_inv_pair1 … H0) -H0 #V2 #X #HV02 #H0 #H destruct
 103   elim (tdeq_inv_pair1 … H0) -H0 #W2 #T2 #HW02 #HT02 #H destruct
 104   elim (lfpx_inv_flat … H1) -H1 #H1LV0 #H1
 105   elim (lfpx_inv_bind … H1) -H1 #H1LW0 #H1LT0
 106   elim (lfdeq_inv_flat … H2) -H2 #H2LV0 #H2
 107   elim (lfdeq_inv_bind … H2) -H2 #H2LW0 #H2LT0
 108   lapply (lfdeq_bind_repl_dx … H2LT0 (BPair Abbr W2) ?) -H2LT0 /2 width=1 by ext2_pair/ #H2LT0
 109   elim (IHV … HV02 … H1LV0 … H2LV0) -IHV -HV02 -H1LV0 -H2LV0 #V #HV1
 110   elim (IHW … HW02 … H1LW0 … H2LW0) -IHW -HW02 -H1LW0 -H2LW0
 111   elim (IHT … HT02 … H1LT0 … H2LT0) -L0 -V0 -T0
 112   elim (tdeq_lifts_sn … HV1 … HVU1) -V1
 113   /4 width=9 by cpx_theta, tdeq_pair, ex2_intro/ (* note: 2 tdeq_pair *)
 114 ]
 115 qed-.
 116
 117 lemma cpx_tdeq_conf: ∀h,o,G,L. ∀T0:term. ∀T1. ⦃G, L⦄ ⊢ T0 ⬈[h] T1 →
 118                      ∀T2. T0 ≡[h, o] T2 →
 119                      ∃∃T. T1 ≡[h, o] T & ⦃G, L⦄ ⊢ T2 ⬈[h] T.
 120 #h #o #G #L #T0 #T1 #HT01 #T2 #HT02
 121 elim (cpx_tdeq_conf_lexs … HT01 … HT02 L … L) -HT01 -HT02
 122 /2 width=3 by lfxs_refl, ex2_intro/
 123 qed-.
 124
 125 lemma tdeq_cpx_trans: ∀h,o,G,L,T2. ∀T0:term. T2 ≡[h, o] T0 →
 126                       ∀T1. ⦃G, L⦄ ⊢ T0 ⬈[h] T1 →
 127                       ∃∃T. ⦃G, L⦄ ⊢ T2 ⬈[h] T & T ≡[h, o] T1.
 128 #h #o #G #L #T2 #T0 #HT20 #T1 #HT01
 129 elim (cpx_tdeq_conf … HT01 T2) -HT01 /3 width=3 by tdeq_sym, ex2_intro/
 130 qed-.
 131
 132 (* Basic_2A1: uses: cpx_lleq_conf *)
 133 lemma cpx_lfdeq_conf: ∀h,o,G,L0,T0,T1. ⦃G, L0⦄ ⊢ T0 ⬈[h] T1 →
 134                       ∀L2. L0 ≡[h, o, T0] L2 →
 135                       ∃∃T. ⦃G, L2⦄ ⊢ T0 ⬈[h] T & T1 ≡[h, o] T.
 136 #h #o #G #L0 #T0 #T1 #HT01 #L2 #HL02
 137 elim (cpx_tdeq_conf_lexs … HT01 T0 … L0 … HL02) -HT01 -HL02
 138 /2 width=3 by lfxs_refl, ex2_intro/
 139 qed-.
 140
 141 (* Basic_2A1: uses: lleq_cpx_trans *)
 142 lemma lfdeq_cpx_trans: ∀h,o,G,L2,L0,T0. L2 ≡[h, o, T0] L0 →
 143                        ∀T1. ⦃G, L0⦄ ⊢ T0 ⬈[h] T1 →
 144                        ∃∃T. ⦃G, L2⦄ ⊢ T0 ⬈[h] T & T ≡[h, o] T1.
 145 #h #o #G #L2 #L0 #T0 #HL20 #T1 #HT01
 146 elim (cpx_lfdeq_conf … o … HT01 L2) -HT01
 147 /3 width=3 by lfdeq_sym, tdeq_sym, ex2_intro/
 148 qed-.
 149
 150 lemma lfpx_lfdeq_conf: ∀h,o,G,T. confluent2 … (lfpx h G T) (lfdeq h o T).
 151 /3 width=6 by lfpx_frees_conf, cpx_tdeq_conf_lexs, frees_lfdeq_conf_lexs, lfxs_conf/ qed-.
 152
 153 (* Basic_2A1: uses: lleq_lpx_trans *)
 154 lemma lfdeq_lfpx_trans: ∀h,o,G,T,L2,K2. ⦃G, L2⦄ ⊢ ⬈[h, T] K2 →
 155                         ∀L1. L1 ≡[h, o, T] L2 →
 156                         ∃∃K1. ⦃G, L1⦄ ⊢ ⬈[h, T] K1 & K1 ≡[h, o, T] K2.
 157 #h #o #G #T #L2 #K2 #HLK2 #L1 #HL12
 158 elim (lfpx_lfdeq_conf … o … HLK2 L1)
 159 /3 width=3 by lfdeq_sym, ex2_intro/
 160 qed-.