matita/matita/contribs/lambdadelta/basic_2/rt_transition/lpx_aaa.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/static/aaa_drops.ma".
  16 include "static_2/static/lsuba_aaa.ma".
  17 include "basic_2/rt_transition/lpx_drops.ma".
  18
  19 (* UNBOUND PARALLEL RT-TRANSITION FOR FULL LOCAL ENVIRONMENTS ***************)
  20
  21 (* Properties with atomic arity assignment for terms ************************)
  22
  23 (* Note: lemma 500 *)
  24 (* Basic_2A1: was: cpx_lpx_aaa_conf *)
  25 lemma cpx_aaa_conf_lpx (h): ∀G,L1,T1,A. ⦃G, L1⦄ ⊢ T1 ⁝ A →
  26                             ∀T2. ⦃G, L1⦄ ⊢ T1 ⬈[h] T2 →
  27                             ∀L2. ⦃G, L1⦄ ⊢ ⬈[h] L2 → ⦃G, L2⦄ ⊢ T2 ⁝ A.
  28 #h #G #L1 #T1 #A #H elim H -G -L1 -T1 -A
  29 [ #G #L1 #s #X #H
  30   elim (cpx_inv_sort1 … H) -H #H destruct //
  31 | #I #G #K1 #V1 #B #_ #IH #X #HX #Y #HY
  32   elim (lpx_inv_pair_sn … HY) -HY #K2 #V2 #HK12 #HV12 #H destruct
  33   elim (cpx_inv_zero1_pair … HX) -HX
  34   [ #H destruct /3 width=1 by aaa_zero/
  35   | * #V #HV1 #HVX -HV12
  36     /4 width=7 by aaa_lifts, drops_refl, drops_drop, true/
  37   ]
  38 | #I1 #G #K1 #A #i #_ #IH #X #HX #Y #HY
  39   elim (lpx_inv_bind_sn … HY) -HY #I2 #K2 #HK12 #_ #H destruct
  40   elim (cpx_inv_lref1_bind … HX) -HX
  41   [ #H destruct /3 width=1 by aaa_lref/
  42   | * #T #HT #HTX
  43     /4 width=7 by aaa_lifts, drops_refl, drops_drop, true/
  44   ]
  45 | #p #G #L1 #V1 #T1 #B #A #_ #_ #IHV1 #IHT1 #X #H #L2 #HL12
  46   elim (cpx_inv_abbr1 … H) -H *
  47   [ #V2 #T2 #HV12 #HT12 #H destruct /4 width=2 by lpx_pair, aaa_abbr/
  48   | #T2 #HT12 #HT2 #H destruct -IHV1
  49     /4 width=8 by lpx_pair, aaa_inv_lifts, drops_refl, drops_drop/
  50   ]
  51 | #p #G #L1 #V1 #T1 #B #A #_ #_ #IHV1 #IHT1 #X #H #L2 #HL12
  52   elim (cpx_inv_abst1 … H) -H #V2 #T2 #HV12 #HT12 #H destruct
  53   /4 width=1 by lpx_pair, aaa_abst/
  54 | #G #L1 #V1 #T1 #B #A #_ #_ #IHV1 #IHT1 #X #H #L2 #HL12
  55   elim (cpx_inv_appl1 … H) -H *
  56   [ #V2 #T2 #HV12 #HT12 #H destruct /3 width=3 by aaa_appl/
  57   | #q #V2 #W1 #W2 #U1 #U2 #HV12 #HW12 #HU12 #H1 #H2 destruct
  58     lapply (IHV1 … HV12 … HL12) -IHV1 -HV12 #HV2
  59     lapply (IHT1 (ⓛ{q}W2.U2) … HL12) -IHT1 /2 width=1 by cpx_bind/ -L1 #H
  60     elim (aaa_inv_abst … H) -H #B0 #A0 #HW1 #HU2 #H destruct
  61     /5 width=6 by lsuba_aaa_trans, lsuba_beta, aaa_abbr, aaa_cast/
  62   | #q #V #V2 #W1 #W2 #U1 #U2 #HV1 #HV2 #HW12 #HU12 #H1 #H2 destruct
  63     lapply (aaa_lifts G L2 … B … (L2.ⓓW2) … HV2) -HV2 /3 width=2 by drops_refl, drops_drop/ #HV2
  64     lapply (IHT1 (ⓓ{q}W2.U2) … HL12) -IHT1 /2 width=1 by cpx_bind/ -L1 #H
  65     elim (aaa_inv_abbr … H) -H /3 width=3 by aaa_abbr, aaa_appl/
  66   ]
  67 | #G #L1 #V1 #T1 #A #_ #_ #IHV1 #IHT1 #X #H #L2 #HL12
  68   elim (cpx_inv_cast1 … H) -H
  69   [ * #V2 #T2 #HV12 #HT12 #H destruct /3 width=1 by aaa_cast/
  70   | -IHV1 /2 width=1 by/
  71   | -IHT1 /2 width=1 by/
  72   ]
  73 ]
  74 qed-.
  75
  76 lemma cpx_aaa_conf (h): ∀G,L. Conf3 … (aaa G L) (cpx h G L).
  77 /2 width=7 by cpx_aaa_conf_lpx/ qed-.
  78
  79 lemma lpx_aaa_conf (h): ∀G,T. Conf3 … (λL. aaa G L T) (lpx h G).
  80 /2 width=7 by cpx_aaa_conf_lpx/ qed-.