matita/matita/contribs/lambdadelta/basic_2/static/lfxs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/relationstar_4.ma".
  16 include "basic_2/syntax/cext2.ma".
  17 include "basic_2/relocation/lexs.ma".
  18 include "basic_2/static/fle.ma".
  19
  20 (* GENERIC EXTENSION ON REFERRED ENTRIES OF A CONTEXT-SENSITIVE REALTION ****)
  21
  22 definition lfxs (R) (T): relation lenv ≝
  23                 λL1,L2. ∃∃f. L1 ⊢ 𝐅*⦃T⦄ ≡ f & L1 ⪤*[cext2 R, cfull, f] L2.
  24
  25 interpretation "generic extension on referred entries (local environment)"
  26    'RelationStar R T L1 L2 = (lfxs R T L1 L2).
  27
  28 definition R_fle_compatible: predicate (relation3 …) ≝ λRN.
  29                              ∀L,T1,T2. RN L T1 T2 → ⦃L, T2⦄ ⊆ ⦃L, T1⦄.
  30
  31 definition lfxs_fle_compatible: predicate (relation3 …) ≝ λRN.
  32                                 ∀L1,L2,T. L1 ⪤*[RN, T] L2 → ⦃L2, T⦄ ⊆ ⦃L1, T⦄.
  33
  34 definition R_confluent2_lfxs: relation4 (relation3 lenv term term)
  35                                         (relation3 lenv term term) … ≝
  36                               λR1,R2,RP1,RP2.
  37                               ∀L0,T0,T1. R1 L0 T0 T1 → ∀T2. R2 L0 T0 T2 →
  38                               ∀L1. L0 ⪤*[RP1, T0] L1 → ∀L2. L0 ⪤*[RP2, T0] L2 →
  39                               ∃∃T. R2 L1 T1 T & R1 L2 T2 T.
  40
  41 definition lfxs_confluent: relation … ≝
  42                            λR1,R2.
  43                            ∀K1,K,V1. K1 ⪤*[R1, V1] K → ∀V. R1 K1 V1 V →
  44                            ∀K2. K ⪤*[R2, V] K2 → K ⪤*[R2, V1] K2.
  45
  46 definition lfxs_transitive: relation3 ? (relation3 ?? term) ? ≝
  47                             λR1,R2,R3.
  48                             ∀K1,K,V1. K1 ⪤*[R1, V1] K →
  49                             ∀V. R1 K1 V1 V → ∀V2. R2 K V V2 → R3 K1 V1 V2.
  50
  51 (* Basic inversion lemmas ***************************************************)
  52
  53 lemma lfxs_inv_atom_sn: ∀R,Y2,T. ⋆ ⪤*[R, T] Y2 → Y2 = ⋆.
  54 #R #Y2 #T * /2 width=4 by lexs_inv_atom1/
  55 qed-.
  56
  57 lemma lfxs_inv_atom_dx: ∀R,Y1,T. Y1 ⪤*[R, T] ⋆ → Y1 = ⋆.
  58 #R #I #Y1 * /2 width=4 by lexs_inv_atom2/
  59 qed-.
  60
  61 lemma lfxs_inv_sort: ∀R,Y1,Y2,s. Y1 ⪤*[R, ⋆s] Y2 →
  62                      ∨∨ Y1 = ⋆ ∧ Y2 = ⋆
  63                       | ∃∃I1,I2,L1,L2. L1 ⪤*[R, ⋆s] L2 &
  64                                        Y1 = L1.ⓘ{I1} & Y2 = L2.ⓘ{I2}.
  65 #R * [ | #Y1 #I1 ] #Y2 #s * #f #H1 #H2
  66 [ lapply (lexs_inv_atom1 … H2) -H2 /3 width=1 by or_introl, conj/
  67 | lapply (frees_inv_sort … H1) -H1 #Hf
  68   elim (isid_inv_gen … Hf) -Hf #g #Hg #H destruct
  69   elim (lexs_inv_push1 … H2) -H2 #I2 #L2 #H12 #_ #H destruct
  70   /5 width=7 by frees_sort, ex3_4_intro, ex2_intro, or_intror/
  71 ]
  72 qed-.
  73
  74 lemma lfxs_inv_zero: ∀R,Y1,Y2. Y1 ⪤*[R, #0] Y2 →
  75                      ∨∨ Y1 = ⋆ ∧ Y2 = ⋆
  76                       | ∃∃I,L1,L2,V1,V2. L1 ⪤*[R, V1] L2 & R L1 V1 V2 &
  77                                          Y1 = L1.ⓑ{I}V1 & Y2 = L2.ⓑ{I}V2
  78                       | ∃∃f,I,L1,L2. 𝐈⦃f⦄ & L1 ⪤*[cext2 R, cfull, f] L2 &
  79                                      Y1 = L1.ⓤ{I} & Y2 = L2.ⓤ{I}.
  80 #R * [ | #Y1 * #I1 [ | #X ] ] #Y2 * #f #H1 #H2
  81 [ lapply (lexs_inv_atom1 … H2) -H2 /3 width=1 by or3_intro0, conj/
  82 | elim (frees_inv_unit … H1) -H1 #g #HX #H destruct
  83   elim (lexs_inv_next1 … H2) -H2 #I2 #L2 #HL12 #H #H2 destruct
  84   >(ext2_inv_unit_sn … H) -H /3 width=8 by or3_intro2, ex4_4_intro/
  85 | elim (frees_inv_pair … H1) -H1 #g #Hg #H destruct
  86   elim (lexs_inv_next1 … H2) -H2 #Z2 #L2 #HL12 #H
  87   elim (ext2_inv_pair_sn … H) -H
  88   /4 width=9 by or3_intro1, ex4_5_intro, ex2_intro/
  89 ]
  90 qed-.
  91
  92 lemma lfxs_inv_lref: ∀R,Y1,Y2,i. Y1 ⪤*[R, #⫯i] Y2 →
  93                      ∨∨ Y1 = ⋆ ∧ Y2 = ⋆
  94                       | ∃∃I1,I2,L1,L2. L1 ⪤*[R, #i] L2 &
  95                                        Y1 = L1.ⓘ{I1} & Y2 = L2.ⓘ{I2}.
  96 #R * [ | #Y1 #I1 ] #Y2 #i * #f #H1 #H2
  97 [ lapply (lexs_inv_atom1 … H2) -H2 /3 width=1 by or_introl, conj/
  98 | elim (frees_inv_lref … H1) -H1 #g #Hg #H destruct
  99   elim (lexs_inv_push1 … H2) -H2
 100   /4 width=7 by ex3_4_intro, ex2_intro, or_intror/
 101 ]
 102 qed-.
 103
 104 lemma lfxs_inv_gref: ∀R,Y1,Y2,l. Y1 ⪤*[R, §l] Y2 →
 105                      ∨∨ Y1 = ⋆ ∧ Y2 = ⋆
 106                       | ∃∃I1,I2,L1,L2. L1 ⪤*[R, §l] L2 &
 107                                        Y1 = L1.ⓘ{I1} & Y2 = L2.ⓘ{I2}.
 108 #R * [ | #Y1 #I1 ] #Y2 #l * #f #H1 #H2
 109 [ lapply (lexs_inv_atom1 … H2) -H2 /3 width=1 by or_introl, conj/
 110 | lapply (frees_inv_gref … H1) -H1 #Hf
 111   elim (isid_inv_gen … Hf) -Hf #g #Hg #H destruct
 112   elim (lexs_inv_push1 … H2) -H2 #I2 #L2 #H12 #_ #H destruct
 113   /5 width=7 by frees_gref, ex3_4_intro, ex2_intro, or_intror/
 114 ]
 115 qed-.
 116
 117 (* Basic_2A1: uses: llpx_sn_inv_bind llpx_sn_inv_bind_O *)
 118 lemma lfxs_inv_bind: ∀R,p,I,L1,L2,V1,V2,T. L1 ⪤*[R, ⓑ{p,I}V1.T] L2 → R L1 V1 V2 →
 119                      L1 ⪤*[R, V1] L2 ∧ L1.ⓑ{I}V1 ⪤*[R, T] L2.ⓑ{I}V2.
 120 #R #p #I #L1 #L2 #V1 #V2 #T * #f #Hf #HL #HV elim (frees_inv_bind … Hf) -Hf
 121 /6 width=6 by sle_lexs_trans, lexs_inv_tl, ext2_pair, sor_inv_sle_dx, sor_inv_sle_sn, ex2_intro, conj/
 122 qed-.
 123
 124 (* Basic_2A1: uses: llpx_sn_inv_flat *)
 125 lemma lfxs_inv_flat: ∀R,I,L1,L2,V,T. L1 ⪤*[R, ⓕ{I}V.T] L2 →
 126                      L1 ⪤*[R, V] L2 ∧ L1 ⪤*[R, T] L2.
 127 #R #I #L1 #L2 #V #T * #f #Hf #HL elim (frees_inv_flat … Hf) -Hf
 128 /5 width=6 by sle_lexs_trans, sor_inv_sle_dx, sor_inv_sle_sn, ex2_intro, conj/
 129 qed-.
 130
 131 (* Advanced inversion lemmas ************************************************)
 132
 133 lemma lfxs_inv_sort_bind_sn: ∀R,I1,K1,L2,s. K1.ⓘ{I1} ⪤*[R, ⋆s] L2 →
 134                              ∃∃I2,K2. K1 ⪤*[R, ⋆s] K2 & L2 = K2.ⓘ{I2}.
 135 #R #I1 #K1 #L2 #s #H elim (lfxs_inv_sort … H) -H *
 136 [ #H destruct
 137 | #Z1 #I2 #Y1 #K2 #Hs #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 138 ]
 139 qed-.
 140
 141 lemma lfxs_inv_sort_bind_dx: ∀R,I2,K2,L1,s. L1 ⪤*[R, ⋆s] K2.ⓘ{I2} →
 142                              ∃∃I1,K1. K1 ⪤*[R, ⋆s] K2 & L1 = K1.ⓘ{I1}.
 143 #R #I2 #K2 #L1 #s #H elim (lfxs_inv_sort … H) -H *
 144 [ #_ #H destruct
 145 | #I1 #Z2 #K1 #Y2 #Hs #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 146 ]
 147 qed-.
 148
 149 lemma lfxs_inv_zero_pair_sn: ∀R,I,L2,K1,V1. K1.ⓑ{I}V1 ⪤*[R, #0] L2 →
 150                              ∃∃K2,V2. K1 ⪤*[R, V1] K2 & R K1 V1 V2 &
 151                                       L2 = K2.ⓑ{I}V2.
 152 #R #I #L2 #K1 #V1 #H elim (lfxs_inv_zero … H) -H *
 153 [ #H destruct
 154 | #Z #Y1 #K2 #X1 #V2 #HK12 #HV12 #H1 #H2 destruct
 155   /2 width=5 by ex3_2_intro/
 156 | #f #Z #Y1 #Y2 #_ #_ #H destruct
 157 ]
 158 qed-.
 159
 160 lemma lfxs_inv_zero_pair_dx: ∀R,I,L1,K2,V2. L1 ⪤*[R, #0] K2.ⓑ{I}V2 →
 161                              ∃∃K1,V1. K1 ⪤*[R, V1] K2 & R K1 V1 V2 &
 162                                       L1 = K1.ⓑ{I}V1.
 163 #R #I #L1 #K2 #V2 #H elim (lfxs_inv_zero … H) -H *
 164 [ #_ #H destruct
 165 | #Z #K1 #Y2 #V1 #X2 #HK12 #HV12 #H1 #H2 destruct
 166   /2 width=5 by ex3_2_intro/
 167 | #f #Z #Y1 #Y2 #_ #_ #_ #H destruct
 168 ]
 169 qed-.
 170
 171 lemma lfxs_inv_zero_unit_sn: ∀R,I,K1,L2. K1.ⓤ{I} ⪤*[R, #0] L2 →
 172                              ∃∃f,K2. 𝐈⦃f⦄ & K1 ⪤*[cext2 R, cfull, f] K2 &
 173                                      L2 = K2.ⓤ{I}.
 174 #R #I #K1 #L2 #H elim (lfxs_inv_zero … H) -H *
 175 [ #H destruct
 176 | #Z #Y1 #Y2 #X1 #X2 #_ #_ #H destruct
 177 | #f #Z #Y1 #K2 #Hf #HK12 #H1 #H2 destruct /2 width=5 by ex3_2_intro/
 178 ]
 179 qed-.
 180
 181 lemma lfxs_inv_zero_unit_dx: ∀R,I,L1,K2. L1 ⪤*[R, #0] K2.ⓤ{I} →
 182                              ∃∃f,K1. 𝐈⦃f⦄ & K1 ⪤*[cext2 R, cfull, f] K2 &
 183                                      L1 = K1.ⓤ{I}.
 184 #R #I #L1 #K2 #H elim (lfxs_inv_zero … H) -H *
 185 [ #_ #H destruct
 186 | #Z #Y1 #Y2 #X1 #X2 #_ #_ #_ #H destruct
 187 | #f #Z #K1 #Y2 #Hf #HK12 #H1 #H2 destruct /2 width=5 by ex3_2_intro/
 188 ]
 189 qed-.
 190
 191 lemma lfxs_inv_lref_bind_sn: ∀R,I1,K1,L2,i. K1.ⓘ{I1} ⪤*[R, #⫯i] L2 →
 192                              ∃∃I2,K2. K1 ⪤*[R, #i] K2 & L2 = K2.ⓘ{I2}.
 193 #R #I1 #K1 #L2 #i #H elim (lfxs_inv_lref … H) -H *
 194 [ #H destruct
 195 | #Z1 #I2 #Y1 #K2 #Hi #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 196 ]
 197 qed-.
 198
 199 lemma lfxs_inv_lref_bind_dx: ∀R,I2,K2,L1,i. L1 ⪤*[R, #⫯i] K2.ⓘ{I2} →
 200                              ∃∃I1,K1. K1 ⪤*[R, #i] K2 & L1 = K1.ⓘ{I1}.
 201 #R #I2 #K2 #L1 #i #H elim (lfxs_inv_lref … H) -H *
 202 [ #_ #H destruct
 203 | #I1 #Z2 #K1 #Y2 #Hi #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 204 ]
 205 qed-.
 206
 207 lemma lfxs_inv_gref_bind_sn: ∀R,I1,K1,L2,l. K1.ⓘ{I1} ⪤*[R, §l] L2 →
 208                              ∃∃I2,K2. K1 ⪤*[R, §l] K2 & L2 = K2.ⓘ{I2}.
 209 #R #I1 #K1 #L2 #l #H elim (lfxs_inv_gref … H) -H *
 210 [ #H destruct
 211 | #Z1 #I2 #Y1 #K2 #Hl #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 212 ]
 213 qed-.
 214
 215 lemma lfxs_inv_gref_bind_dx: ∀R,I2,K2,L1,l. L1 ⪤*[R, §l] K2.ⓘ{I2} →
 216                              ∃∃I1,K1. K1 ⪤*[R, §l] K2 & L1 = K1.ⓘ{I1}.
 217 #R #I2 #K2 #L1 #l #H elim (lfxs_inv_gref … H) -H *
 218 [ #_ #H destruct
 219 | #I1 #Z2 #K1 #Y2 #Hl #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 220 ]
 221 qed-.
 222
 223 (* Basic forward lemmas *****************************************************)
 224
 225 lemma lfxs_fwd_zero_pair: ∀R,I,K1,K2,V1,V2.
 226                           K1.ⓑ{I}V1 ⪤*[R, #0] K2.ⓑ{I}V2 → K1 ⪤*[R, V1] K2.
 227 #R #I #K1 #K2 #V1 #V2 #H
 228 elim (lfxs_inv_zero_pair_sn … H) -H #Y #X #HK12 #_ #H destruct //
 229 qed-.
 230
 231 (* Basic_2A1: uses: llpx_sn_fwd_pair_sn llpx_sn_fwd_bind_sn llpx_sn_fwd_flat_sn *)
 232 lemma lfxs_fwd_pair_sn: ∀R,I,L1,L2,V,T. L1 ⪤*[R, ②{I}V.T] L2 → L1 ⪤*[R, V] L2.
 233 #R * [ #p ] #I #L1 #L2 #V #T * #f #Hf #HL
 234 [ elim (frees_inv_bind … Hf) | elim (frees_inv_flat … Hf) ] -Hf
 235 /4 width=6 by sle_lexs_trans, sor_inv_sle_sn, ex2_intro/
 236 qed-.
 237
 238 (* Basic_2A1: uses: llpx_sn_fwd_bind_dx llpx_sn_fwd_bind_O_dx *)
 239 lemma lfxs_fwd_bind_dx: ∀R,p,I,L1,L2,V1,V2,T. L1 ⪤*[R, ⓑ{p,I}V1.T] L2 →
 240                         R L1 V1 V2 → L1.ⓑ{I}V1 ⪤*[R, T] L2.ⓑ{I}V2.
 241 #R #p #I #L1 #L2 #V1 #V2 #T #H #HV elim (lfxs_inv_bind … H HV) -H -HV //
 242 qed-.
 243
 244 (* Basic_2A1: uses: llpx_sn_fwd_flat_dx *)
 245 lemma lfxs_fwd_flat_dx: ∀R,I,L1,L2,V,T. L1 ⪤*[R, ⓕ{I}V.T] L2 → L1 ⪤*[R, T] L2.
 246 #R #I #L1 #L2 #V #T #H elim (lfxs_inv_flat … H) -H //
 247 qed-.
 248
 249 lemma lfxs_fwd_dx: ∀R,I2,L1,K2,T. L1 ⪤*[R, T] K2.ⓘ{I2} →
 250                    ∃∃I1,K1. L1 = K1.ⓘ{I1}.
 251 #R #I2 #L1 #K2 #T * #f elim (pn_split f) * #g #Hg #_ #Hf destruct
 252 [ elim (lexs_inv_push2 … Hf) | elim (lexs_inv_next2 … Hf) ] -Hf #I1 #K1 #_ #_ #H destruct
 253 /2 width=3 by ex1_2_intro/
 254 qed-.
 255
 256 (* Basic properties *********************************************************)
 257
 258 lemma lfxs_atom: ∀R,I. ⋆ ⪤*[R, ⓪{I}] ⋆.
 259 #R * /3 width=3 by frees_sort, frees_atom, frees_gref, lexs_atom, ex2_intro/
 260 qed.
 261
 262 (* Basic_2A1: uses: llpx_sn_sort *)
 263 lemma lfxs_sort: ∀R,I1,I2,L1,L2,s.
 264                  L1 ⪤*[R, ⋆s] L2 → L1.ⓘ{I1} ⪤*[R, ⋆s] L2.ⓘ{I2}.
 265 #R #I1 #I2 #L1 #L2 #s * #f #Hf #H12
 266 lapply (frees_inv_sort … Hf) -Hf
 267 /4 width=3 by frees_sort, lexs_push, isid_push, ex2_intro/
 268 qed.
 269
 270 lemma lfxs_pair: ∀R,I,L1,L2,V1,V2. L1 ⪤*[R, V1] L2 →
 271                  R L1 V1 V2 → L1.ⓑ{I}V1 ⪤*[R, #0] L2.ⓑ{I}V2.
 272 #R #I1 #I2 #L1 #L2 #V1 *
 273 /4 width=3 by ext2_pair, frees_pair, lexs_next, ex2_intro/
 274 qed.
 275
 276 lemma lfxs_unit: ∀R,f,I,L1,L2. 𝐈⦃f⦄ → L1 ⪤*[cext2 R, cfull, f] L2 →
 277                  L1.ⓤ{I} ⪤*[R, #0] L2.ⓤ{I}.
 278 /4 width=3 by frees_unit, lexs_next, ext2_unit, ex2_intro/ qed.
 279
 280 lemma lfxs_lref: ∀R,I1,I2,L1,L2,i.
 281                  L1 ⪤*[R, #i] L2 → L1.ⓘ{I1} ⪤*[R, #⫯i] L2.ⓘ{I2}.
 282 #R #I1 #I2 #L1 #L2 #i * /3 width=3 by lexs_push, frees_lref, ex2_intro/
 283 qed.
 284
 285 (* Basic_2A1: uses: llpx_sn_gref *)
 286 lemma lfxs_gref: ∀R,I1,I2,L1,L2,l.
 287                  L1 ⪤*[R, §l] L2 → L1.ⓘ{I1} ⪤*[R, §l] L2.ⓘ{I2}.
 288 #R #I1 #I2 #L1 #L2 #l * #f #Hf #H12
 289 lapply (frees_inv_gref … Hf) -Hf
 290 /4 width=3 by frees_gref, lexs_push, isid_push, ex2_intro/
 291 qed.
 292
 293 lemma lfxs_bind_repl_dx: ∀R,I,I1,L1,L2,T.
 294                          L1.ⓘ{I} ⪤*[R, T] L2.ⓘ{I1} →
 295                          ∀I2. cext2 R L1 I I2 →
 296                          L1.ⓘ{I} ⪤*[R, T] L2.ⓘ{I2}.
 297 #R #I #I1 #L1 #L2 #T * #f #Hf #HL12 #I2 #HR
 298 /3 width=5 by lexs_pair_repl, ex2_intro/
 299 qed-.
 300
 301 (* Basic_2A1: uses: llpx_sn_co *)
 302 lemma lfxs_co: ∀R1,R2. (∀L,T1,T2. R1 L T1 T2 → R2 L T1 T2) →
 303                ∀L1,L2,T. L1 ⪤*[R1, T] L2 → L1 ⪤*[R2, T] L2.
 304 #R1 #R2 #HR #L1 #L2 #T * /5 width=7 by lexs_co, cext2_co, ex2_intro/
 305 qed-.
 306
 307 lemma lfxs_isid: ∀R1,R2,L1,L2,T1,T2.
 308                  (∀f. L1 ⊢ 𝐅*⦃T1⦄ ≡ f → 𝐈⦃f⦄) →
 309                  (∀f. 𝐈⦃f⦄ → L1 ⊢ 𝐅*⦃T2⦄ ≡ f) →
 310                  L1 ⪤*[R1, T1] L2 → L1 ⪤*[R2, T2] L2.
 311 #R1 #R2 #L1 #L2 #T1 #T2 #H1 #H2 *
 312 /4 width=7 by lexs_co_isid, ex2_intro/
 313 qed-.
 314
 315 lemma lfxs_unit_sn: ∀R1,R2,I,K1,L2.
 316                     K1.ⓤ{I} ⪤*[R1, #0] L2 → K1.ⓤ{I} ⪤*[R2, #0] L2.
 317 #R1 #R2 #I #K1 #L2 #H
 318 elim (lfxs_inv_zero_unit_sn … H) -H #f #K2 #Hf #HK12 #H destruct
 319 /3 width=7 by lfxs_unit, lexs_co_isid/
 320 qed-.
 321
 322 (* Basic_2A1: removed theorems 9:
 323               llpx_sn_skip llpx_sn_lref llpx_sn_free
 324               llpx_sn_fwd_lref
 325               llpx_sn_Y llpx_sn_ge_up llpx_sn_ge
 326               llpx_sn_fwd_drop_sn llpx_sn_fwd_drop_dx
 327 *)