matita/matita/contribs/lambdadelta/basic_2/rt_transition/lpx_fquq.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/s_transition/fquq.ma".
  16 include "basic_2/rt_transition/lpx.ma".
  17
  18 (* UNBOUND PARALLEL RT-TRANSITION FOR FULL LOCAL ENVIRONMENTS ***************)
  19
  20 (* Properties with extended structural successor for closures ***************)
  21
  22 lemma lpx_fqu_trans (h) (b): ∀G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐[b] ⦃G2, L2, T2⦄ →
  23                              ∀K1. ⦃G1, K1⦄ ⊢ ⬈[h] L1 →
  24                              ∃∃K2,T. ⦃G1, K1⦄ ⊢ T1 ⬈[h] T & ⦃G1, K1, T⦄ ⊐[b] ⦃G2, K2, T2⦄ & ⦃G2, K2⦄ ⊢ ⬈[h] L2.
  25 #h #b #G1 #G2 #L1 #L2 #T1 #T2 #H elim H -G1 -G2 -L1 -L2 -T1 -T2
  26 [ #I #G #K #V #K1 #H
  27   elim (lpx_inv_pair_dx … H) -H #K0 #V0 #HK0 #HV0 #H destruct
  28   elim (lifts_total V (𝐔❴1❵)) #T #HVT
  29   /3 width=5 by cpx_delta, fqu_drop, ex3_2_intro/
  30 | /3 width=5 by cpx_pair_sn, fqu_pair_sn, ex3_2_intro/
  31 | /3 width=5 by lpx_bind_refl_dx, cpx_pair_sn, fqu_bind_dx, ex3_2_intro/
  32 | /3 width=5 by lpx_bind_refl_dx, cpx_pair_sn, fqu_clear, ex3_2_intro/
  33 | /3 width=5 by cpx_pair_sn, fqu_flat_dx, ex3_2_intro/
  34 | #I #G #K #T #U #HTU #K1 #H
  35   elim (lpx_inv_bind_dx … H) -H #I0 #K0 #HK0 #HI0 #H destruct
  36   /3 width=5 by fqu_drop, ex3_2_intro/
  37 ]
  38 qed-.
  39
  40 lemma fqu_lpx_trans (h) (b): ∀G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐[b] ⦃G2, L2, T2⦄ →
  41                              ∀K2. ⦃G2, L2⦄ ⊢ ⬈[h] K2 →
  42                              ∃∃K1,T. ⦃G1, L1⦄ ⊢ ⬈[h] K1 & ⦃G1, L1⦄ ⊢ T1 ⬈[h] T & ⦃G1, K1, T⦄ ⊐[b] ⦃G2, K2, T2⦄.
  43 #h #b #G1 #G2 #L1 #L2 #T1 #T2 #H elim H -G1 -G2 -L1 -L2 -T1 -T2
  44 [ /3 width=5 by lpx_bind_refl_dx, fqu_lref_O, ex3_2_intro/
  45 | /3 width=5 by cpx_pair_sn, fqu_pair_sn, ex3_2_intro/
  46 | #p #I #G2 #L2 #V2 #T2 #X #H
  47   elim (lpx_inv_pair_sn … H) -H #K2 #W2 #HLK2 #HVW2 #H destruct
  48   /3 width=5 by cpx_pair_sn, fqu_bind_dx, ex3_2_intro/
  49 | #p #I #G2 #L2 #V2 #T2 #Hb #X #H
  50   elim (lpx_inv_unit_sn … H) -H #K2 #HLK2 #H destruct
  51   /3 width=5 by cpx_pair_sn, fqu_clear, ex3_2_intro/
  52 | /3 width=5 by cpx_pair_sn, fqu_flat_dx, ex3_2_intro/
  53 | /3 width=5 by lpx_bind_refl_dx, fqu_drop, ex3_2_intro/
  54 ]
  55 qed-.
  56
  57 (* Properties with extended optional structural successor for closures ******)
  58
  59 lemma lpx_fquq_trans (h) (b): ∀G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐⸮[b] ⦃G2, L2, T2⦄ →
  60                               ∀K1. ⦃G1, K1⦄ ⊢ ⬈[h] L1 →
  61                               ∃∃K2,T. ⦃G1, K1⦄ ⊢ T1 ⬈[h] T & ⦃G1, K1, T⦄ ⊐⸮[b] ⦃G2, K2, T2⦄ & ⦃G2, K2⦄ ⊢ ⬈[h] L2.
  62 #h #b #G1 #G2 #L1 #L2 #T1 #T2 #H #K1 #HKL1 cases H -H
  63 [ #H12 elim (lpx_fqu_trans … H12 … HKL1) -L1 /3 width=5 by fqu_fquq, ex3_2_intro/
  64 | * #H1 #H2 #H3 destruct /2 width=5 by ex3_2_intro/
  65 ]
  66 qed-.
  67
  68 lemma fquq_lpx_trans (h) (b): ∀G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐⸮[b] ⦃G2, L2, T2⦄ →
  69                               ∀K2. ⦃G2, L2⦄ ⊢ ⬈[h] K2 →
  70                               ∃∃K1,T. ⦃G1, L1⦄ ⊢ ⬈[h] K1 & ⦃G1, L1⦄ ⊢ T1 ⬈[h] T & ⦃G1, K1, T⦄ ⊐⸮[b] ⦃G2, K2, T2⦄.
  71 #h #b #G1 #G2 #L1 #L2 #T1 #T2 #H #K2 #HLK2 cases H -H
  72 [ #H12 elim (fqu_lpx_trans … H12 … HLK2) /3 width=5 by fqu_fquq, ex3_2_intro/
  73 | * #H1 #H2 #H3 destruct /2 width=5 by ex3_2_intro/
  74 ]
  75 qed-.