matita/matita/contribs/lambdadelta/basic_2/rt_transition/lfpx_lfdeq.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/relocation/lifts_tdeq.ma".
  16 include "basic_2/static/lfxs_lfxs.ma".
  17 include "basic_2/static/lfdeq_fqup.ma".
  18 include "basic_2/rt_transition/lfpx_frees.ma".
  19 include "basic_2/rt_transition/lfpx.ma". (**) (* should be in lfpx_frees.ma *)
  20
  21 (* UNCOUNTED PARALLEL RT-TRANSITION FOR LOCAL ENV.S ON REFERRED ENTRIES *****)
  22
  23 (* Properties with degree-based equivalence for local environments **********)
  24
  25 lemma cpx_tdeq_conf_lexs: ∀h,o,G. R_confluent2_lfxs … (cpx h G) (cdeq h o) (cpx h G) (cdeq h o).
  26 #h #o #G #L0 #T0 #T1 #H @(cpx_ind … H) -G -L0 -T0 -T1 /2 width=3 by ex2_intro/
  27 [ #G #L0 #s0 #X0 #H0 #L1 #HL01 #L2 #HL02
  28   elim (tdeq_inv_sort1 … H0) -H0 #s1 #d1 #Hs0 #Hs1 #H destruct
  29   /4 width=3 by tdeq_sort, deg_next, ex2_intro/
  30 | #I #G #K0 #V0 #V1 #W1 #_ #IH #HVW1 #T2 #H0 #L1 #H1 #L2 #H2
  31   >(tdeq_inv_lref1 … H0) -H0
  32   elim (lfpx_inv_zero_pair_sn … H1) -H1 #K1 #X1 #HK01 #HX1 #H destruct
  33   elim (lfdeq_inv_zero_pair_sn … H2) -H2 #K2 #X2 #HK02 #HX2 #H destruct
  34   elim (IH X2 … HK01 … HK02) // -K0 -V0 #V #HV1 #HV2
  35   elim (tdeq_lifts_sn … HV1 … HVW1) -V1 /3 width=5 by cpx_delta, ex2_intro/
  36 | #I #G #K0 #V0 #V1 #W1 #i #_ #IH #HVW1 #T2 #H0 #L1 #H1 #L2 #H2
  37   >(tdeq_inv_lref1 … H0) -H0
  38   elim (lfpx_inv_lref_pair_sn … H1) -H1 #K1 #X1 #HK01 #H destruct
  39   elim (lfdeq_inv_lref_pair_sn … H2) -H2 #K2 #X2 #HK02 #H destruct
  40   elim (IH … HK01 … HK02) [|*: //] -K0 -V0 #V #HV1 #HV2
  41   elim (tdeq_lifts_sn … HV1 … HVW1) -V1 /3 width=5 by cpx_lref, ex2_intro/
  42 | #p #I #G #L0 #V0 #V1 #T0 #T1 #_ #_ #IHV #IHT #X0 #H0 #L1 #H1 #L2 #H2
  43   elim (tdeq_inv_pair1 … H0) -H0 #V2 #T2 #HV02 #HT02 #H destruct
  44   elim (lfpx_inv_bind … H1) -H1 #HL01 #H1
  45   elim (lfdeq_inv_bind … H2) -H2 #HL02 #H2
  46   lapply (lfdeq_pair_repl_dx … H2 … HV02) -H2 #H2
  47   elim (IHV … HV02 … HL01 … HL02) -IHV -HV02 -HL01 -HL02
  48   elim (IHT … HT02 … H1 … H2) -L0 -T0
  49   /3 width=5 by cpx_bind, tdeq_pair, ex2_intro/
  50 | #I #G #L0 #V0 #V1 #T0 #T1 #_ #_ #IHV #IHT #X0 #H0 #L1 #H1 #L2 #H2
  51   elim (tdeq_inv_pair1 … H0) -H0 #V2 #T2 #HV02 #HT02 #H destruct
  52   elim (lfpx_inv_flat … H1) -H1 #HL01 #H1
  53   elim (lfdeq_inv_flat … H2) -H2 #HL02 #H2
  54   elim (IHV … HV02 … HL01 … HL02) -IHV -HV02 -HL01 -HL02
  55   elim (IHT … HT02 … H1 … H2) -L0 -V0 -T0
  56   /3 width=5 by cpx_flat, tdeq_pair, ex2_intro/
  57 | #G #L0 #V0 #T0 #T1 #U1 #_ #IH #HUT1 #X0 #H0 #L1 #H1 #L2 #H2
  58   elim (tdeq_inv_pair1 … H0) -H0 #V2 #T2 #HV02 #HT02 #H destruct
  59   elim (lfpx_inv_bind … H1) -H1 #HL01 #H1
  60   elim (lfdeq_inv_bind … H2) -H2 #HL02 #H2
  61   lapply (lfdeq_pair_repl_dx … H2 … HV02) -H2 -HV02 #H2
  62   elim (IH … HT02 … H1 … H2) -L0 -T0 #T #HT1
  63   elim (tdeq_inv_lifts_sn … HT1 … HUT1) -T1
  64   /3 width=5 by cpx_zeta, ex2_intro/
  65 | #G #L0 #V0 #T0 #T1 #_ #IH #X0 #H0 #L1 #H1 #L2 #H2
  66   elim (tdeq_inv_pair1 … H0) -H0 #V2 #T2 #_ #HT02 #H destruct
  67   elim (lfpx_inv_flat … H1) -H1 #HL01 #H1
  68   elim (lfdeq_inv_flat … H2) -H2 #HL02 #H2
  69   elim (IH … HT02 … H1 … H2) -L0 -V0 -T0
  70   /3 width=3 by cpx_eps, ex2_intro/
  71 | #G #L0 #V0 #T0 #T1 #_ #IH #X0 #H0 #L1 #H1 #L2 #H2
  72   elim (tdeq_inv_pair1 … H0) -H0 #V2 #T2 #HV02 #_ #H destruct
  73   elim (lfpx_inv_flat … H1) -H1 #HL01 #H1
  74   elim (lfdeq_inv_flat … H2) -H2 #HL02 #H2
  75   elim (IH … HV02 … HL01 … HL02) -L0 -V0 -T1
  76   /3 width=3 by cpx_ee, ex2_intro/
  77 | #p #G #L0 #V0 #V1 #W0 #W1 #T0 #T1 #_ #_ #_ #IHV #IHW #IHT #X0 #H0 #L1 #H1 #L2 #H2
  78   elim (tdeq_inv_pair1 … H0) -H0 #V2 #X #HV02 #H0 #H destruct
  79   elim (tdeq_inv_pair1 … H0) -H0 #W2 #T2 #HW02 #HT02 #H destruct
  80   elim (lfpx_inv_flat … H1) -H1 #H1LV0 #H1
  81   elim (lfpx_inv_bind … H1) -H1 #H1LW0 #H1LT0
  82   elim (lfdeq_inv_flat … H2) -H2 #H2LV0 #H2
  83   elim (lfdeq_inv_bind … H2) -H2 #H2LW0 #H2LT0
  84   lapply (lfdeq_pair_repl_dx … H2LT0 … HW02) -H2LT0 #H2LT0
  85   elim (IHV … HV02 … H1LV0 … H2LV0) -IHV -HV02 -H1LV0 -H2LV0
  86   elim (IHW … HW02 … H1LW0 … H2LW0) -IHW -HW02 -H1LW0 -H2LW0
  87   elim (IHT … HT02 … H1LT0 … H2LT0) -L0 -V0 -T0
  88   /4 width=7 by cpx_beta, tdeq_pair, ex2_intro/ (* note: 2 tdeq_pair *)
  89 | #p #G #L0 #V0 #V1 #U1 #W0 #W1 #T0 #T1 #_ #_ #_ #IHV #IHW #IHT #HVU1 #X0 #H0 #L1 #H1 #L2 #H2
  90   elim (tdeq_inv_pair1 … H0) -H0 #V2 #X #HV02 #H0 #H destruct
  91   elim (tdeq_inv_pair1 … H0) -H0 #W2 #T2 #HW02 #HT02 #H destruct
  92   elim (lfpx_inv_flat … H1) -H1 #H1LV0 #H1
  93   elim (lfpx_inv_bind … H1) -H1 #H1LW0 #H1LT0
  94   elim (lfdeq_inv_flat … H2) -H2 #H2LV0 #H2
  95   elim (lfdeq_inv_bind … H2) -H2 #H2LW0 #H2LT0
  96   lapply (lfdeq_pair_repl_dx … H2LT0 … HW02) -H2LT0 #H2LT0
  97   elim (IHV … HV02 … H1LV0 … H2LV0) -IHV -HV02 -H1LV0 -H2LV0 #V #HV1
  98   elim (IHW … HW02 … H1LW0 … H2LW0) -IHW -HW02 -H1LW0 -H2LW0
  99   elim (IHT … HT02 … H1LT0 … H2LT0) -L0 -V0 -T0
 100   elim (tdeq_lifts_sn … HV1 … HVU1) -V1
 101   /4 width=9 by cpx_theta, tdeq_pair, ex2_intro/ (* note: 2 tdeq_pair *)
 102 ]
 103 qed-.
 104
 105 lemma cpx_tdeq_conf: ∀h,o,G,L,T0,T1. ⦃G, L⦄ ⊢ T0 ⬈[h] T1 →
 106                      ∀T2. T0 ≡[h, o] T2 →
 107                      ∃∃T. T1 ≡[h, o] T & ⦃G, L⦄ ⊢ T2 ⬈[h] T.
 108 #h #o #G #L #T0 #T1 #HT01 #T2 #HT02
 109 elim (cpx_tdeq_conf_lexs … HT01 … HT02 L … L) -HT01 -HT02
 110 /2 width=3 by lfxs_refl, ex2_intro/
 111 qed-.
 112
 113 lemma tdeq_cpx_trans: ∀h,o,G,L,T2,T0. T2 ≡[h, o] T0 →
 114                       ∀T1. ⦃G, L⦄ ⊢ T0 ⬈[h] T1 →
 115                       ∃∃T. ⦃G, L⦄ ⊢ T2 ⬈[h] T & T ≡[h, o] T1.
 116 #h #o #G #L #T2 #T0 #HT20 #T1 #HT01
 117 elim (cpx_tdeq_conf … HT01 T2) -HT01 /3 width=3 by tdeq_sym, ex2_intro/
 118 qed-.
 119
 120 (* Basic_2A1: was just: cpx_lleq_conf *)
 121 lemma cpx_lfdeq_conf: ∀h,o,G,L0,T0,T1. ⦃G, L0⦄ ⊢ T0 ⬈[h] T1 →
 122                       ∀L2. L0 ≡[h, o, T0] L2 →
 123                       ∃∃T. ⦃G, L2⦄ ⊢ T0 ⬈[h] T & T1 ≡[h, o] T.
 124 #h #o #G #L0 #T0 #T1 #HT01 #L2 #HL02
 125 elim (cpx_tdeq_conf_lexs … HT01 T0 … L0 … HL02) -HT01 -HL02
 126 /2 width=3 by lfxs_refl, ex2_intro/
 127 qed-.
 128
 129 (* Basic_2A1: was just: lleq_cpx_trans *)
 130 lemma lfdeq_cpx_trans: ∀h,o,G,L2,L0,T0. L2 ≡[h, o, T0] L0 →
 131                        ∀T1. ⦃G, L0⦄ ⊢ T0 ⬈[h] T1 →
 132                        ∃∃T. ⦃G, L2⦄ ⊢ T0 ⬈[h] T & T ≡[h, o] T1.
 133 #h #o #G #L2 #L0 #T0 #HL20 #T1 #HT01
 134 elim (cpx_lfdeq_conf … o … HT01 L2) -HT01
 135 /3 width=3 by lfdeq_sym, tdeq_sym, ex2_intro/
 136 qed-.
 137
 138 lemma lfpx_lfdeq_conf: ∀h,o,G,T. confluent2 … (lfpx h G T) (lfdeq h o T).
 139 /3 width=6 by lfpx_frees_conf, cpx_tdeq_conf_lexs, frees_lfdeq_conf_lexs, lfxs_conf/ qed-.
 140
 141 (* Basic_2A1: was just: lleq_lpx_trans *)
 142 lemma lfdeq_lfpx_trans: ∀h,o,G,T,L2,K2. ⦃G, L2⦄ ⊢ ⬈[h, T] K2 →
 143                         ∀L1. L1 ≡[h, o, T] L2 →
 144                         ∃∃K1. ⦃G, L1⦄ ⊢ ⬈[h, T] K1 & K1 ≡[h, o, T] K2.
 145 #h #o #G #T #L2 #K2 #HLK2 #L1 #HL12
 146 elim (lfpx_lfdeq_conf … o … HLK2 L1)
 147 /3 width=3 by lfdeq_sym, ex2_intro/
 148 qed-.
 149 (*
 150 (* Properties with supclosure ***********************************************)
 151
 152 lemma lpx_lleq_fqu_trans: ∀h,o,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐ ⦃G2, L2, T2⦄ →
 153                           ∀K1. ⦃G1, K1⦄ ⊢ ➡[h, o] L1 → K1 ≡[T1, 0] L1 →
 154                           ∃∃K2. ⦃G1, K1, T1⦄ ⊐ ⦃G2, K2, T2⦄ & ⦃G2, K2⦄ ⊢ ➡[h, o] L2 & K2 ≡[T2, 0] L2.
 155 #h #o #G1 #G2 #L1 #L2 #T1 #T2 #H elim H -G1 -G2 -L1 -L2 -T1 -T2
 156 [ #I #G1 #L1 #V1 #X #H1 #H2 elim (lpx_inv_pair2 … H1) -H1
 157   #K0 #V0 #H1KL1 #_ #H destruct
 158   elim (lleq_inv_lref_ge_dx … H2 ? I L1 V1) -H2 //
 159   #K1 #H #H2KL1 lapply (drop_inv_O2 … H) -H #H destruct
 160   /2 width=4 by fqu_lref_O, ex3_intro/
 161 | * [ #a ] #I #G1 #L1 #V1 #T1 #K1 #HLK1 #H
 162   [ elim (lleq_inv_bind … H)
 163   | elim (lleq_inv_flat … H)
 164   ] -H /2 width=4 by fqu_pair_sn, ex3_intro/
 165 | #a #I #G1 #L1 #V1 #T1 #K1 #HLK1 #H elim (lleq_inv_bind_O … H) -H
 166   /3 width=4 by lpx_pair, fqu_bind_dx, ex3_intro/
 167 | #I #G1 #L1 #V1 #T1 #K1 #HLK1 #H elim (lleq_inv_flat … H) -H
 168   /2 width=4 by fqu_flat_dx, ex3_intro/
 169 | #G1 #L1 #L #T1 #U1 #k #HL1 #HTU1 #K1 #H1KL1 #H2KL1
 170   elim (drop_O1_le (Ⓕ) (k+1) K1)
 171   [ #K #HK1 lapply (lleq_inv_lift_le … H2KL1 … HK1 HL1 … HTU1 ?) -H2KL1 //
 172     #H2KL elim (lpx_drop_trans_O1 … H1KL1 … HL1) -L1
 173     #K0 #HK10 #H1KL lapply (drop_mono … HK10 … HK1) -HK10 #H destruct
 174     /3 width=4 by fqu_drop, ex3_intro/
 175   | lapply (drop_fwd_length_le2 … HL1) -L -T1 -o
 176     lapply (lleq_fwd_length … H2KL1) //
 177   ]
 178 ]
 179 qed-.
 180
 181 lemma lpx_lleq_fquq_trans: ∀h,o,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐⸮ ⦃G2, L2, T2⦄ →
 182                            ∀K1. ⦃G1, K1⦄ ⊢ ➡[h, o] L1 → K1 ≡[T1, 0] L1 →
 183                            ∃∃K2. ⦃G1, K1, T1⦄ ⊐⸮ ⦃G2, K2, T2⦄ & ⦃G2, K2⦄ ⊢ ➡[h, o] L2 & K2 ≡[T2, 0] L2.
 184 #h #o #G1 #G2 #L1 #L2 #T1 #T2 #H #K1 #H1KL1 #H2KL1
 185 elim (fquq_inv_gen … H) -H
 186 [ #H elim (lpx_lleq_fqu_trans … H … H1KL1 H2KL1) -L1
 187   /3 width=4 by fqu_fquq, ex3_intro/
 188 | * #HG #HL #HT destruct /2 width=4 by ex3_intro/
 189 ]
 190 qed-.
 191
 192 lemma lpx_lleq_fqup_trans: ∀h,o,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐+ ⦃G2, L2, T2⦄ →
 193                            ∀K1. ⦃G1, K1⦄ ⊢ ➡[h, o] L1 → K1 ≡[T1, 0] L1 →
 194                            ∃∃K2. ⦃G1, K1, T1⦄ ⊐+ ⦃G2, K2, T2⦄ & ⦃G2, K2⦄ ⊢ ➡[h, o] L2 & K2 ≡[T2, 0] L2.
 195 #h #o #G1 #G2 #L1 #L2 #T1 #T2 #H @(fqup_ind … H) -G2 -L2 -T2
 196 [ #G2 #L2 #T2 #H #K1 #H1KL1 #H2KL1 elim (lpx_lleq_fqu_trans … H … H1KL1 H2KL1) -L1
 197   /3 width=4 by fqu_fqup, ex3_intro/
 198 | #G #G2 #L #L2 #T #T2 #_ #HT2 #IHT1 #K1 #H1KL1 #H2KL1 elim (IHT1 … H2KL1) // -L1
 199   #K #HT1 #H1KL #H2KL elim (lpx_lleq_fqu_trans … HT2 … H1KL H2KL) -L
 200   /3 width=5 by fqup_strap1, ex3_intro/
 201 ]
 202 qed-.
 203
 204 lemma lpx_lleq_fqus_trans: ∀h,o,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐* ⦃G2, L2, T2⦄ →
 205                            ∀K1. ⦃G1, K1⦄ ⊢ ➡[h, o] L1 → K1 ≡[T1, 0] L1 →
 206                            ∃∃K2. ⦃G1, K1, T1⦄ ⊐* ⦃G2, K2, T2⦄ & ⦃G2, K2⦄ ⊢ ➡[h, o] L2 & K2 ≡[T2, 0] L2.
 207 #h #o #G1 #G2 #L1 #L2 #T1 #T2 #H #K1 #H1KL1 #H2KL1
 208 elim (fqus_inv_gen … H) -H
 209 [ #H elim (lpx_lleq_fqup_trans … H … H1KL1 H2KL1) -L1
 210   /3 width=4 by fqup_fqus, ex3_intro/
 211 | * #HG #HL #HT destruct /2 width=4 by ex3_intro/
 212 ]
 213 qed-.
 214 *)