matita/matita/contribs/lambdadelta/basic_2/static/lfeq.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/lazyeqsn_3.ma".
  16 include "basic_2/static/lfxs.ma".
  17
  18 (* SYNTACTIC EQUIVALENCE FOR LOCAL ENVIRONMENTS ON REFERRED ENTRIES *********)
  19
  20 (* Basic_2A1: was: lleq *)
  21 definition lfeq: relation3 term lenv lenv ≝
  22                  lfxs ceq.
  23
  24 interpretation
  25    "syntactic equivalence on referred entries (local environment)"
  26    'LazyEqSn T L1 L2 = (lfeq T L1 L2).
  27
  28 (* Basic_2A1: uses: lleq_transitive *)
  29 definition lfeq_transitive: predicate (relation3 lenv term term) ≝
  30            λR. ∀L2,T1,T2. R L2 T1 T2 → ∀L1. L1 ≡[T1] L2 → R L1 T1 T2.
  31
  32 (* Basic inversion lemmas ***************************************************)
  33
  34 lemma lfeq_transitive_inv_lfxs: ∀R. lfeq_transitive R → lfxs_transitive ceq R R.
  35 /2 width=3 by/ qed-.
  36
  37 lemma lfeq_inv_bind: ∀p,I,L1,L2,V,T. L1 ≡[ⓑ{p,I}V.T] L2 →
  38                      ∧∧ L1 ≡[V] L2 & L1.ⓑ{I}V ≡[T] L2.ⓑ{I}V.
  39 /2 width=2 by lfxs_inv_bind/ qed-.
  40
  41 lemma lfeq_inv_flat: ∀I,L1,L2,V,T. L1 ≡[ⓕ{I}V.T] L2 →
  42                      ∧∧ L1 ≡[V] L2 & L1 ≡[T] L2.
  43 /2 width=2 by lfxs_inv_flat/ qed-.
  44
  45 (* Advanced inversion lemmas ************************************************)
  46
  47 lemma lfeq_inv_zero_pair_sn: ∀I,L2,K1,V. K1.ⓑ{I}V ≡[#0] L2 →
  48                              ∃∃K2. K1 ≡[V] K2 & L2 = K2.ⓑ{I}V.
  49 #I #L2 #K1 #V #H
  50 elim (lfxs_inv_zero_pair_sn … H) -H #K2 #X #HK12 #HX #H destruct
  51 /2 width=3 by ex2_intro/
  52 qed-.
  53
  54 lemma lfeq_inv_zero_pair_dx: ∀I,L1,K2,V. L1 ≡[#0] K2.ⓑ{I}V →
  55                              ∃∃K1. K1 ≡[V] K2 & L1 = K1.ⓑ{I}V.
  56 #I #L1 #K2 #V #H
  57 elim (lfxs_inv_zero_pair_dx … H) -H #K1 #X #HK12 #HX #H destruct
  58 /2 width=3 by ex2_intro/
  59 qed-.
  60
  61 lemma lfeq_inv_lref_bind_sn: ∀I1,K1,L2,i. K1.ⓘ{I1} ≡[#⫯i] L2 →
  62                              ∃∃I2,K2. K1 ≡[#i] K2 & L2 = K2.ⓘ{I2}.
  63 /2 width=2 by lfxs_inv_lref_bind_sn/ qed-.
  64
  65 lemma lfeq_inv_lref_bind_dx: ∀I2,K2,L1,i. L1 ≡[#⫯i] K2.ⓘ{I2} →
  66                              ∃∃I1,K1. K1 ≡[#i] K2 & L1 = K1.ⓘ{I1}.
  67 /2 width=2 by lfxs_inv_lref_bind_dx/ qed-.
  68
  69 (* Basic forward lemmas *****************************************************)
  70
  71 (* Basic_2A1: was: llpx_sn_lrefl *)
  72 (* Note: this should have been lleq_fwd_llpx_sn *)
  73 lemma lfeq_fwd_lfxs: ∀R. c_reflexive … R →
  74                      ∀L1,L2,T. L1 ≡[T] L2 → L1 ⪤*[R, T] L2.
  75 #R #HR #L1 #L2 #T * #f #Hf #HL12
  76 /4 width=7 by lexs_co, cext2_co, ex2_intro/
  77 qed-.
  78
  79 (* Basic_properties *********************************************************)
  80
  81 lemma lfxs_transitive_lfeq: ∀R. lfxs_transitive ceq R R → lfeq_transitive R.
  82 /2 width=5 by/ qed.
  83
  84 lemma frees_lfeq_conf: ∀f,L1,T. L1 ⊢ 𝐅*⦃T⦄ ≡ f →
  85                        ∀L2. L1 ≡[T] L2 → L2 ⊢ 𝐅*⦃T⦄ ≡ f.
  86 #f #L1 #T #H elim H -f -L1 -T
  87 [ /2 width=3 by frees_sort/
  88 | #f #i #Hf #L2 #H2
  89   >(lfxs_inv_atom_sn … H2) -L2
  90   /2 width=1 by frees_atom/
  91 | #f #I #L1 #V1 #_ #IH #Y #H2
  92   elim (lfeq_inv_zero_pair_sn … H2) -H2 #L2 #HL12 #H destruct
  93   /3 width=1 by frees_pair/
  94 | #f #I #L1 #Hf #Y #H2
  95   elim (lfxs_inv_zero_unit_sn … H2) -H2 #g #L2 #_ #_ #H destruct
  96   /2 width=1 by frees_unit/
  97 | #f #I #L1 #i #_ #IH #Y #H2
  98   elim (lfeq_inv_lref_bind_sn … H2) -H2 #J #L2 #HL12 #H destruct
  99   /3 width=1 by frees_lref/
 100 | /2 width=1 by frees_gref/
 101 | #f1V #f1T #f1 #p #I #L1 #V1 #T1 #_ #_ #Hf1 #IHV #IHT #L2 #H2
 102   elim (lfeq_inv_bind … H2) -H2 /3 width=5 by frees_bind/
 103 | #f1V #f1T #f1 #I #L1 #V1 #T1 #_ #_ #Hf1 #IHV #IHT #L2 #H2
 104   elim (lfeq_inv_flat … H2) -H2 /3 width=5 by frees_flat/
 105 ]
 106 qed-.
 107
 108 (* Basic_2A1: removed theorems 10:
 109               lleq_ind lleq_fwd_lref
 110               lleq_fwd_drop_sn lleq_fwd_drop_dx
 111               lleq_skip lleq_lref lleq_free
 112               lleq_Y lleq_ge_up lleq_ge
 113
 114 *)