matita/matita/contribs/lambdadelta/basic_2/s_computation/fqup.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/suptermplus_6.ma".
  16 include "basic_2/s_transition/fqu.ma".
  17
  18 (* PLUS-ITERATED SUPCLOSURE *************************************************)
  19
  20 definition fqup: tri_relation genv lenv term ≝ tri_TC … fqu.
  21
  22 interpretation "plus-iterated structural successor (closure)"
  23    'SupTermPlus G1 L1 T1 G2 L2 T2 = (fqup G1 L1 T1 G2 L2 T2).
  24
  25 (* Basic properties *********************************************************)
  26
  27 lemma fqu_fqup: ∀G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐ ⦃G2, L2, T2⦄ → ⦃G1, L1, T1⦄ ⊐+ ⦃G2, L2, T2⦄.
  28 /2 width=1 by tri_inj/ qed.
  29
  30 lemma fqup_strap1: ∀G1,G,G2,L1,L,L2,T1,T,T2.
  31                    ⦃G1, L1, T1⦄ ⊐+ ⦃G, L, T⦄ → ⦃G, L, T⦄ ⊐ ⦃G2, L2, T2⦄ →
  32                    ⦃G1, L1, T1⦄ ⊐+ ⦃G2, L2, T2⦄.
  33 /2 width=5 by tri_step/ qed.
  34
  35 lemma fqup_strap2: ∀G1,G,G2,L1,L,L2,T1,T,T2.
  36                    ⦃G1, L1, T1⦄ ⊐ ⦃G, L, T⦄ → ⦃G, L, T⦄ ⊐+ ⦃G2, L2, T2⦄ →
  37                    ⦃G1, L1, T1⦄ ⊐+ ⦃G2, L2, T2⦄.
  38 /2 width=5 by tri_TC_strap/ qed.
  39
  40 lemma fqup_pair_sn: ∀I,G,L,V,T. ⦃G, L, ②{I}V.T⦄ ⊐+ ⦃G, L, V⦄.
  41 /2 width=1 by fqu_pair_sn, fqu_fqup/ qed.
  42
  43 lemma fqup_bind_dx: ∀a,I,G,L,V,T. ⦃G, L, ⓑ{a,I}V.T⦄ ⊐+ ⦃G, L.ⓑ{I}V, T⦄.
  44 /2 width=1 by fqu_bind_dx, fqu_fqup/ qed.
  45
  46 lemma fqup_flat_dx: ∀I,G,L,V,T. ⦃G, L, ⓕ{I}V.T⦄ ⊐+ ⦃G, L, T⦄.
  47 /2 width=1 by fqu_flat_dx, fqu_fqup/ qed.
  48
  49 lemma fqup_flat_dx_pair_sn: ∀I1,I2,G,L,V1,V2,T. ⦃G, L, ⓕ{I1}V1.②{I2}V2.T⦄ ⊐+ ⦃G, L, V2⦄.
  50 /2 width=5 by fqu_pair_sn, fqup_strap1/ qed.
  51
  52 lemma fqup_bind_dx_flat_dx: ∀a,G,I1,I2,L,V1,V2,T. ⦃G, L, ⓑ{a,I1}V1.ⓕ{I2}V2.T⦄ ⊐+ ⦃G, L.ⓑ{I1}V1, T⦄.
  53 /2 width=5 by fqu_flat_dx, fqup_strap1/ qed.
  54
  55 lemma fqup_flat_dx_bind_dx: ∀a,I1,I2,G,L,V1,V2,T. ⦃G, L, ⓕ{I1}V1.ⓑ{a,I2}V2.T⦄ ⊐+ ⦃G, L.ⓑ{I2}V2, T⦄.
  56 /2 width=5 by fqu_bind_dx, fqup_strap1/ qed.
  57
  58 (* Basic eliminators ********************************************************)
  59
  60 lemma fqup_ind: ∀G1,L1,T1. ∀R:relation3 ….
  61                 (∀G2,L2,T2. ⦃G1, L1, T1⦄ ⊐ ⦃G2, L2, T2⦄ → R G2 L2 T2) →
  62                 (∀G,G2,L,L2,T,T2. ⦃G1, L1, T1⦄ ⊐+ ⦃G, L, T⦄ → ⦃G, L, T⦄ ⊐ ⦃G2, L2, T2⦄ → R G L T → R G2 L2 T2) →
  63                 ∀G2,L2,T2. ⦃G1, L1, T1⦄ ⊐+ ⦃G2, L2, T2⦄ → R G2 L2 T2.
  64 #G1 #L1 #T1 #R #IH1 #IH2 #G2 #L2 #T2 #H
  65 @(tri_TC_ind … IH1 IH2 G2 L2 T2 H)
  66 qed-.
  67
  68 lemma fqup_ind_dx: ∀G2,L2,T2. ∀R:relation3 ….
  69                    (∀G1,L1,T1. ⦃G1, L1, T1⦄ ⊐ ⦃G2, L2, T2⦄ → R G1 L1 T1) →
  70                    (∀G1,G,L1,L,T1,T. ⦃G1, L1, T1⦄ ⊐ ⦃G, L, T⦄ → ⦃G, L, T⦄ ⊐+ ⦃G2, L2, T2⦄ → R G L T → R G1 L1 T1) →
  71                    ∀G1,L1,T1. ⦃G1, L1, T1⦄ ⊐+ ⦃G2, L2, T2⦄ → R G1 L1 T1.
  72 #G2 #L2 #T2 #R #IH1 #IH2 #G1 #L1 #T1 #H
  73 @(tri_TC_ind_dx … IH1 IH2 G1 L1 T1 H)
  74 qed-.
  75
  76 (* Basic_2A1: removed theorems 1: fqup_drop *)