matita/matita/contribs/lambdadelta/basic_2/rt_transition/rpx_rdeq.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/static/rdeq_fqup.ma".
  16 include "static_2/static/rdeq_rdeq.ma".
  17 include "basic_2/rt_transition/rpx_fsle.ma".
  18
  19 (* UNBOUND PARALLEL RT-TRANSITION FOR REFERRED LOCAL ENVIRONMENTS ***********)
  20
  21 (* Properties with degree-based equivalence for local environments **********)
  22
  23 lemma rpx_pair_sn_split: ∀h,G,L1,L2,V. ⦃G, L1⦄ ⊢ ⬈[h, V] L2 → ∀o,I,T.
  24                          ∃∃L. ⦃G, L1⦄ ⊢ ⬈[h, ②{I}V.T] L & L ≛[h, o, V] L2.
  25 /3 width=5 by rpx_fsge_comp, rex_pair_sn_split/ qed-.
  26
  27 lemma rpx_flat_dx_split: ∀h,G,L1,L2,T. ⦃G, L1⦄ ⊢ ⬈[h, T] L2 → ∀o,I,V.
  28                          ∃∃L. ⦃G, L1⦄ ⊢ ⬈[h, ⓕ{I}V.T] L & L ≛[h, o, T] L2.
  29 /3 width=5 by rpx_fsge_comp, rex_flat_dx_split/ qed-.
  30
  31 lemma rpx_bind_dx_split: ∀h,I,G,L1,L2,V1,T. ⦃G, L1.ⓑ{I}V1⦄ ⊢ ⬈[h, T] L2 → ∀o,p.
  32                          ∃∃L,V. ⦃G, L1⦄ ⊢ ⬈[h, ⓑ{p,I}V1.T] L & L.ⓑ{I}V ≛[h, o, T] L2 & ⦃G, L1⦄ ⊢ V1 ⬈[h] V.
  33 /3 width=5 by rpx_fsge_comp, rex_bind_dx_split/ qed-.
  34
  35 lemma rpx_bind_dx_split_void: ∀h,G,K1,L2,T. ⦃G, K1.ⓧ⦄ ⊢ ⬈[h, T] L2 → ∀o,p,I,V.
  36                               ∃∃K2. ⦃G, K1⦄ ⊢ ⬈[h, ⓑ{p,I}V.T] K2 & K2.ⓧ ≛[h, o, T] L2.
  37 /3 width=5 by rpx_fsge_comp, rex_bind_dx_split_void/ qed-.
  38
  39 lemma rpx_tdeq_conf: ∀h,o,G. s_r_confluent1 … (cdeq h o) (rpx h G).
  40 /2 width=5 by tdeq_rex_conf/ qed-.
  41
  42 lemma rpx_tdeq_div: ∀h,o,T1,T2. T1 ≛[h, o] T2 →
  43                     ∀G,L1,L2. ⦃G, L1⦄ ⊢ ⬈[h, T2] L2 → ⦃G, L1⦄ ⊢ ⬈[h, T1] L2.
  44 /2 width=5 by tdeq_rex_div/ qed-.
  45
  46 lemma cpx_tdeq_conf_sex: ∀h,o,G. R_confluent2_rex … (cpx h G) (cdeq h o) (cpx h G) (cdeq h o).
  47 #h #o #G #L0 #T0 #T1 #H @(cpx_ind … H) -G -L0 -T0 -T1 /2 width=3 by ex2_intro/
  48 [ #G #L0 #s0 #X0 #H0 #L1 #HL01 #L2 #HL02
  49   elim (tdeq_inv_sort1 … H0) -H0 #s1 #d1 #Hs0 #Hs1 #H destruct
  50   /4 width=3 by tdeq_sort, deg_next, ex2_intro/
  51 | #I #G #K0 #V0 #V1 #W1 #_ #IH #HVW1 #T2 #H0 #L1 #H1 #L2 #H2
  52   >(tdeq_inv_lref1 … H0) -H0
  53   elim (rpx_inv_zero_pair_sn … H1) -H1 #K1 #X1 #HK01 #HX1 #H destruct
  54   elim (rdeq_inv_zero_pair_sn … H2) -H2 #K2 #X2 #HK02 #HX2 #H destruct
  55   elim (IH X2 … HK01 … HK02) // -K0 -V0 #V #HV1 #HV2
  56   elim (tdeq_lifts_sn … HV1 … HVW1) -V1 /3 width=5 by cpx_delta, ex2_intro/
  57 | #I0 #G #K0 #V1 #W1 #i #_ #IH #HVW1 #T2 #H0 #L1 #H1 #L2 #H2
  58   >(tdeq_inv_lref1 … H0) -H0
  59   elim (rpx_inv_lref_bind_sn … H1) -H1 #I1 #K1 #HK01 #H destruct
  60   elim (rdeq_inv_lref_bind_sn … H2) -H2 #I2 #K2 #HK02 #H destruct
  61   elim (IH … HK01 … HK02) [|*: //] -K0 #V #HV1 #HV2
  62   elim (tdeq_lifts_sn … HV1 … HVW1) -V1 /3 width=5 by cpx_lref, ex2_intro/
  63 | #p #I #G #L0 #V0 #V1 #T0 #T1 #_ #_ #IHV #IHT #X0 #H0 #L1 #H1 #L2 #H2
  64   elim (tdeq_inv_pair1 … H0) -H0 #V2 #T2 #HV02 #HT02 #H destruct
  65   elim (rpx_inv_bind … H1) -H1 #HL01 #H1
  66   elim (rdeq_inv_bind … H2) -H2 #HL02 #H2
  67   lapply (rdeq_bind_repl_dx … H2 (BPair I V2) ?) -H2 /2 width=1 by ext2_pair/ #H2
  68   elim (IHV … HV02 … HL01 … HL02) -IHV -HV02 -HL01 -HL02
  69   elim (IHT … HT02 … H1 … H2) -L0 -T0
  70   /3 width=5 by cpx_bind, tdeq_pair, ex2_intro/
  71 | #I #G #L0 #V0 #V1 #T0 #T1 #_ #_ #IHV #IHT #X0 #H0 #L1 #H1 #L2 #H2
  72   elim (tdeq_inv_pair1 … H0) -H0 #V2 #T2 #HV02 #HT02 #H destruct
  73   elim (rpx_inv_flat … H1) -H1 #HL01 #H1
  74   elim (rdeq_inv_flat … H2) -H2 #HL02 #H2
  75   elim (IHV … HV02 … HL01 … HL02) -IHV -HV02 -HL01 -HL02
  76   elim (IHT … HT02 … H1 … H2) -L0 -V0 -T0
  77   /3 width=5 by cpx_flat, tdeq_pair, ex2_intro/
  78 | #G #L0 #V0 #T0 #T1 #U1 #_ #IH #HUT1 #X0 #H0 #L1 #H1 #L2 #H2
  79   elim (tdeq_inv_pair1 … H0) -H0 #V2 #T2 #HV02 #HT02 #H destruct
  80   elim (rpx_inv_bind … H1) -H1 #HL01 #H1
  81   elim (rdeq_inv_bind … H2) -H2 #HL02 #H2
  82   lapply (rdeq_bind_repl_dx … H2 (BPair Abbr V2) ?) -H2 /2 width=1 by ext2_pair/ -HV02 #H2
  83   elim (IH … HT02 … H1 … H2) -L0 -T0 #T #HT1
  84   elim (tdeq_inv_lifts_sn … HT1 … HUT1) -T1
  85   /3 width=5 by cpx_zeta, ex2_intro/
  86 | #G #L0 #V0 #T0 #T1 #_ #IH #X0 #H0 #L1 #H1 #L2 #H2
  87   elim (tdeq_inv_pair1 … H0) -H0 #V2 #T2 #_ #HT02 #H destruct
  88   elim (rpx_inv_flat … H1) -H1 #HL01 #H1
  89   elim (rdeq_inv_flat … H2) -H2 #HL02 #H2
  90   elim (IH … HT02 … H1 … H2) -L0 -V0 -T0
  91   /3 width=3 by cpx_eps, ex2_intro/
  92 | #G #L0 #V0 #T0 #T1 #_ #IH #X0 #H0 #L1 #H1 #L2 #H2
  93   elim (tdeq_inv_pair1 … H0) -H0 #V2 #T2 #HV02 #_ #H destruct
  94   elim (rpx_inv_flat … H1) -H1 #HL01 #H1
  95   elim (rdeq_inv_flat … H2) -H2 #HL02 #H2
  96   elim (IH … HV02 … HL01 … HL02) -L0 -V0 -T1
  97   /3 width=3 by cpx_ee, ex2_intro/
  98 | #p #G #L0 #V0 #V1 #W0 #W1 #T0 #T1 #_ #_ #_ #IHV #IHW #IHT #X0 #H0 #L1 #H1 #L2 #H2
  99   elim (tdeq_inv_pair1 … H0) -H0 #V2 #X #HV02 #H0 #H destruct
 100   elim (tdeq_inv_pair1 … H0) -H0 #W2 #T2 #HW02 #HT02 #H destruct
 101   elim (rpx_inv_flat … H1) -H1 #H1LV0 #H1
 102   elim (rpx_inv_bind … H1) -H1 #H1LW0 #H1LT0
 103   elim (rdeq_inv_flat … H2) -H2 #H2LV0 #H2
 104   elim (rdeq_inv_bind … H2) -H2 #H2LW0 #H2LT0
 105   lapply (rdeq_bind_repl_dx … H2LT0 (BPair Abst W2) ?) -H2LT0 /2 width=1 by ext2_pair/ #H2LT0
 106   elim (IHV … HV02 … H1LV0 … H2LV0) -IHV -HV02 -H1LV0 -H2LV0
 107   elim (IHW … HW02 … H1LW0 … H2LW0) -IHW -HW02 -H1LW0 -H2LW0
 108   elim (IHT … HT02 … H1LT0 … H2LT0) -L0 -V0 -T0
 109   /4 width=7 by cpx_beta, tdeq_pair, ex2_intro/ (* note: 2 tdeq_pair *)
 110 | #p #G #L0 #V0 #V1 #U1 #W0 #W1 #T0 #T1 #_ #_ #_ #IHV #IHW #IHT #HVU1 #X0 #H0 #L1 #H1 #L2 #H2
 111   elim (tdeq_inv_pair1 … H0) -H0 #V2 #X #HV02 #H0 #H destruct
 112   elim (tdeq_inv_pair1 … H0) -H0 #W2 #T2 #HW02 #HT02 #H destruct
 113   elim (rpx_inv_flat … H1) -H1 #H1LV0 #H1
 114   elim (rpx_inv_bind … H1) -H1 #H1LW0 #H1LT0
 115   elim (rdeq_inv_flat … H2) -H2 #H2LV0 #H2
 116   elim (rdeq_inv_bind … H2) -H2 #H2LW0 #H2LT0
 117   lapply (rdeq_bind_repl_dx … H2LT0 (BPair Abbr W2) ?) -H2LT0 /2 width=1 by ext2_pair/ #H2LT0
 118   elim (IHV … HV02 … H1LV0 … H2LV0) -IHV -HV02 -H1LV0 -H2LV0 #V #HV1
 119   elim (IHW … HW02 … H1LW0 … H2LW0) -IHW -HW02 -H1LW0 -H2LW0
 120   elim (IHT … HT02 … H1LT0 … H2LT0) -L0 -V0 -T0
 121   elim (tdeq_lifts_sn … HV1 … HVU1) -V1
 122   /4 width=9 by cpx_theta, tdeq_pair, ex2_intro/ (* note: 2 tdeq_pair *)
 123 ]
 124 qed-.
 125
 126 lemma cpx_tdeq_conf: ∀h,o,G,L. ∀T0:term. ∀T1. ⦃G, L⦄ ⊢ T0 ⬈[h] T1 →
 127                      ∀T2. T0 ≛[h, o] T2 →
 128                      ∃∃T. T1 ≛[h, o] T & ⦃G, L⦄ ⊢ T2 ⬈[h] T.
 129 #h #o #G #L #T0 #T1 #HT01 #T2 #HT02
 130 elim (cpx_tdeq_conf_sex … HT01 … HT02 L … L) -HT01 -HT02
 131 /2 width=3 by rex_refl, ex2_intro/
 132 qed-.
 133
 134 lemma tdeq_cpx_trans: ∀h,o,G,L,T2. ∀T0:term. T2 ≛[h, o] T0 →
 135                       ∀T1. ⦃G, L⦄ ⊢ T0 ⬈[h] T1 →
 136                       ∃∃T. ⦃G, L⦄ ⊢ T2 ⬈[h] T & T ≛[h, o] T1.
 137 #h #o #G #L #T2 #T0 #HT20 #T1 #HT01
 138 elim (cpx_tdeq_conf … HT01 T2) -HT01 /3 width=3 by tdeq_sym, ex2_intro/
 139 qed-.
 140
 141 (* Basic_2A1: uses: cpx_lleq_conf *)
 142 lemma cpx_rdeq_conf: ∀h,o,G,L0,T0,T1. ⦃G, L0⦄ ⊢ T0 ⬈[h] T1 →
 143                      ∀L2. L0 ≛[h, o, T0] L2 →
 144                      ∃∃T. ⦃G, L2⦄ ⊢ T0 ⬈[h] T & T1 ≛[h, o] T.
 145 #h #o #G #L0 #T0 #T1 #HT01 #L2 #HL02
 146 elim (cpx_tdeq_conf_sex … HT01 T0 … L0 … HL02) -HT01 -HL02
 147 /2 width=3 by rex_refl, ex2_intro/
 148 qed-.
 149
 150 (* Basic_2A1: uses: lleq_cpx_trans *)
 151 lemma rdeq_cpx_trans: ∀h,o,G,L2,L0,T0. L2 ≛[h, o, T0] L0 →
 152                       ∀T1. ⦃G, L0⦄ ⊢ T0 ⬈[h] T1 →
 153                       ∃∃T. ⦃G, L2⦄ ⊢ T0 ⬈[h] T & T ≛[h, o] T1.
 154 #h #o #G #L2 #L0 #T0 #HL20 #T1 #HT01
 155 elim (cpx_rdeq_conf … o … HT01 L2) -HT01
 156 /3 width=3 by rdeq_sym, tdeq_sym, ex2_intro/
 157 qed-.
 158
 159 lemma rpx_rdeq_conf: ∀h,o,G,T. confluent2 … (rpx h G T) (rdeq h o T).
 160 /3 width=6 by rpx_fsge_comp, rdeq_fsge_comp, cpx_tdeq_conf_sex, rex_conf/ qed-.
 161
 162 lemma rdeq_rpx_trans: ∀h,o,G,T,L2,K2. ⦃G, L2⦄ ⊢ ⬈[h, T] K2 →
 163                       ∀L1. L1 ≛[h, o, T] L2 →
 164                       ∃∃K1. ⦃G, L1⦄ ⊢ ⬈[h, T] K1 & K1 ≛[h, o, T] K2.
 165 #h #o #G #T #L2 #K2 #HLK2 #L1 #HL12
 166 elim (rpx_rdeq_conf … o … HLK2 L1)
 167 /3 width=3 by rdeq_sym, ex2_intro/
 168 qed-.