matita/matita/contribs/lambdadelta/basic_2/s_computation/fqus.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/lib/star.ma".
  16 include "basic_2/notation/relations/suptermstar_6.ma".
  17 include "basic_2/s_transition/fquq.ma".
  18
  19 (* STAR-ITERATED SUPCLOSURE *************************************************)
  20
  21 definition fqus: tri_relation genv lenv term ≝ tri_TC … fquq.
  22
  23 interpretation "star-iterated structural successor (closure)"
  24    'SupTermStar G1 L1 T1 G2 L2 T2 = (fqus G1 L1 T1 G2 L2 T2).
  25
  26 (* Basic eliminators ********************************************************)
  27
  28 lemma fqus_ind: ∀G1,L1,T1. ∀R:relation3 …. R G1 L1 T1 →
  29                 (∀G,G2,L,L2,T,T2. ⦃G1, L1, T1⦄ ⊐* ⦃G, L, T⦄ → ⦃G, L, T⦄ ⊐⸮ ⦃G2, L2, T2⦄ → R G L T → R G2 L2 T2) →
  30                 ∀G2,L2,T2. ⦃G1, L1, T1⦄ ⊐* ⦃G2, L2, T2⦄ → R G2 L2 T2.
  31 #G1 #L1 #T1 #R #IH1 #IH2 #G2 #L2 #T2 #H
  32 @(tri_TC_star_ind … IH1 IH2 G2 L2 T2 H) //
  33 qed-.
  34
  35 lemma fqus_ind_dx: ∀G2,L2,T2. ∀R:relation3 …. R G2 L2 T2 →
  36                    (∀G1,G,L1,L,T1,T. ⦃G1, L1, T1⦄ ⊐⸮ ⦃G, L, T⦄ → ⦃G, L, T⦄ ⊐* ⦃G2, L2, T2⦄ → R G L T → R G1 L1 T1) →
  37                    ∀G1,L1,T1. ⦃G1, L1, T1⦄ ⊐* ⦃G2, L2, T2⦄ → R G1 L1 T1.
  38 #G2 #L2 #T2 #R #IH1 #IH2 #G1 #L1 #T1 #H
  39 @(tri_TC_star_ind_dx … IH1 IH2 G1 L1 T1 H) //
  40 qed-.
  41
  42 (* Basic properties *********************************************************)
  43
  44 lemma fqus_refl: tri_reflexive … fqus.
  45 /2 width=1 by tri_inj/ qed.
  46
  47 lemma fquq_fqus: ∀G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐⸮ ⦃G2, L2, T2⦄ → ⦃G1, L1, T1⦄ ⊐* ⦃G2, L2, T2⦄.
  48 /2 width=1 by tri_inj/ qed.
  49
  50 lemma fqus_strap1: ∀G1,G,G2,L1,L,L2,T1,T,T2. ⦃G1, L1, T1⦄ ⊐* ⦃G, L, T⦄ → ⦃G, L, T⦄ ⊐⸮ ⦃G2, L2, T2⦄ →
  51                    ⦃G1, L1, T1⦄ ⊐* ⦃G2, L2, T2⦄.
  52 /2 width=5 by tri_step/ qed-.
  53
  54 lemma fqus_strap2: ∀G1,G,G2,L1,L,L2,T1,T,T2. ⦃G1, L1, T1⦄ ⊐⸮ ⦃G, L, T⦄ → ⦃G, L, T⦄ ⊐* ⦃G2, L2, T2⦄ →
  55                    ⦃G1, L1, T1⦄ ⊐* ⦃G2, L2, T2⦄.
  56 /2 width=5 by tri_TC_strap/ qed-.
  57
  58 (* Basic inversion lemmas ***************************************************)
  59
  60 lemma fqus_inv_fqu_sn: ∀G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐* ⦃G2, L2, T2⦄ →
  61                        (∧∧ G1 = G2 & L1 = L2 & T1 = T2) ∨
  62                        ∃∃G,L,T. ⦃G1, L1, T1⦄ ⊐ ⦃G, L, T⦄ & ⦃G, L, T⦄ ⊐* ⦃G2, L2, T2⦄.
  63 #G1 #G2 #L1 #L2 #T1 #T2 #H12 @(fqus_ind_dx … H12) -G1 -L1 -T1 /3 width=1 by and3_intro, or_introl/
  64 #G1 #G #L1 #L #T1 #T * /3 width=5 by ex2_3_intro, or_intror/
  65 * #HG #HL #HT #_ destruct //
  66 qed-.
  67
  68 lemma fqus_inv_sort1: ∀G1,G2,L1,L2,T2,s. ⦃G1, L1, ⋆s⦄ ⊐* ⦃G2, L2, T2⦄ →
  69                       (∧∧ G1 = G2 & L1 = L2 & ⋆s = T2) ∨
  70                       ∃∃J,L,V. ⦃G1, L, ⋆s⦄ ⊐* ⦃G2, L2, T2⦄ & L1 = L.ⓑ{J}V.
  71 #G1 #G2 #L1 #L2 #T2 #s #H elim (fqus_inv_fqu_sn … H) -H * /3 width=1 by and3_intro, or_introl/
  72 #G #L #T #H elim (fqu_inv_sort1 … H) -H /3 width=5 by ex2_3_intro, or_intror/
  73 qed-.
  74
  75 lemma fqus_inv_lref1: ∀G1,G2,L1,L2,T2,i. ⦃G1, L1, #i⦄ ⊐* ⦃G2, L2, T2⦄ →
  76                       ∨∨ ∧∧ G1 = G2 & L1 = L2 & #i = T2
  77                        | ∃∃J,L,V. ⦃G1, L, V⦄ ⊐* ⦃G2, L2, T2⦄ & L1 = L.ⓑ{J}V & i = 0
  78                        | ∃∃J,L,V,j. ⦃G1, L, #j⦄ ⊐* ⦃G2, L2, T2⦄ & L1 = L.ⓑ{J}V & i = ⫯j.
  79 #G1 #G2 #L1 #L2 #T2 #i #H elim (fqus_inv_fqu_sn … H) -H * /3 width=1 by and3_intro, or3_intro0/
  80 #G #L #T #H elim (fqu_inv_lref1 … H) -H * /3 width=7 by or3_intro1, or3_intro2, ex3_4_intro, ex3_3_intro/
  81 qed-.
  82
  83 lemma fqus_inv_gref1: ∀G1,G2,L1,L2,T2,l. ⦃G1, L1, §l⦄ ⊐* ⦃G2, L2, T2⦄ →
  84                       (∧∧ G1 = G2 & L1 = L2 & §l = T2) ∨
  85                       ∃∃J,L,V. ⦃G1, L, §l⦄ ⊐* ⦃G2, L2, T2⦄ & L1 = L.ⓑ{J}V.
  86 #G1 #G2 #L1 #L2 #T2 #l #H elim (fqus_inv_fqu_sn … H) -H * /3 width=1 by and3_intro, or_introl/
  87 #G #L #T #H elim (fqu_inv_gref1 … H) -H /3 width=5 by ex2_3_intro, or_intror/
  88 qed-.
  89
  90 lemma fqus_inv_bind1: ∀p,I,G1,G2,L1,L2,V1,T1,T2. ⦃G1, L1, ⓑ{p,I}V1.T1⦄ ⊐* ⦃G2, L2, T2⦄ →
  91                       ∨∨ ∧∧ G1 = G2 & L1 = L2 & ⓑ{p,I}V1.T1 = T2
  92                        | ⦃G1, L1, V1⦄ ⊐* ⦃G2, L2, T2⦄
  93                        | ⦃G1, L1.ⓑ{I}V1, T1⦄ ⊐* ⦃G2, L2, T2⦄
  94                        | ∃∃J,L,V,T. ⦃G1, L, T⦄ ⊐* ⦃G2, L2, T2⦄ & ⬆*[1] T ≡ ⓑ{p,I}V1.T1 & L1 = L.ⓑ{J}V.
  95 #p #I #G1 #G2 #L1 #L2 #V1 #T1 #T2 #H elim (fqus_inv_fqu_sn … H) -H * /3 width=1 by and3_intro, or4_intro0/
  96 #G #L #T #H elim (fqu_inv_bind1 … H) -H *
  97 [3: #J #V ] #H1 #H2 #H3 #H destruct
  98 /3 width=7 by or4_intro1, or4_intro2, or4_intro3, ex3_4_intro/
  99 qed-.
 100
 101 lemma fqus_inv_flat1: ∀I,G1,G2,L1,L2,V1,T1,T2. ⦃G1, L1, ⓕ{I}V1.T1⦄ ⊐* ⦃G2, L2, T2⦄ →
 102                       ∨∨ ∧∧ G1 = G2 & L1 = L2 & ⓕ{I}V1.T1 = T2
 103                        | ⦃G1, L1, V1⦄ ⊐* ⦃G2, L2, T2⦄
 104                        | ⦃G1, L1, T1⦄ ⊐* ⦃G2, L2, T2⦄
 105                        | ∃∃J,L,V,T. ⦃G1, L, T⦄ ⊐* ⦃G2, L2, T2⦄ & ⬆*[1] T ≡ ⓕ{I}V1.T1 & L1 = L.ⓑ{J}V.
 106 #I #G1 #G2 #L1 #L2 #V1 #T1 #T2 #H elim (fqus_inv_fqu_sn … H) -H * /3 width=1 by and3_intro, or4_intro0/
 107 #G #L #T #H elim (fqu_inv_flat1 … H) -H *
 108 [3: #J #V ] #H1 #H2 #H3 #H destruct
 109 /3 width=7 by or4_intro1, or4_intro2, or4_intro3, ex3_4_intro/
 110 qed-.
 111
 112 (* Advanced inversion lemmas ************************************************)
 113
 114 lemma fqus_inv_atom1: ∀I,G1,G2,L2,T2. ⦃G1, ⋆, ⓪{I}⦄ ⊐* ⦃G2, L2, T2⦄ →
 115                       ∧∧ G1 = G2 & ⋆ = L2 & ⓪{I} = T2.
 116 #I #G1 #G2 #L2 #T2 #H elim (fqus_inv_fqu_sn … H) -H * /2 width=1 by and3_intro/
 117 #G #L #T #H elim (fqu_inv_atom1 … H)
 118 qed-.
 119
 120 lemma fqus_inv_sort1_pair: ∀I,G1,G2,L1,L2,V1,T2,s. ⦃G1, L1.ⓑ{I}V1, ⋆s⦄ ⊐* ⦃G2, L2, T2⦄ →
 121                            (∧∧ G1 = G2 & L1.ⓑ{I}V1 = L2 & ⋆s = T2) ∨ ⦃G1, L1, ⋆s⦄ ⊐* ⦃G2, L2, T2⦄.
 122 #I #G1 #G2 #L1 #L2 #V #T2 #s #H elim (fqus_inv_fqu_sn … H) -H * /3 width=1 by and3_intro, or_introl/
 123 #G #L #T #H elim (fqu_inv_sort1_pair … H) -H
 124 #H1 #H2 #H3 #H destruct /2 width=1 by or_intror/
 125 qed-.
 126
 127 lemma fqus_inv_zero1_pair: ∀I,G1,G2,L1,L2,V1,T2. ⦃G1, L1.ⓑ{I}V1, #0⦄ ⊐* ⦃G2, L2, T2⦄ →
 128                            (∧∧ G1 = G2 & L1.ⓑ{I}V1 = L2 & #0 = T2) ∨ ⦃G1, L1, V1⦄ ⊐* ⦃G2, L2, T2⦄.
 129 #I #G1 #G2 #L1 #L2 #V1 #T2 #H elim (fqus_inv_fqu_sn … H) -H * /3 width=1 by and3_intro, or_introl/
 130 #G #L #T #H elim (fqu_inv_zero1_pair … H) -H
 131 #H1 #H2 #H3 #H destruct /2 width=1 by or_intror/
 132 qed-.
 133
 134 lemma fqus_inv_lref1_pair: ∀I,G1,G2,L1,L2,V1,T2,i. ⦃G1, L1.ⓑ{I}V1, #⫯i⦄ ⊐* ⦃G2, L2, T2⦄ →
 135                            (∧∧ G1 = G2 & L1.ⓑ{I}V1 = L2 & #(⫯i) = T2) ∨ ⦃G1, L1, #i⦄ ⊐* ⦃G2, L2, T2⦄.
 136 #I #G1 #G2 #L1 #L2 #V #T2 #i #H elim (fqus_inv_fqu_sn … H) -H * /3 width=1 by and3_intro, or_introl/
 137 #G #L #T #H elim (fqu_inv_lref1_pair … H) -H
 138 #H1 #H2 #H3 #H destruct /2 width=1 by or_intror/
 139 qed-.
 140
 141 lemma fqus_inv_gref1_pair: ∀I,G1,G2,L1,L2,V1,T2,l. ⦃G1, L1.ⓑ{I}V1, §l⦄ ⊐* ⦃G2, L2, T2⦄ →
 142                            (∧∧ G1 = G2 & L1.ⓑ{I}V1 = L2 & §l = T2) ∨ ⦃G1, L1, §l⦄ ⊐* ⦃G2, L2, T2⦄.
 143 #I #G1 #G2 #L1 #L2 #V #T2 #l #H elim (fqus_inv_fqu_sn … H) -H * /3 width=1 by and3_intro, or_introl/
 144 #G #L #T #H elim (fqu_inv_gref1_pair … H) -H
 145 #H1 #H2 #H3 #H destruct /2 width=1 by or_intror/
 146 qed-.
 147
 148 (* Basic_2A1: removed theorems 1: fqus_drop *)