matita/matita/contribs/lambdadelta/basic_2/rt_transition/rpx_reqx.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/static/reqx_drops.ma".
  16 include "static_2/static/reqx_fqup.ma".
  17 include "static_2/static/reqx_reqx.ma".
  18 include "basic_2/rt_transition/rpx_fsle.ma".
  19
  20 (* EXTENDED PARALLEL RT-TRANSITION FOR REFERRED LOCAL ENVIRONMENTS **********)
  21
  22 (* Properties with sort-irrelevant equivalence for local environments *******)
  23
  24 lemma rpx_pair_sn_split (G):
  25       ∀L1,L2,V. ❪G,L1❫ ⊢ ⬈[V] L2 → ∀I,T.
  26       ∃∃L. ❪G,L1❫ ⊢ ⬈[②[I]V.T] L & L ≛[V] L2.
  27 /3 width=5 by rpx_fsge_comp, rex_pair_sn_split/ qed-.
  28
  29 lemma rpx_flat_dx_split (G):
  30       ∀L1,L2,T. ❪G,L1❫ ⊢ ⬈[T] L2 → ∀I,V.
  31       ∃∃L. ❪G,L1❫ ⊢ ⬈[ⓕ[I]V.T] L & L ≛[T] L2.
  32 /3 width=5 by rpx_fsge_comp, rex_flat_dx_split/ qed-.
  33
  34 lemma rpx_bind_dx_split (G):
  35       ∀I,L1,L2,V1,T. ❪G,L1.ⓑ[I]V1❫ ⊢ ⬈[T] L2 → ∀p.
  36       ∃∃L,V. ❪G,L1❫ ⊢ ⬈[ⓑ[p,I]V1.T] L & L.ⓑ[I]V ≛[T] L2 & ❪G,L1❫ ⊢ V1 ⬈ V.
  37 /3 width=5 by rpx_fsge_comp, rex_bind_dx_split/ qed-.
  38
  39 lemma rpx_bind_dx_split_void (G):
  40       ∀K1,L2,T. ❪G,K1.ⓧ❫ ⊢ ⬈[T] L2 → ∀p,I,V.
  41       ∃∃K2. ❪G,K1❫ ⊢ ⬈[ⓑ[p,I]V.T] K2 & K2.ⓧ ≛[T] L2.
  42 /3 width=5 by rpx_fsge_comp, rex_bind_dx_split_void/ qed-.
  43
  44 lemma rpx_teqx_conf (G): s_r_confluent1 … cdeq (rpx G).
  45 /2 width=5 by teqx_rex_conf/ qed-.
  46
  47 lemma rpx_teqx_div (G):
  48       ∀T1,T2. T1 ≛ T2 → ∀L1,L2. ❪G,L1❫ ⊢ ⬈[T2] L2 → ❪G,L1❫ ⊢ ⬈[T1] L2.
  49 /2 width=5 by teqx_rex_div/ qed-.
  50
  51 lemma cpx_teqx_conf_rex (G): R_confluent2_rex … (cpx G) cdeq (cpx G) cdeq.
  52 #G #L0 #T0 #T1 #H @(cpx_ind … H) -G -L0 -T0 -T1 /2 width=3 by ex2_intro/
  53 [ #G #L0 #s0 #s1 #X0 #H0 #L1 #HL01 #L2 #HL02
  54   elim (teqx_inv_sort1 … H0) -H0 #s2 #H destruct
  55   /3 width=3 by teqx_sort, ex2_intro/
  56 | #I #G #K0 #V0 #V1 #W1 #_ #IH #HVW1 #T2 #H0 #L1 #H1 #L2 #H2
  57   >(teqx_inv_lref1 … H0) -H0
  58   elim (rpx_inv_zero_pair_sn … H1) -H1 #K1 #X1 #HK01 #HX1 #H destruct
  59   elim (reqx_inv_zero_pair_sn … H2) -H2 #K2 #X2 #HK02 #HX2 #H destruct
  60   elim (IH X2 … HK01 … HK02) // -K0 -V0 #V #HV1 #HV2
  61   elim (teqx_lifts_sn … HV1 … HVW1) -V1 /3 width=5 by cpx_delta, ex2_intro/
  62 | #I0 #G #K0 #V1 #W1 #i #_ #IH #HVW1 #T2 #H0 #L1 #H1 #L2 #H2
  63   >(teqx_inv_lref1 … H0) -H0
  64   elim (rpx_inv_lref_bind_sn … H1) -H1 #I1 #K1 #HK01 #H destruct
  65   elim (reqx_inv_lref_bind_sn … H2) -H2 #I2 #K2 #HK02 #H destruct
  66   elim (IH … HK01 … HK02) [|*: //] -K0 #V #HV1 #HV2
  67   elim (teqx_lifts_sn … HV1 … HVW1) -V1 /3 width=5 by cpx_lref, ex2_intro/
  68 | #p #I #G #L0 #V0 #V1 #T0 #T1 #_ #_ #IHV #IHT #X0 #H0 #L1 #H1 #L2 #H2
  69   elim (teqx_inv_pair1 … H0) -H0 #V2 #T2 #HV02 #HT02 #H destruct
  70   elim (rpx_inv_bind … H1) -H1 #HL01 #H1
  71   elim (reqx_inv_bind … H2) -H2 #HL02 #H2
  72   lapply (reqx_bind_repl_dx … H2 (BPair I V2) ?) -H2 /2 width=1 by ext2_pair/ #H2
  73   elim (IHV … HV02 … HL01 … HL02) -IHV -HV02 -HL01 -HL02
  74   elim (IHT … HT02 … H1 … H2) -L0 -T0
  75   /3 width=5 by cpx_bind, teqx_pair, ex2_intro/
  76 | #I #G #L0 #V0 #V1 #T0 #T1 #_ #_ #IHV #IHT #X0 #H0 #L1 #H1 #L2 #H2
  77   elim (teqx_inv_pair1 … H0) -H0 #V2 #T2 #HV02 #HT02 #H destruct
  78   elim (rpx_inv_flat … H1) -H1 #HL01 #H1
  79   elim (reqx_inv_flat … H2) -H2 #HL02 #H2
  80   elim (IHV … HV02 … HL01 … HL02) -IHV -HV02 -HL01 -HL02
  81   elim (IHT … HT02 … H1 … H2) -L0 -V0 -T0
  82   /3 width=5 by cpx_flat, teqx_pair, ex2_intro/
  83 | #G #L0 #V0 #U0 #T0 #T1 #HTU0 #_ #IH #X0 #H0 #L1 #H1 #L2 #H2
  84   elim (teqx_inv_pair1 … H0) -H0 #V2 #U2 #HV02 #HU02 #H destruct
  85   elim (rpx_inv_bind … H1) -H1 #HL01 #H1
  86   elim (reqx_inv_bind … H2) -H2 #HL02 #H2
  87   lapply (rpx_inv_lifts_bi … H1 (Ⓣ) … HTU0) -H1 [6:|*: /3 width=2 by drops_refl, drops_drop/ ] #H1
  88   lapply (reqx_inv_lifts_bi … H2 (Ⓣ) … HTU0) -H2 [6:|*: /3 width=2 by drops_refl, drops_drop/ ] #H2
  89   elim (teqx_inv_lifts_sn … HU02 … HTU0) -U0 #T2 #HTU2 #HT02
  90   elim (IH … HT02 … H1 … H2) -L0 -T0 #T #HT1
  91   /3 width=5 by cpx_zeta, ex2_intro/
  92 | #G #L0 #V0 #T0 #T1 #_ #IH #X0 #H0 #L1 #H1 #L2 #H2
  93   elim (teqx_inv_pair1 … H0) -H0 #V2 #T2 #_ #HT02 #H destruct
  94   elim (rpx_inv_flat … H1) -H1 #HL01 #H1
  95   elim (reqx_inv_flat … H2) -H2 #HL02 #H2
  96   elim (IH … HT02 … H1 … H2) -L0 -V0 -T0
  97   /3 width=3 by cpx_eps, ex2_intro/
  98 | #G #L0 #V0 #T0 #T1 #_ #IH #X0 #H0 #L1 #H1 #L2 #H2
  99   elim (teqx_inv_pair1 … H0) -H0 #V2 #T2 #HV02 #_ #H destruct
 100   elim (rpx_inv_flat … H1) -H1 #HL01 #H1
 101   elim (reqx_inv_flat … H2) -H2 #HL02 #H2
 102   elim (IH … HV02 … HL01 … HL02) -L0 -V0 -T1
 103   /3 width=3 by cpx_ee, ex2_intro/
 104 | #p #G #L0 #V0 #V1 #W0 #W1 #T0 #T1 #_ #_ #_ #IHV #IHW #IHT #X0 #H0 #L1 #H1 #L2 #H2
 105   elim (teqx_inv_pair1 … H0) -H0 #V2 #X #HV02 #H0 #H destruct
 106   elim (teqx_inv_pair1 … H0) -H0 #W2 #T2 #HW02 #HT02 #H destruct
 107   elim (rpx_inv_flat … H1) -H1 #H1LV0 #H1
 108   elim (rpx_inv_bind … H1) -H1 #H1LW0 #H1LT0
 109   elim (reqx_inv_flat … H2) -H2 #H2LV0 #H2
 110   elim (reqx_inv_bind … H2) -H2 #H2LW0 #H2LT0
 111   lapply (reqx_bind_repl_dx … H2LT0 (BPair Abst W2) ?) -H2LT0 /2 width=1 by ext2_pair/ #H2LT0
 112   elim (IHV … HV02 … H1LV0 … H2LV0) -IHV -HV02 -H1LV0 -H2LV0
 113   elim (IHW … HW02 … H1LW0 … H2LW0) -IHW -HW02 -H1LW0 -H2LW0
 114   elim (IHT … HT02 … H1LT0 … H2LT0) -L0 -V0 -T0
 115   /4 width=7 by cpx_beta, teqx_pair, ex2_intro/ (* note: 2 teqx_pair *)
 116 | #p #G #L0 #V0 #V1 #U1 #W0 #W1 #T0 #T1 #_ #_ #_ #IHV #IHW #IHT #HVU1 #X0 #H0 #L1 #H1 #L2 #H2
 117   elim (teqx_inv_pair1 … H0) -H0 #V2 #X #HV02 #H0 #H destruct
 118   elim (teqx_inv_pair1 … H0) -H0 #W2 #T2 #HW02 #HT02 #H destruct
 119   elim (rpx_inv_flat … H1) -H1 #H1LV0 #H1
 120   elim (rpx_inv_bind … H1) -H1 #H1LW0 #H1LT0
 121   elim (reqx_inv_flat … H2) -H2 #H2LV0 #H2
 122   elim (reqx_inv_bind … H2) -H2 #H2LW0 #H2LT0
 123   lapply (reqx_bind_repl_dx … H2LT0 (BPair Abbr W2) ?) -H2LT0 /2 width=1 by ext2_pair/ #H2LT0
 124   elim (IHV … HV02 … H1LV0 … H2LV0) -IHV -HV02 -H1LV0 -H2LV0 #V #HV1
 125   elim (IHW … HW02 … H1LW0 … H2LW0) -IHW -HW02 -H1LW0 -H2LW0
 126   elim (IHT … HT02 … H1LT0 … H2LT0) -L0 -V0 -T0
 127   elim (teqx_lifts_sn … HV1 … HVU1) -V1
 128   /4 width=9 by cpx_theta, teqx_pair, ex2_intro/ (* note: 2 teqx_pair *)
 129 ]
 130 qed-.
 131
 132 lemma cpx_teqx_conf (G) (L):
 133       ∀T0:term. ∀T1. ❪G,L❫ ⊢ T0 ⬈ T1 → ∀T2. T0 ≛ T2 →
 134       ∃∃T. T1 ≛ T & ❪G,L❫ ⊢ T2 ⬈ T.
 135 #G #L #T0 #T1 #HT01 #T2 #HT02
 136 elim (cpx_teqx_conf_rex … HT01 … HT02 L … L) -HT01 -HT02
 137 /2 width=3 by rex_refl, ex2_intro/
 138 qed-.
 139
 140 lemma teqx_cpx_trans (G) (L):
 141       ∀T2. ∀T0:term. T2 ≛ T0 → ∀T1. ❪G,L❫ ⊢ T0 ⬈ T1 →
 142       ∃∃T. ❪G,L❫ ⊢ T2 ⬈ T & T ≛ T1.
 143 #G #L #T2 #T0 #HT20 #T1 #HT01
 144 elim (cpx_teqx_conf … HT01 T2) -HT01 /3 width=3 by teqx_sym, ex2_intro/
 145 qed-.
 146
 147 (* Basic_2A1: uses: cpx_lleq_conf *)
 148 lemma cpx_reqx_conf (G):
 149       ∀L0,T0,T1. ❪G,L0❫ ⊢ T0 ⬈ T1 → ∀L2. L0 ≛[T0] L2 →
 150       ∃∃T. ❪G,L2❫ ⊢ T0 ⬈ T & T1 ≛ T.
 151 #G #L0 #T0 #T1 #HT01 #L2 #HL02
 152 elim (cpx_teqx_conf_rex … HT01 T0 … L0 … HL02) -HT01 -HL02
 153 /2 width=3 by rex_refl, ex2_intro/
 154 qed-.
 155
 156 (* Basic_2A1: uses: lleq_cpx_trans *)
 157 lemma reqx_cpx_trans (G):
 158       ∀L2,L0,T0. L2 ≛[T0] L0 → ∀T1. ❪G,L0❫ ⊢ T0 ⬈ T1 →
 159       ∃∃T. ❪G,L2❫ ⊢ T0 ⬈ T & T ≛ T1.
 160 #G #L2 #L0 #T0 #HL20 #T1 #HT01
 161 elim (cpx_reqx_conf … HT01 L2) -HT01
 162 /3 width=3 by reqx_sym, teqx_sym, ex2_intro/
 163 qed-.
 164
 165 lemma rpx_reqx_conf (G) (T): confluent2 … (rpx G T) (reqx T).
 166 /3 width=6 by rpx_fsge_comp, reqx_fsge_comp, cpx_teqx_conf_rex, rex_conf/ qed-.
 167
 168 lemma reqx_rpx_trans (G) (T):
 169       ∀L2,K2. ❪G,L2❫ ⊢ ⬈[T] K2 → ∀L1. L1 ≛[T] L2 →
 170       ∃∃K1. ❪G,L1❫ ⊢ ⬈[T] K1 & K1 ≛[T] K2.
 171 #G #T #L2 #K2 #HLK2 #L1 #HL12
 172 elim (rpx_reqx_conf … HLK2 L1)
 173 /3 width=3 by reqx_sym, ex2_intro/
 174 qed-.