matita/matita/contribs/lambdadelta/basic_2/static/lfeq.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/lazyeqsn_3.ma".
  16 include "basic_2/static/lfxs.ma".
  17
  18 (* SYNTACTIC EQUIVALENCE FOR LOCAL ENVIRONMENTS ON REFERRED ENTRIES *********)
  19
  20 (* Basic_2A1: was: lleq *)
  21 definition lfeq: relation3 term lenv lenv ≝
  22                  lfxs ceq.
  23
  24 interpretation
  25    "syntactic equivalence on referred entries (local environment)"
  26    'LazyEqSn T L1 L2 = (lfeq T L1 L2).
  27
  28 (* Basic_2A1: uses: lleq_transitive *)
  29 definition lfeq_transitive: predicate (relation3 lenv term term) ≝
  30            λR. ∀L2,T1,T2. R L2 T1 T2 → ∀L1. L1 ≡[T1] L2 → R L1 T1 T2.
  31
  32 (* Basic_properties *********************************************************)
  33
  34 lemma lfxs_transitive_lfeq: ∀R. lfxs_transitive ceq R R → lfeq_transitive R.
  35 /2 width=5 by/ qed.
  36
  37 (* Basic inversion lemmas ***************************************************)
  38
  39 lemma lfeq_transitive_inv_lfxs: ∀R. lfeq_transitive R → lfxs_transitive ceq R R.
  40 /2 width=3 by/ qed-.
  41
  42 lemma lfeq_inv_bind: ∀p,I,L1,L2,V,T. L1 ≡[ⓑ{p,I}V.T] L2 →
  43                      ∧∧ L1 ≡[V] L2 & L1.ⓑ{I}V ≡[T] L2.ⓑ{I}V.
  44 /2 width=2 by lfxs_inv_bind/ qed-.
  45
  46 lemma lfeq_inv_flat: ∀I,L1,L2,V,T. L1 ≡[ⓕ{I}V.T] L2 →
  47                      ∧∧ L1 ≡[V] L2 & L1 ≡[T] L2.
  48 /2 width=2 by lfxs_inv_flat/ qed-.
  49
  50 (* Advanced inversion lemmas ************************************************)
  51
  52 lemma lfeq_inv_zero_pair_sn: ∀I,L2,K1,V. K1.ⓑ{I}V ≡[#0] L2 →
  53                              ∃∃K2. K1 ≡[V] K2 & L2 = K2.ⓑ{I}V.
  54 #I #L2 #K1 #V #H
  55 elim (lfxs_inv_zero_pair_sn … H) -H #K2 #X #HK12 #HX #H destruct
  56 /2 width=3 by ex2_intro/
  57 qed-.
  58
  59 lemma lfeq_inv_zero_pair_dx: ∀I,L1,K2,V. L1 ≡[#0] K2.ⓑ{I}V →
  60                              ∃∃K1. K1 ≡[V] K2 & L1 = K1.ⓑ{I}V.
  61 #I #L1 #K2 #V #H
  62 elim (lfxs_inv_zero_pair_dx … H) -H #K1 #X #HK12 #HX #H destruct
  63 /2 width=3 by ex2_intro/
  64 qed-.
  65
  66 lemma lfeq_inv_lref_bind_sn: ∀I1,K1,L2,i. K1.ⓘ{I1} ≡[#⫯i] L2 →
  67                              ∃∃I2,K2. K1 ≡[#i] K2 & L2 = K2.ⓘ{I2}.
  68 /2 width=2 by lfxs_inv_lref_bind_sn/ qed-.
  69
  70 lemma lfeq_inv_lref_bind_dx: ∀I2,K2,L1,i. L1 ≡[#⫯i] K2.ⓘ{I2} →
  71                              ∃∃I1,K1. K1 ≡[#i] K2 & L1 = K1.ⓘ{I1}.
  72 /2 width=2 by lfxs_inv_lref_bind_dx/ qed-.
  73
  74 (* Basic forward lemmas *****************************************************)
  75
  76 (* Basic_2A1: was: llpx_sn_lrefl *)
  77 (* Note: this should have been lleq_fwd_llpx_sn *)
  78 lemma lfeq_fwd_lfxs: ∀R. c_reflexive … R →
  79                      ∀L1,L2,T. L1 ≡[T] L2 → L1 ⪤*[R, T] L2.
  80 #R #HR #L1 #L2 #T * #f #Hf #HL12
  81 /4 width=7 by lexs_co, cext2_co, ex2_intro/
  82 qed-.
  83
  84 (* Basic_2A1: removed theorems 10:
  85               lleq_ind lleq_fwd_lref
  86               lleq_fwd_drop_sn lleq_fwd_drop_dx
  87               lleq_skip lleq_lref lleq_free
  88               lleq_Y lleq_ge_up lleq_ge
  89
  90 *)