matita/matita/contribs/lambdadelta/basic_2/rt_transition/rpx_rdeq.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/static/rdeq_drops.ma".
  16 include "static_2/static/rdeq_fqup.ma".
  17 include "static_2/static/rdeq_rdeq.ma".
  18 include "basic_2/rt_transition/rpx_fsle.ma".
  19
  20 (* UNBOUND PARALLEL RT-TRANSITION FOR REFERRED LOCAL ENVIRONMENTS ***********)
  21
  22 (* Properties with sort-irrelevant equivalence for local environments *******)
  23
  24 lemma rpx_pair_sn_split: ∀h,G,L1,L2,V. ⦃G, L1⦄ ⊢ ⬈[h, V] L2 → ∀I,T.
  25                          ∃∃L. ⦃G, L1⦄ ⊢ ⬈[h, ②{I}V.T] L & L ≛[V] L2.
  26 /3 width=5 by rpx_fsge_comp, rex_pair_sn_split/ qed-.
  27
  28 lemma rpx_flat_dx_split: ∀h,G,L1,L2,T. ⦃G, L1⦄ ⊢ ⬈[h, T] L2 → ∀I,V.
  29                          ∃∃L. ⦃G, L1⦄ ⊢ ⬈[h, ⓕ{I}V.T] L & L ≛[T] L2.
  30 /3 width=5 by rpx_fsge_comp, rex_flat_dx_split/ qed-.
  31
  32 lemma rpx_bind_dx_split: ∀h,I,G,L1,L2,V1,T. ⦃G, L1.ⓑ{I}V1⦄ ⊢ ⬈[h, T] L2 → ∀p.
  33                          ∃∃L,V. ⦃G, L1⦄ ⊢ ⬈[h, ⓑ{p,I}V1.T] L & L.ⓑ{I}V ≛[T] L2 & ⦃G, L1⦄ ⊢ V1 ⬈[h] V.
  34 /3 width=5 by rpx_fsge_comp, rex_bind_dx_split/ qed-.
  35
  36 lemma rpx_bind_dx_split_void: ∀h,G,K1,L2,T. ⦃G, K1.ⓧ⦄ ⊢ ⬈[h, T] L2 → ∀p,I,V.
  37                               ∃∃K2. ⦃G, K1⦄ ⊢ ⬈[h, ⓑ{p,I}V.T] K2 & K2.ⓧ ≛[T] L2.
  38 /3 width=5 by rpx_fsge_comp, rex_bind_dx_split_void/ qed-.
  39
  40 lemma rpx_tdeq_conf: ∀h,G. s_r_confluent1 … cdeq (rpx h G).
  41 /2 width=5 by tdeq_rex_conf/ qed-.
  42
  43 lemma rpx_tdeq_div: ∀h,T1,T2. T1 ≛ T2 →
  44                     ∀G,L1,L2. ⦃G, L1⦄ ⊢ ⬈[h, T2] L2 → ⦃G, L1⦄ ⊢ ⬈[h, T1] L2.
  45 /2 width=5 by tdeq_rex_div/ qed-.
  46
  47 lemma cpx_tdeq_conf_sex: ∀h,G. R_confluent2_rex … (cpx h G) cdeq (cpx h G) cdeq.
  48 #h #G #L0 #T0 #T1 #H @(cpx_ind … H) -G -L0 -T0 -T1 /2 width=3 by ex2_intro/
  49 [ #G #L0 #s0 #X0 #H0 #L1 #HL01 #L2 #HL02
  50   elim (tdeq_inv_sort1 … H0) -H0 #s1 #H destruct
  51   /3 width=3 by tdeq_sort, ex2_intro/
  52 | #I #G #K0 #V0 #V1 #W1 #_ #IH #HVW1 #T2 #H0 #L1 #H1 #L2 #H2
  53   >(tdeq_inv_lref1 … H0) -H0
  54   elim (rpx_inv_zero_pair_sn … H1) -H1 #K1 #X1 #HK01 #HX1 #H destruct
  55   elim (rdeq_inv_zero_pair_sn … H2) -H2 #K2 #X2 #HK02 #HX2 #H destruct
  56   elim (IH X2 … HK01 … HK02) // -K0 -V0 #V #HV1 #HV2
  57   elim (tdeq_lifts_sn … HV1 … HVW1) -V1 /3 width=5 by cpx_delta, ex2_intro/
  58 | #I0 #G #K0 #V1 #W1 #i #_ #IH #HVW1 #T2 #H0 #L1 #H1 #L2 #H2
  59   >(tdeq_inv_lref1 … H0) -H0
  60   elim (rpx_inv_lref_bind_sn … H1) -H1 #I1 #K1 #HK01 #H destruct
  61   elim (rdeq_inv_lref_bind_sn … H2) -H2 #I2 #K2 #HK02 #H destruct
  62   elim (IH … HK01 … HK02) [|*: //] -K0 #V #HV1 #HV2
  63   elim (tdeq_lifts_sn … HV1 … HVW1) -V1 /3 width=5 by cpx_lref, ex2_intro/
  64 | #p #I #G #L0 #V0 #V1 #T0 #T1 #_ #_ #IHV #IHT #X0 #H0 #L1 #H1 #L2 #H2
  65   elim (tdeq_inv_pair1 … H0) -H0 #V2 #T2 #HV02 #HT02 #H destruct
  66   elim (rpx_inv_bind … H1) -H1 #HL01 #H1
  67   elim (rdeq_inv_bind … H2) -H2 #HL02 #H2
  68   lapply (rdeq_bind_repl_dx … H2 (BPair I V2) ?) -H2 /2 width=1 by ext2_pair/ #H2
  69   elim (IHV … HV02 … HL01 … HL02) -IHV -HV02 -HL01 -HL02
  70   elim (IHT … HT02 … H1 … H2) -L0 -T0
  71   /3 width=5 by cpx_bind, tdeq_pair, ex2_intro/
  72 | #I #G #L0 #V0 #V1 #T0 #T1 #_ #_ #IHV #IHT #X0 #H0 #L1 #H1 #L2 #H2
  73   elim (tdeq_inv_pair1 … H0) -H0 #V2 #T2 #HV02 #HT02 #H destruct
  74   elim (rpx_inv_flat … H1) -H1 #HL01 #H1
  75   elim (rdeq_inv_flat … H2) -H2 #HL02 #H2
  76   elim (IHV … HV02 … HL01 … HL02) -IHV -HV02 -HL01 -HL02
  77   elim (IHT … HT02 … H1 … H2) -L0 -V0 -T0
  78   /3 width=5 by cpx_flat, tdeq_pair, ex2_intro/
  79 | #G #L0 #V0 #U0 #T0 #T1 #HTU0 #_ #IH #X0 #H0 #L1 #H1 #L2 #H2
  80   elim (tdeq_inv_pair1 … H0) -H0 #V2 #U2 #HV02 #HU02 #H destruct
  81   elim (rpx_inv_bind … H1) -H1 #HL01 #H1
  82   elim (rdeq_inv_bind … H2) -H2 #HL02 #H2
  83   lapply (rpx_inv_lifts_bi … H1 (Ⓣ) … HTU0) -H1 [6:|*: /3 width=2 by drops_refl, drops_drop/ ] #H1
  84   lapply (rdeq_inv_lifts_bi … H2 (Ⓣ) … HTU0) -H2 [6:|*: /3 width=2 by drops_refl, drops_drop/ ] #H2
  85   elim (tdeq_inv_lifts_sn … HU02 … HTU0) -U0 #T2 #HTU2 #HT02
  86   elim (IH … HT02 … H1 … H2) -L0 -T0 #T #HT1
  87   /3 width=5 by cpx_zeta, ex2_intro/
  88 | #G #L0 #V0 #T0 #T1 #_ #IH #X0 #H0 #L1 #H1 #L2 #H2
  89   elim (tdeq_inv_pair1 … H0) -H0 #V2 #T2 #_ #HT02 #H destruct
  90   elim (rpx_inv_flat … H1) -H1 #HL01 #H1
  91   elim (rdeq_inv_flat … H2) -H2 #HL02 #H2
  92   elim (IH … HT02 … H1 … H2) -L0 -V0 -T0
  93   /3 width=3 by cpx_eps, ex2_intro/
  94 | #G #L0 #V0 #T0 #T1 #_ #IH #X0 #H0 #L1 #H1 #L2 #H2
  95   elim (tdeq_inv_pair1 … H0) -H0 #V2 #T2 #HV02 #_ #H destruct
  96   elim (rpx_inv_flat … H1) -H1 #HL01 #H1
  97   elim (rdeq_inv_flat … H2) -H2 #HL02 #H2
  98   elim (IH … HV02 … HL01 … HL02) -L0 -V0 -T1
  99   /3 width=3 by cpx_ee, ex2_intro/
 100 | #p #G #L0 #V0 #V1 #W0 #W1 #T0 #T1 #_ #_ #_ #IHV #IHW #IHT #X0 #H0 #L1 #H1 #L2 #H2
 101   elim (tdeq_inv_pair1 … H0) -H0 #V2 #X #HV02 #H0 #H destruct
 102   elim (tdeq_inv_pair1 … H0) -H0 #W2 #T2 #HW02 #HT02 #H destruct
 103   elim (rpx_inv_flat … H1) -H1 #H1LV0 #H1
 104   elim (rpx_inv_bind … H1) -H1 #H1LW0 #H1LT0
 105   elim (rdeq_inv_flat … H2) -H2 #H2LV0 #H2
 106   elim (rdeq_inv_bind … H2) -H2 #H2LW0 #H2LT0
 107   lapply (rdeq_bind_repl_dx … H2LT0 (BPair Abst W2) ?) -H2LT0 /2 width=1 by ext2_pair/ #H2LT0
 108   elim (IHV … HV02 … H1LV0 … H2LV0) -IHV -HV02 -H1LV0 -H2LV0
 109   elim (IHW … HW02 … H1LW0 … H2LW0) -IHW -HW02 -H1LW0 -H2LW0
 110   elim (IHT … HT02 … H1LT0 … H2LT0) -L0 -V0 -T0
 111   /4 width=7 by cpx_beta, tdeq_pair, ex2_intro/ (* note: 2 tdeq_pair *)
 112 | #p #G #L0 #V0 #V1 #U1 #W0 #W1 #T0 #T1 #_ #_ #_ #IHV #IHW #IHT #HVU1 #X0 #H0 #L1 #H1 #L2 #H2
 113   elim (tdeq_inv_pair1 … H0) -H0 #V2 #X #HV02 #H0 #H destruct
 114   elim (tdeq_inv_pair1 … H0) -H0 #W2 #T2 #HW02 #HT02 #H destruct
 115   elim (rpx_inv_flat … H1) -H1 #H1LV0 #H1
 116   elim (rpx_inv_bind … H1) -H1 #H1LW0 #H1LT0
 117   elim (rdeq_inv_flat … H2) -H2 #H2LV0 #H2
 118   elim (rdeq_inv_bind … H2) -H2 #H2LW0 #H2LT0
 119   lapply (rdeq_bind_repl_dx … H2LT0 (BPair Abbr W2) ?) -H2LT0 /2 width=1 by ext2_pair/ #H2LT0
 120   elim (IHV … HV02 … H1LV0 … H2LV0) -IHV -HV02 -H1LV0 -H2LV0 #V #HV1
 121   elim (IHW … HW02 … H1LW0 … H2LW0) -IHW -HW02 -H1LW0 -H2LW0
 122   elim (IHT … HT02 … H1LT0 … H2LT0) -L0 -V0 -T0
 123   elim (tdeq_lifts_sn … HV1 … HVU1) -V1
 124   /4 width=9 by cpx_theta, tdeq_pair, ex2_intro/ (* note: 2 tdeq_pair *)
 125 ]
 126 qed-.
 127
 128 lemma cpx_tdeq_conf: ∀h,G,L. ∀T0:term. ∀T1. ⦃G, L⦄ ⊢ T0 ⬈[h] T1 →
 129                      ∀T2. T0 ≛ T2 →
 130                      ∃∃T. T1 ≛ T & ⦃G, L⦄ ⊢ T2 ⬈[h] T.
 131 #h #G #L #T0 #T1 #HT01 #T2 #HT02
 132 elim (cpx_tdeq_conf_sex … HT01 … HT02 L … L) -HT01 -HT02
 133 /2 width=3 by rex_refl, ex2_intro/
 134 qed-.
 135
 136 lemma tdeq_cpx_trans: ∀h,G,L,T2. ∀T0:term. T2 ≛ T0 →
 137                       ∀T1. ⦃G, L⦄ ⊢ T0 ⬈[h] T1 →
 138                       ∃∃T. ⦃G, L⦄ ⊢ T2 ⬈[h] T & T ≛ T1.
 139 #h #G #L #T2 #T0 #HT20 #T1 #HT01
 140 elim (cpx_tdeq_conf … HT01 T2) -HT01 /3 width=3 by tdeq_sym, ex2_intro/
 141 qed-.
 142
 143 (* Basic_2A1: uses: cpx_lleq_conf *)
 144 lemma cpx_rdeq_conf: ∀h,G,L0,T0,T1. ⦃G, L0⦄ ⊢ T0 ⬈[h] T1 →
 145                      ∀L2. L0 ≛[T0] L2 →
 146                      ∃∃T. ⦃G, L2⦄ ⊢ T0 ⬈[h] T & T1 ≛ T.
 147 #h #G #L0 #T0 #T1 #HT01 #L2 #HL02
 148 elim (cpx_tdeq_conf_sex … HT01 T0 … L0 … HL02) -HT01 -HL02
 149 /2 width=3 by rex_refl, ex2_intro/
 150 qed-.
 151
 152 (* Basic_2A1: uses: lleq_cpx_trans *)
 153 lemma rdeq_cpx_trans: ∀h,G,L2,L0,T0. L2 ≛[T0] L0 →
 154                       ∀T1. ⦃G, L0⦄ ⊢ T0 ⬈[h] T1 →
 155                       ∃∃T. ⦃G, L2⦄ ⊢ T0 ⬈[h] T & T ≛ T1.
 156 #h #G #L2 #L0 #T0 #HL20 #T1 #HT01
 157 elim (cpx_rdeq_conf … HT01 L2) -HT01
 158 /3 width=3 by rdeq_sym, tdeq_sym, ex2_intro/
 159 qed-.
 160
 161 lemma rpx_rdeq_conf: ∀h,G,T. confluent2 … (rpx h G T) (rdeq T).
 162 /3 width=6 by rpx_fsge_comp, rdeq_fsge_comp, cpx_tdeq_conf_sex, rex_conf/ qed-.
 163
 164 lemma rdeq_rpx_trans: ∀h,G,T,L2,K2. ⦃G, L2⦄ ⊢ ⬈[h, T] K2 →
 165                       ∀L1. L1 ≛[T] L2 →
 166                       ∃∃K1. ⦃G, L1⦄ ⊢ ⬈[h, T] K1 & K1 ≛[T] K2.
 167 #h #G #T #L2 #K2 #HLK2 #L1 #HL12
 168 elim (rpx_rdeq_conf … HLK2 L1)
 169 /3 width=3 by rdeq_sym, ex2_intro/
 170 qed-.