matita/matita/contribs/lambdadelta/basic_2/s_transition/fqu_length.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/syntax/lenv_length.ma".
  16 include "basic_2/s_transition/fqu.ma".
  17
  18 (* SUPCLOSURE ***************************************************************)
  19
  20 (* Forward lemmas with length for local environments ************************)
  21
  22 fact fqu_fwd_length_lref1_aux: ∀b,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐[b] ⦃G2, L2, T2⦄ →
  23                                ∀i. T1 = #i → |L2| < |L1|.
  24 #b #G1 #G2 #L1 #L2 #T1 #T2 #H elim H -G1 -G2 -L1 -L2 -T1 -T2 // [2,3: #p]
  25 #I #G #L #V #T [2: #_ ] #j #H destruct
  26 qed-.
  27
  28 lemma fqu_fwd_length_lref1: ∀b,G1,G2,L1,L2,T2,i. ⦃G1, L1, #i⦄ ⊐[b] ⦃G2, L2, T2⦄ →
  29                             |L2| < |L1|.
  30 /2 width=8 by fqu_fwd_length_lref1_aux/
  31 qed-.
  32
  33 (* Inversion lemmas with length for local environments **********************)
  34
  35 fact fqu_inv_eq_aux: ∀b,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊐[b] ⦃G2, L2, T2⦄ →
  36                      G1 = G2 → |L1| = |L2| → T1 = T2 → ⊥.
  37 #b #G1 #G2 #L1 #L2 #T1 #T2 * -G1 -G2 -L1 -L2 -T1 -T2
  38 [1: #I #G #L #V #_ #H elim (succ_inv_refl_sn … H)
  39 |6: #I #G #L #T #U #_ #_ #H elim (succ_inv_refl_sn … H)
  40 ]
  41 /2 width=4 by discr_tpair_xy_y, discr_tpair_xy_x/
  42 qed-.
  43
  44 lemma fqu_inv_eq: ∀b,G,L1,L2,T. ⦃G, L1, T⦄ ⊐[b] ⦃G, L2, T⦄ → |L1| = |L2| → ⊥.
  45 #b #G #L1 #L2 #T #H #H0 @(fqu_inv_eq_aux … H … H0) // (**) (* full auto fails *)
  46 qed-.