matita/matita/contribs/lambdadelta/basic_2/static/frees_drops.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/relocation/drops_drops.ma".
  16 include "basic_2/static/frees.ma".
  17
  18 (* CONTEXT-SENSITIVE FREE VARIABLES *****************************************)
  19
  20 (* Advanced properties ******************************************************)
  21
  22 lemma frees_lref_atom: ∀b,L,i. ⬇*[b, 𝐔❴i❵] L ≡ ⋆ →
  23                        ∀f. 𝐈⦃f⦄ → L ⊢ 𝐅*⦃#i⦄ ≡ f.
  24 #b #L elim L -L /2 width=1 by frees_atom/
  25 #L #I #V #IH *
  26 [ #H lapply (drops_fwd_isid … H ?) -H // #H destruct
  27 | /5 width=3 by frees_eq_repl_back, frees_lref, drops_inv_drop1, eq_push_inv_isid/
  28 ]
  29 qed.
  30
  31 lemma frees_lref_pair: ∀f,K,V. K ⊢ 𝐅*⦃V⦄ ≡ f →
  32                        ∀i,I,L. ⬇*[i] L ≡ K.ⓑ{I}V → L ⊢ 𝐅*⦃#i⦄ ≡ ↑*[i] ⫯f.
  33 #f #K #V #Hf #i elim i -i
  34 [ #I #L #H lapply (drops_fwd_isid … H ?) -H /2 width=1 by frees_zero/
  35 | #i #IH #I #L #H elim (drops_inv_succ … H) -H /3 width=2 by frees_lref/
  36 ]
  37 qed.
  38
  39 lemma frees_sort_pushs: ∀f,K,s. K ⊢ 𝐅*⦃⋆s⦄ ≡ f →
  40                         ∀i,L. ⬇*[i] L ≡ K → L ⊢ 𝐅*⦃⋆s⦄ ≡ ↑*[i] f.
  41 #f #K #s #Hf #i elim i -i
  42 [ #L #H lapply (drops_fwd_isid … H ?) -H //
  43 | #i #IH #L #H elim (drops_inv_succ … H) -H /3 width=1 by frees_sort/
  44 ]
  45 qed.
  46
  47 lemma frees_lref_pushs: ∀f,K,j. K ⊢ 𝐅*⦃#j⦄ ≡ f →
  48                         ∀i,L. ⬇*[i] L ≡ K → L ⊢ 𝐅*⦃#(i+j)⦄ ≡ ↑*[i] f.
  49 #f #K #j #Hf #i elim i -i
  50 [ #L #H lapply (drops_fwd_isid … H ?) -H //
  51 | #i #IH #L #H elim (drops_inv_succ … H) -H /3 width=1 by frees_lref/
  52 ]
  53 qed.
  54
  55 lemma frees_gref_pushs: ∀f,K,l. K ⊢ 𝐅*⦃§l⦄ ≡ f →
  56                         ∀i,L. ⬇*[i] L ≡ K → L ⊢ 𝐅*⦃§l⦄ ≡ ↑*[i] f.
  57 #f #K #l #Hf #i elim i -i
  58 [ #L #H lapply (drops_fwd_isid … H ?) -H //
  59 | #i #IH #L #H elim (drops_inv_succ … H) -H /3 width=1 by frees_gref/
  60 ]
  61 qed.
  62
  63 (* Advanced inversion lemmas ************************************************)
  64
  65 lemma frees_inv_lref_drops: ∀i,f,L. L ⊢ 𝐅*⦃#i⦄ ≡ f →
  66                             (⬇*[Ⓕ, 𝐔❴i❵] L ≡ ⋆ ∧ 𝐈⦃f⦄) ∨
  67                             ∃∃g,I,K,V. K ⊢ 𝐅*⦃V⦄ ≡ g &
  68                                        ⬇*[i] L ≡ K.ⓑ{I}V & f = ↑*[i] ⫯g.
  69 #i elim i -i
  70 [ #f #L #H elim (frees_inv_zero … H) -H *
  71   /4 width=7 by ex3_4_intro, or_introl, or_intror, conj, drops_refl/
  72 | #i #IH #f #L #H elim (frees_inv_lref … H) -H * /3 width=1 by or_introl, conj/
  73   #g #I #K #V #Hg #H1 #H2 destruct
  74   elim (IH … Hg) -IH -Hg *
  75   [ /4 width=3 by or_introl, conj, isid_push, drops_drop/
  76   | /4 width=7 by drops_drop, ex3_4_intro, or_intror/
  77   ]
  78 ]
  79 qed-.
  80
  81 (* Properties with generic slicing for local environments *******************)
  82
  83 lemma frees_lifts: ∀b,f1,K,T. K ⊢ 𝐅*⦃T⦄ ≡ f1 →
  84                    ∀f,L. ⬇*[b, f] L ≡ K → ∀U. ⬆*[f] T ≡ U →
  85                    ∀f2. f ~⊚ f1 ≡ f2 → L ⊢ 𝐅*⦃U⦄ ≡ f2.
  86 #b #f1 #K #T #H lapply (frees_fwd_isfin … H) elim H -f1 -K -T
  87 [ #f1 #I #Hf1 #_ #f #L #H1 #U #H2 #f2 #H3
  88   lapply (coafter_isid_inv_dx … H3 … Hf1) -f1 #Hf2
  89   elim (lifts_inv_atom1 … H2) -H2 *
  90   /2 width=1 by frees_sort_gen, frees_gref_gen/
  91   #i #j #Hij #H #H0 destruct
  92   elim (drops_inv_atom2 … H1) -H1 #n #g #H1 #Hf
  93   elim (after_at_fwd … Hij … Hf) -f #x #_ #Hj -g -i
  94   lapply (at_inv_uni … Hj) -Hj #H destruct
  95   /3 width=8 by frees_lref_atom, drops_trans/
  96 | #f1 #I #K #V #s #_ #IH #Hf1 #f #L #H1 #U #H2 #f2 #H3
  97   lapply (isfin_fwd_push … Hf1 ??) -Hf1 [3: |*: // ] #Hf1
  98   lapply (lifts_inv_sort1 … H2) -H2 #H destruct
  99   elim (drops_split_trans_pair2 … H1) -H1 [ |*: // ] #Y #W #HLY #HYK #_
 100   elim (coafter_fwd_xpx_pushs … H3) [ |*: // ] #g2 #H2 destruct
 101   lapply (coafter_tls_succ … H3 ??) -H3 [3: |*: // ] #H3
 102   lapply (IH … HYK … H3) -IH -H3 -HYK [1,3: // | skip ]
 103   /3 width=5 by drops_isuni_fwd_drop2, frees_sort_pushs/
 104 | #f1 #I #K #V #_ #IH #Hf1 #f #L #H1 #U #H2 #f2 #H3
 105   lapply (isfin_inv_next … Hf1 ??) -Hf1 [3: |*: // ] #Hf1
 106   lapply (lifts_inv_lref1 … H2) -H2 * #j #Hf #H destruct
 107   elim (drops_split_trans_pair2 … H1) -H1 [ |*: // ] #Y #W #HLY #HYK #HVW
 108   elim (coafter_fwd_xnx_pushs … H3) [ |*: // ] #g2 #H2 destruct
 109   lapply (coafter_tls_succ … H3 ??) -H3 [3: |*: // ]
 110   <tls_S in ⊢ (???%→?); <tls_pushs <tl_next_rew <tl_next_rew #H3
 111   lapply (IH … HYK … HVW … H3) -IH -H3 -HYK -HVW //
 112   /2 width=5 by frees_lref_pair/
 113 | #f1 #I #K #V #i #_ #IH #Hf1 #f #L #H1 #U #H2 #f2 #H3
 114   lapply (isfin_fwd_push … Hf1 ??) -Hf1 [3: |*: // ] #Hf1
 115   lapply (lifts_inv_lref1 … H2) -H2 * #x #Hf #H destruct
 116   elim (at_inv_nxx … Hf) -Hf [ |*: // ] #j #Hf #H destruct
 117   elim (drops_split_trans_pair2 … H1) -H1 [ |*: // ] #Y #W #HLY #HYK #_
 118   elim (coafter_fwd_xpx_pushs … H3) [ |*: // ] #g2 #H2 destruct
 119   lapply (coafter_tls_succ … H3 ??) -H3 [3: |*: // ] <tls_pushs #H3
 120   lapply (drops_isuni_fwd_drop2 … HLY) -HLY // #HLY
 121   lapply (IH … HYK … H3) -IH -H3 -HYK [4: |*: /2 width=2 by lifts_lref/ ]
 122   >plus_S1 /2 width=3 by frees_lref_pushs/ (**) (* full auto fails *)
 123 | #f1 #I #K #V #l #_ #IH #Hf1 #f #L #H1 #U #H2 #f2 #H3
 124   lapply (isfin_fwd_push … Hf1 ??) -Hf1 [3: |*: // ] #Hf1
 125   lapply (lifts_inv_gref1 … H2) -H2 #H destruct
 126   elim (drops_split_trans_pair2 … H1) -H1 [ |*: // ] #Y #W #HLY #HYK #_
 127   elim (coafter_fwd_xpx_pushs … H3) [ |*: // ] #g2 #H2 destruct
 128   lapply (coafter_tls_succ … H3 ??) -H3 [3: |*: // ] #H3
 129   lapply (IH … HYK … H3) -IH -H3 -HYK [1,3: // | skip ]
 130   /3 width=5 by drops_isuni_fwd_drop2, frees_gref_pushs/
 131 | #f1V #f1T #f1 #p #I #K #V #T #_ #_ #H1f1 #IHV #IHT #H2f1 #f #L #H1 #Y #H2 #f2 #H3
 132   elim (sor_inv_isfin3 … H1f1) // #Hf1V #H
 133   lapply (isfin_inv_tl … H) -H
 134   elim (lifts_inv_bind1 … H2) -H2 #W #U #HVW #HTU #H destruct
 135   elim (coafter_sor … H3 … H1f1) /2 width=5 by coafter_isfin2_fwd/ -H3 -H1f1 #f2V #f2T #Hf2V #H
 136   elim (coafter_inv_tl1 … H) -H /4 width=5 by frees_bind, drops_skip/
 137 | #f1V #f1T #f1 #I #K #V #T #_ #_ #H1f1 #IHV #IHT #H2f1 #f #L #H1 #Y #H2 #f2 #H3
 138   elim (sor_inv_isfin3 … H1f1) //
 139   elim (lifts_inv_flat1 … H2) -H2 #W #U #HVW #HTU #H destruct
 140   elim (coafter_sor … H3 … H1f1)
 141   /3 width=5 by coafter_isfin2_fwd, frees_flat/
 142 ]
 143 qed-.
 144
 145 (* Inversion lemmas with generic slicing for local environments *************)
 146
 147 lemma frees_inv_lifts: ∀b,f2,L,U. L ⊢ 𝐅*⦃U⦄ ≡ f2 →
 148                        ∀f,K. ⬇*[b, f] L ≡ K → ∀T. ⬆*[f] T ≡ U →
 149                        ∀f1. f ~⊚ f1 ≡ f2 → K ⊢ 𝐅*⦃T⦄ ≡ f1.
 150 #b #f2 #L #U #H lapply (frees_fwd_isfin … H) elim H -f2 -L -U
 151 [ #f2 #I #Hf2 #_ #f #K #H1 #T #H2 #f1 #H3
 152   lapply (coafter_fwd_isid2 … H3 … Hf2) -H3 // -Hf2 #Hf1
 153   elim (drops_inv_atom1 … H1) -H1 #H #_ destruct
 154   elim (lifts_inv_atom2 … H2) -H2 * /2 width=3 by frees_atom/
 155 | #f2 #I #L #W #s #_ #IH #Hf2 #f #Y #H1 #T #H2 #f1 #H3
 156   lapply (isfin_fwd_push … Hf2 ??) -Hf2 [3: |*: // ] #Hf2
 157   lapply (lifts_inv_sort2 … H2) -H2 #H destruct
 158   elim (coafter_inv_xxp … H3) -H3 [1,3: * |*: // ]
 159   [ #g #g1 #Hf2 #H #H0 destruct
 160     elim (drops_inv_skip1 … H1) -H1 #K #V #HLK #_ #H destruct
 161   | #g #Hf2 #H destruct
 162     lapply (drops_inv_drop1 … H1) -H1
 163   ] /3 width=4 by frees_sort/
 164 | #f2 #I #L #W #_ #IH #Hf2 #f #Y #H1 #T #H2 #f1 #H3
 165   lapply (isfin_inv_next … Hf2 ??) -Hf2 [3: |*: // ] #Hf2
 166   elim (lifts_inv_lref2 … H2) -H2 #i #H2 #H destruct
 167   lapply (at_inv_xxp … H2 ?) -H2 // * #g #H #H0 destruct
 168   elim (drops_inv_skip1 … H1) -H1 #K #V #HLK #HVW #H destruct
 169   elim (coafter_inv_pxn … H3) -H3 [ |*: // ] #g1 #Hf2 #H destruct
 170   /3 width=4 by frees_zero/
 171 | #f2 #I #L #W #j #_ #IH #Hf2 #f #Y #H1 #T #H2 #f1 #H3
 172   lapply (isfin_fwd_push … Hf2 ??) -Hf2 [3: |*: // ] #Hf2
 173   elim (lifts_inv_lref2 … H2) -H2 #x #H2 #H destruct
 174   elim (coafter_inv_xxp … H3) -H3 [1,3: * |*: // ]
 175   [ #g #g1 #Hf2 #H #H0 destruct
 176     elim (drops_inv_skip1 … H1) -H1 #K #V #HLK #HVW #H destruct
 177     elim (at_inv_xpn … H2) -H2 [ |*: // ] #j #Hg #H destruct
 178   | #g #Hf2 #H destruct
 179     lapply (drops_inv_drop1 … H1) -H1
 180     lapply (at_inv_xnn … H2 ????) -H2 [5: |*: // ]
 181   ] /4 width=4 by lifts_lref, frees_lref/
 182 | #f2 #I #L #W #l #_ #IH #Hf2 #f #Y #H1 #T #H2 #f1 #H3
 183   lapply (isfin_fwd_push … Hf2 ??) -Hf2 [3: |*: // ] #Hf2
 184   lapply (lifts_inv_gref2 … H2) -H2 #H destruct
 185   elim (coafter_inv_xxp … H3) -H3 [1,3: * |*: // ]
 186   [ #g #g1 #Hf2 #H #H0 destruct
 187     elim (drops_inv_skip1 … H1) -H1 #K #V #HLK #_ #H destruct
 188   | #g #Hf2 #H destruct
 189     lapply (drops_inv_drop1 … H1) -H1
 190   ] /3 width=4 by frees_gref/
 191 | #f2W #f2U #f2 #p #I #L #W #U #_ #_ #H1f2 #IHW #IHU #H2f2 #f #K #H1 #X #H2 #f1 #H3
 192   elim (sor_inv_isfin3 … H1f2) // #H1f2W #H
 193   lapply (isfin_inv_tl … H) -H
 194   elim (lifts_inv_bind2 … H2) -H2 #V #T #HVW #HTU #H destruct
 195   elim (coafter_inv_sor … H3 … H1f2) -H3 -H1f2 // #f1W #f1U #H2f2W #H
 196   elim (coafter_inv_tl0 … H) -H /4 width=5 by frees_bind, drops_skip/
 197 | #f2W #f2U #f2 #I #L #W #U #_ #_ #H1f2 #IHW #IHU #H2f2 #f #K #H1 #X #H2 #f1 #H3
 198   elim (sor_inv_isfin3 … H1f2) //
 199   elim (lifts_inv_flat2 … H2) -H2 #V #T #HVW #HTU #H destruct
 200   elim (coafter_inv_sor … H3 … H1f2) -H3 -H1f2 /3 width=5 by frees_flat/
 201 ]
 202 qed-.
 203
 204 lemma frees_inv_drops: ∀f2,L,U. L ⊢ 𝐅*⦃U⦄ ≡ f2 →
 205                        ∀f,K. ⬇*[Ⓣ, f] L ≡ K → ∀f1. f ~⊚ f1 ≡ f2 →
 206                        ∃∃T. K ⊢ 𝐅*⦃T⦄ ≡ f1 & ⬆*[f] T ≡ U.
 207 #f2 #L #U #H lapply (frees_fwd_isfin … H) elim H -f2 -L -U
 208 [ #f2 #I #Hf2 #_ #f #K #H1 #f1 #H2
 209   lapply (coafter_fwd_isid2 … H2 ??) -H2 // -Hf2 #Hf1
 210   elim (drops_inv_atom1 … H1) -H1 #H #Hf destruct
 211   /4 width=3 by frees_atom, lifts_refl, ex2_intro/
 212 | #f2 #I #L #W #s #_ #IH #Hf2 #f #Y #H1 #f1 #H2
 213   lapply (isfin_fwd_push … Hf2 ??) -Hf2 [3: |*: // ] #Hf2
 214   elim (coafter_inv_xxp … H2) -H2 [1,3: * |*: // ]
 215   [ #g #g1 #Hf2 #H #H0 destruct
 216     elim (drops_inv_skip1 … H1) -H1 #K #V #HLK #_ #H destruct
 217   | #g #Hf2 #H destruct
 218     lapply (drops_inv_drop1 … H1) -H1 #HLK
 219   ]
 220   elim (IH … HLK … Hf2) -L // -f2 #X #Hg1 #HX
 221   lapply (lifts_inv_sort2 … HX) -HX #H destruct
 222   /3 width=3 by frees_sort, lifts_sort, ex2_intro/
 223 | #f2 #I #L #W #_ #IH #Hf2 #f #Y #H1 #f1 #H2
 224   lapply (isfin_inv_next … Hf2 ??) -Hf2 [3: |*: // ] #Hf2
 225   elim (coafter_inv_xxn … H2) -H2 [ |*: // ] #g #g1 #Hf2 #H0 #H destruct
 226   elim (drops_inv_skip1 … H1) -H1 #K #V #HLK #HVW #H destruct
 227   elim (IH … HLK … Hf2) -L // -f2 #X #Hg1 #HX
 228   lapply (lifts_inj … HX … HVW) -W #H destruct
 229   /3 width=3 by frees_zero, lifts_lref, ex2_intro/
 230 | #f2 #I #L #W #j #_ #IH #Hf2 #f #Y #H1 #f1 #H2
 231   lapply (isfin_fwd_push … Hf2 ??) -Hf2 [3: |*: // ] #Hf2
 232   elim (coafter_inv_xxp … H2) -H2 [1,3: * |*: // ]
 233   [ #g #g1 #Hf2 #H #H0 destruct
 234     elim (drops_inv_skip1 … H1) -H1 #K #V #HLK #_ #H destruct
 235   | #g #Hf2 #H destruct
 236     lapply (drops_inv_drop1 … H1) -H1 #HLK
 237   ]
 238   elim (IH … HLK … Hf2) -L // -f2 #X #Hg1 #HX
 239   elim (lifts_inv_lref2 … HX) -HX #i #Hij #H destruct
 240   /4 width=7 by frees_lref, lifts_lref, at_S1, at_next, ex2_intro/
 241 | #f2 #I #L #W #l #_ #IH #Hf2 #f #Y #H1 #f1 #H2
 242   lapply (isfin_fwd_push … Hf2 ??) -Hf2 [3: |*: // ] #Hf2
 243   elim (coafter_inv_xxp … H2) -H2 [1,3: * |*: // ]
 244   [ #g #g1 #Hf2 #H #H0 destruct
 245     elim (drops_inv_skip1 … H1) -H1 #K #V #HLK #_ #H destruct
 246   | #g #Hf2 #H destruct
 247     lapply (drops_inv_drop1 … H1) -H1 #HLK
 248   ]
 249   elim (IH … HLK … Hf2) -L // -f2 #X #Hg1 #HX
 250   lapply (lifts_inv_gref2 … HX) -HX #H destruct
 251   /3 width=3 by frees_gref, lifts_gref, ex2_intro/
 252 | #f2W #f2U #f2 #p #I #L #W #U #_ #_ #H1f2 #IHW #IHU #H2f2 #f #K #H1 #f1 #H2
 253   elim (sor_inv_isfin3 … H1f2) // #H1f2W #H
 254   lapply (isfin_inv_tl … H) -H #H1f2U
 255   elim (coafter_inv_sor … H2 … H1f2) -H2 -H1f2 // #f1W #f1U #H2f2W #H #Hf1
 256   elim (coafter_inv_tl0 … H) -H #g1 #H2f2U #H destruct
 257   elim (IHW … H1 … H2f2W) -IHW -H2f2W // -H1f2W #V #Hf1W #HVW
 258   elim (IHU … H2f2U) -IHU -H2f2U
 259   /3 width=5 by frees_bind, drops_skip, lifts_bind, ex2_intro/
 260 | #f2W #f2U #f2 #I #L #W #U #_ #_ #H1f2 #IHW #IHU #H2f2 #f #K #H1 #f1 #H2
 261   elim (sor_inv_isfin3 … H1f2) // #H1f2W #H1f2U
 262   elim (coafter_inv_sor … H2 … H1f2) -H2 -H1f2 // #f1W #f1U #H2f2W #H2f2U #Hf1
 263   elim (IHW … H1 … H2f2W) -IHW -H2f2W // -H1f2W
 264   elim (IHU … H1 … H2f2U) -L -H2f2U
 265   /3 width=5 by frees_flat, lifts_flat, ex2_intro/
 266 ]
 267 qed-.