matita/matita/contribs/lambdadelta/basic_2/static/lfdeq.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/stareqsn_5.ma".
  16 include "basic_2/syntax/tdeq_ext.ma".
  17 include "basic_2/static/lfxs.ma".
  18
  19 (* DEGREE-BASED EQUIVALENCE FOR LOCAL ENVIRONMENTS ON REFERRED ENTRIES ******)
  20
  21 definition lfdeq: ∀h. sd h → relation3 term lenv lenv ≝
  22                   λh,o. lfxs (cdeq h o).
  23
  24 interpretation
  25    "degree-based equivalence on referred entries (local environment)"
  26    'StarEqSn h o T L1 L2 = (lfdeq h o T L1 L2).
  27
  28 interpretation
  29    "degree-based ranged equivalence (local environment)"
  30    'StarEqSn h o f L1 L2 = (lexs (cdeq_ext h o) cfull f L1 L2).
  31
  32 (* Basic properties ***********************************************************)
  33
  34 lemma frees_tdeq_conf_lfdeq: ∀h,o,f,L1,T1. L1 ⊢ 𝐅*⦃T1⦄ ≡ f → ∀T2. T1 ≛[h, o] T2 →
  35                              ∀L2. L1 ≛[h, o, f] L2 → L2 ⊢ 𝐅*⦃T2⦄ ≡ f.
  36 #h #o #f #L1 #T1 #H elim H -f -L1 -T1
  37 [ #f #L1 #s1 #Hf #X #H1 #L2 #_
  38   elim (tdeq_inv_sort1 … H1) -H1 #s2 #d #_ #_ #H destruct
  39   /2 width=3 by frees_sort/
  40 | #f #i #Hf #X #H1
  41   >(tdeq_inv_lref1 … H1) -X #Y #H2
  42   >(lexs_inv_atom1 … H2) -Y
  43   /2 width=1 by frees_atom/
  44 | #f #I #L1 #V1 #_ #IH #X #H1
  45   >(tdeq_inv_lref1 … H1) -X #Y #H2
  46   elim (lexs_inv_next1 … H2) -H2 #Z #L2 #HL12 #HZ #H destruct
  47   elim (ext2_inv_pair_sn … HZ) -HZ #V2 #HV12 #H destruct
  48   /3 width=1 by frees_pair/
  49 | #f #I #L1 #Hf #X #H1
  50   >(tdeq_inv_lref1 … H1) -X #Y #H2
  51   elim (lexs_inv_next1 … H2) -H2 #Z #L2 #_ #HZ #H destruct
  52   >(ext2_inv_unit_sn … HZ) -Z /2 width=1 by frees_unit/
  53 | #f #I #L1 #i #_ #IH #X #H1
  54   >(tdeq_inv_lref1 … H1) -X #Y #H2
  55   elim (lexs_inv_push1 … H2) -H2 #J #L2 #HL12 #_ #H destruct
  56   /3 width=1 by frees_lref/
  57 | #f #L1 #l #Hf #X #H1 #L2 #_
  58   >(tdeq_inv_gref1 … H1) -X /2 width=1 by frees_gref/
  59 | #f1V #f1T #f1 #p #I #L1 #V1 #T1 #_ #_ #Hf1 #IHV #IHT #X #H1
  60   elim (tdeq_inv_pair1 … H1) -H1 #V2 #T2 #HV12 #HT12 #H1 #L2 #HL12 destruct
  61   /6 width=5 by frees_bind, lexs_inv_tl, ext2_pair, sle_lexs_trans, sor_inv_sle_dx, sor_inv_sle_sn/
  62 | #f1V #f1T #f1 #I #L1 #V1 #T1 #_ #_ #Hf1 #IHV #IHT #X #H1
  63   elim (tdeq_inv_pair1 … H1) -H1 #V2 #T2 #HV12 #HT12 #H1 #L2 #HL12 destruct
  64   /5 width=5 by frees_flat, sle_lexs_trans, sor_inv_sle_dx, sor_inv_sle_sn/
  65 ]
  66 qed-.
  67
  68 lemma frees_tdeq_conf: ∀h,o,f,L,T1. L ⊢ 𝐅*⦃T1⦄ ≡ f →
  69                        ∀T2. T1 ≛[h, o] T2 → L ⊢ 𝐅*⦃T2⦄ ≡ f.
  70 /4 width=7 by frees_tdeq_conf_lfdeq, lexs_refl, ext2_refl/ qed-.
  71
  72 lemma frees_lfdeq_conf: ∀h,o,f,L1,T. L1 ⊢ 𝐅*⦃T⦄ ≡ f →
  73                         ∀L2. L1 ≛[h, o, f] L2 → L2 ⊢ 𝐅*⦃T⦄ ≡ f.
  74 /2 width=7 by frees_tdeq_conf_lfdeq, tdeq_refl/ qed-.
  75
  76 lemma tdeq_lfdeq_conf: ∀h,o. s_r_confluent1 … (cdeq h o) (lfdeq h o).
  77 #h #o #L1 #T1 #T2 #HT12 #L2 *
  78 /3 width=5 by frees_tdeq_conf, ex2_intro/
  79 qed-.
  80
  81 lemma tdeq_lfdeq_div: ∀h,o,T1,T2. T1 ≛[h, o] T2 →
  82                       ∀L1,L2. L1 ≛[h, o, T2] L2 → L1 ≛[h, o, T1] L2.
  83 /3 width=3 by tdeq_lfdeq_conf, tdeq_sym/ qed-.
  84
  85 lemma lfdeq_atom: ∀h,o,I. ⋆ ≛[h, o, ⓪{I}] ⋆.
  86 /2 width=1 by lfxs_atom/ qed.
  87
  88 (* Basic_2A1: uses: lleq_sort *)
  89 lemma lfdeq_sort: ∀h,o,I1,I2,L1,L2,s.
  90                   L1 ≛[h, o, ⋆s] L2 → L1.ⓘ{I1} ≛[h, o, ⋆s] L2.ⓘ{I2}.
  91 /2 width=1 by lfxs_sort/ qed.
  92
  93 lemma lfdeq_pair: ∀h,o,I,L1,L2,V1,V2. L1 ≛[h, o, V1] L2 → V1 ≛[h, o] V2 →
  94                                       L1.ⓑ{I}V1 ≛[h, o, #0] L2.ⓑ{I}V2.
  95 /2 width=1 by lfxs_pair/ qed.
  96 (*
  97 lemma lfdeq_unit: ∀h,o,f,I,L1,L2. 𝐈⦃f⦄ → L1 ⪤*[cdeq_ext h o, cfull, f] L2 →
  98                   L1.ⓤ{I} ≛[h, o, #0] L2.ⓤ{I}.
  99 /2 width=3 by lfxs_unit/ qed.
 100 *)
 101 lemma lfdeq_lref: ∀h,o,I1,I2,L1,L2,i.
 102                   L1 ≛[h, o, #i] L2 → L1.ⓘ{I1} ≛[h, o, #⫯i] L2.ⓘ{I2}.
 103 /2 width=1 by lfxs_lref/ qed.
 104
 105 (* Basic_2A1: uses: lleq_gref *)
 106 lemma lfdeq_gref: ∀h,o,I1,I2,L1,L2,l.
 107                   L1 ≛[h, o, §l] L2 → L1.ⓘ{I1} ≛[h, o, §l] L2.ⓘ{I2}.
 108 /2 width=1 by lfxs_gref/ qed.
 109
 110 lemma lfdeq_bind_repl_dx: ∀h,o,I,I1,L1,L2.∀T:term.
 111                           L1.ⓘ{I} ≛[h, o, T] L2.ⓘ{I1} →
 112                           ∀I2. I ≛[h, o] I2 →
 113                           L1.ⓘ{I} ≛[h, o, T] L2.ⓘ{I2}.
 114 /2 width=2 by lfxs_bind_repl_dx/ qed-.
 115
 116 (* Basic inversion lemmas ***************************************************)
 117
 118 lemma lfdeq_inv_atom_sn: ∀h,o,Y2. ∀T:term. ⋆ ≛[h, o, T] Y2 → Y2 = ⋆.
 119 /2 width=3 by lfxs_inv_atom_sn/ qed-.
 120
 121 lemma lfdeq_inv_atom_dx: ∀h,o,Y1. ∀T:term. Y1 ≛[h, o, T] ⋆ → Y1 = ⋆.
 122 /2 width=3 by lfxs_inv_atom_dx/ qed-.
 123 (*
 124 lemma lfdeq_inv_zero: ∀h,o,Y1,Y2. Y1 ≛[h, o, #0] Y2 →
 125                       ∨∨ Y1 = ⋆ ∧ Y2 = ⋆
 126                        | ∃∃I,L1,L2,V1,V2. L1 ≛[h, o, V1] L2 & V1 ≛[h, o] V2 &
 127                                           Y1 = L1.ⓑ{I}V1 & Y2 = L2.ⓑ{I}V2
 128                        | ∃∃f,I,L1,L2. 𝐈⦃f⦄ & L1 ⪤*[cdeq_ext h o, cfull, f] L2 &
 129                                            Y1 = L1.ⓤ{I} & Y2 = L2.ⓤ{I}.
 130 #h #o #Y1 #Y2 #H elim (lfxs_inv_zero … H) -H *
 131 /3 width=9 by or3_intro0, or3_intro1, or3_intro2, ex4_5_intro, ex4_4_intro, conj/
 132 qed-.
 133 *)
 134 lemma lfdeq_inv_lref: ∀h,o,Y1,Y2,i. Y1 ≛[h, o, #⫯i] Y2 →
 135                       (Y1 = ⋆ ∧ Y2 = ⋆) ∨
 136                       ∃∃I1,I2,L1,L2. L1 ≛[h, o, #i] L2 &
 137                                      Y1 = L1.ⓘ{I1} & Y2 = L2.ⓘ{I2}.
 138 /2 width=1 by lfxs_inv_lref/ qed-.
 139
 140 (* Basic_2A1: uses: lleq_inv_bind lleq_inv_bind_O *)
 141 lemma lfdeq_inv_bind: ∀h,o,p,I,L1,L2,V,T. L1 ≛[h, o, ⓑ{p,I}V.T] L2 →
 142                       L1 ≛[h, o, V] L2 ∧ L1.ⓑ{I}V ≛[h, o, T] L2.ⓑ{I}V.
 143 /2 width=2 by lfxs_inv_bind/ qed-.
 144
 145 (* Basic_2A1: uses: lleq_inv_flat *)
 146 lemma lfdeq_inv_flat: ∀h,o,I,L1,L2,V,T. L1 ≛[h, o, ⓕ{I}V.T] L2 →
 147                       L1 ≛[h, o, V] L2 ∧ L1 ≛[h, o, T] L2.
 148 /2 width=2 by lfxs_inv_flat/ qed-.
 149
 150 (* Advanced inversion lemmas ************************************************)
 151
 152 lemma lfdeq_inv_zero_pair_sn: ∀h,o,I,Y2,L1,V1. L1.ⓑ{I}V1 ≛[h, o, #0] Y2 →
 153                               ∃∃L2,V2. L1 ≛[h, o, V1] L2 & V1 ≛[h, o] V2 & Y2 = L2.ⓑ{I}V2.
 154 /2 width=1 by lfxs_inv_zero_pair_sn/ qed-.
 155
 156 lemma lfdeq_inv_zero_pair_dx: ∀h,o,I,Y1,L2,V2. Y1 ≛[h, o, #0] L2.ⓑ{I}V2 →
 157                               ∃∃L1,V1. L1 ≛[h, o, V1] L2 & V1 ≛[h, o] V2 & Y1 = L1.ⓑ{I}V1.
 158 /2 width=1 by lfxs_inv_zero_pair_dx/ qed-.
 159
 160 lemma lfdeq_inv_lref_bind_sn: ∀h,o,I1,Y2,L1,i. L1.ⓘ{I1} ≛[h, o, #⫯i] Y2 →
 161                               ∃∃I2,L2. L1 ≛[h, o, #i] L2 & Y2 = L2.ⓘ{I2}.
 162 /2 width=2 by lfxs_inv_lref_bind_sn/ qed-.
 163
 164 lemma lfdeq_inv_lref_bind_dx: ∀h,o,I2,Y1,L2,i. Y1 ≛[h, o, #⫯i] L2.ⓘ{I2} →
 165                               ∃∃I1,L1. L1 ≛[h, o, #i] L2 & Y1 = L1.ⓘ{I1}.
 166 /2 width=2 by lfxs_inv_lref_bind_dx/ qed-.
 167
 168 (* Basic forward lemmas *****************************************************)
 169
 170 lemma lfdeq_fwd_zero_pair: ∀h,o,I,K1,K2,V1,V2.
 171                            K1.ⓑ{I}V1 ≛[h, o, #0] K2.ⓑ{I}V2 → K1 ≛[h, o, V1] K2.
 172 /2 width=3 by lfxs_fwd_zero_pair/ qed-.
 173
 174 (* Basic_2A1: uses: lleq_fwd_bind_sn lleq_fwd_flat_sn *)
 175 lemma lfdeq_fwd_pair_sn: ∀h,o,I,L1,L2,V,T. L1 ≛[h, o, ②{I}V.T] L2 → L1 ≛[h, o, V] L2.
 176 /2 width=3 by lfxs_fwd_pair_sn/ qed-.
 177
 178 (* Basic_2A1: uses: lleq_fwd_bind_dx lleq_fwd_bind_O_dx *)
 179 lemma lfdeq_fwd_bind_dx: ∀h,o,p,I,L1,L2,V,T.
 180                          L1 ≛[h, o, ⓑ{p,I}V.T] L2 → L1.ⓑ{I}V ≛[h, o, T] L2.ⓑ{I}V.
 181 /2 width=2 by lfxs_fwd_bind_dx/ qed-.
 182
 183 (* Basic_2A1: uses: lleq_fwd_flat_dx *)
 184 lemma lfdeq_fwd_flat_dx: ∀h,o,I,L1,L2,V,T. L1 ≛[h, o, ⓕ{I}V.T] L2 → L1 ≛[h, o, T] L2.
 185 /2 width=3 by lfxs_fwd_flat_dx/ qed-.
 186
 187 lemma lfdeq_fwd_dx: ∀h,o,I2,L1,K2. ∀T:term. L1 ≛[h, o, T] K2.ⓘ{I2} →
 188                     ∃∃I1,K1. L1 = K1.ⓘ{I1}.
 189 /2 width=5 by lfxs_fwd_dx/ qed-.