matita/matita/contribs/lambdadelta/basic_2/rt_transition/lpx_aaa.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/static/aaa_drops.ma".
  16 include "static_2/static/lsuba_aaa.ma".
  17 include "basic_2/rt_transition/lpx_drops.ma".
  18
  19 (* EXTENDED PARALLEL RT-TRANSITION FOR FULL LOCAL ENVIRONMENTS **************)
  20
  21 (* Properties with atomic arity assignment for terms ************************)
  22
  23 (* Note: lemma 500 *)
  24 (* Basic_2A1: was: cpx_lpx_aaa_conf *)
  25 lemma cpx_aaa_conf_lpx (G) (L1):
  26       ∀T1,A. ❪G,L1❫ ⊢ T1 ⁝ A →
  27       ∀T2. ❪G,L1❫ ⊢ T1 ⬈ T2 →
  28       ∀L2. ❪G,L1❫ ⊢ ⬈ L2 → ❪G,L2❫ ⊢ T2 ⁝ A.
  29 #G #L1 #T1 #A #H elim H -G -L1 -T1 -A
  30 [ #G #L1 #s1 #X #H
  31   elim (cpx_inv_sort1 … H) -H #s2 #H destruct //
  32 | #I #G #K1 #V1 #B #_ #IH #X #HX #Y #HY
  33   elim (lpx_inv_pair_sn … HY) -HY #K2 #V2 #HK12 #HV12 #H destruct
  34   elim (cpx_inv_zero1_pair … HX) -HX
  35   [ #H destruct /3 width=1 by aaa_zero/
  36   | * #V #HV1 #HVX -HV12
  37     /4 width=7 by aaa_lifts, drops_refl, drops_drop, true/
  38   ]
  39 | #I1 #G #K1 #A #i #_ #IH #X #HX #Y #HY
  40   elim (lpx_inv_bind_sn … HY) -HY #I2 #K2 #HK12 #_ #H destruct
  41   elim (cpx_inv_lref1_bind … HX) -HX
  42   [ #H destruct /3 width=1 by aaa_lref/
  43   | * #T #HT #HTX
  44     /4 width=7 by aaa_lifts, drops_refl, drops_drop, true/
  45   ]
  46 | #p #G #L1 #V1 #T1 #B #A #_ #_ #IHV1 #IHT1 #X #H #L2 #HL12
  47   elim (cpx_inv_abbr1 … H) -H *
  48   [ #V2 #T2 #HV12 #HT12 #H destruct /4 width=2 by lpx_pair, aaa_abbr/
  49   | #X1 #HXT1 #HX1 #H destruct -IHV1
  50     elim (cpx_lifts_sn … HX1 (Ⓣ) … (L1.ⓓV1) … HXT1) -X1
  51     /4 width=7 by lpx_pair, aaa_inv_lifts, drops_refl, drops_drop/
  52   ]
  53 | #p #G #L1 #V1 #T1 #B #A #_ #_ #IHV1 #IHT1 #X #H #L2 #HL12
  54   elim (cpx_inv_abst1 … H) -H #V2 #T2 #HV12 #HT12 #H destruct
  55   /4 width=1 by lpx_pair, aaa_abst/
  56 | #G #L1 #V1 #T1 #B #A #_ #_ #IHV1 #IHT1 #X #H #L2 #HL12
  57   elim (cpx_inv_appl1 … H) -H *
  58   [ #V2 #T2 #HV12 #HT12 #H destruct /3 width=3 by aaa_appl/
  59   | #q #V2 #W1 #W2 #U1 #U2 #HV12 #HW12 #HU12 #H1 #H2 destruct
  60     lapply (IHV1 … HV12 … HL12) -IHV1 -HV12 #HV2
  61     lapply (IHT1 (ⓛ[q]W2.U2) … HL12) -IHT1 /2 width=1 by cpx_bind/ -L1 #H
  62     elim (aaa_inv_abst … H) -H #B0 #A0 #HW1 #HU2 #H destruct
  63     /5 width=6 by lsuba_aaa_trans, lsuba_beta, aaa_abbr, aaa_cast/
  64   | #q #V #V2 #W1 #W2 #U1 #U2 #HV1 #HV2 #HW12 #HU12 #H1 #H2 destruct
  65     lapply (aaa_lifts G L2 … B … (L2.ⓓW2) … HV2) -HV2 /3 width=2 by drops_refl, drops_drop/ #HV2
  66     lapply (IHT1 (ⓓ[q]W2.U2) … HL12) -IHT1 /2 width=1 by cpx_bind/ -L1 #H
  67     elim (aaa_inv_abbr … H) -H /3 width=3 by aaa_abbr, aaa_appl/
  68   ]
  69 | #G #L1 #V1 #T1 #A #_ #_ #IHV1 #IHT1 #X #H #L2 #HL12
  70   elim (cpx_inv_cast1 … H) -H
  71   [ * #V2 #T2 #HV12 #HT12 #H destruct /3 width=1 by aaa_cast/
  72   | -IHV1 /2 width=1 by/
  73   | -IHT1 /2 width=1 by/
  74   ]
  75 ]
  76 qed-.
  77
  78 lemma cpx_aaa_conf (G) (L): Conf3 … (aaa G L) (cpx G L).
  79 /2 width=7 by cpx_aaa_conf_lpx/ qed-.
  80
  81 lemma lpx_aaa_conf (G):
  82       ∀T. Conf3 … (λL. aaa G L T) (lpx G).
  83 /2 width=7 by cpx_aaa_conf_lpx/ qed-.