matita/matita/contribs/lambdadelta/basic_2/static/lfxs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/relocation/rtmap_id.ma".
  16 include "basic_2/notation/relations/relationstar_4.ma".
  17 include "basic_2/syntax/cext2.ma".
  18 include "basic_2/relocation/lexs.ma".
  19 include "basic_2/static/frees.ma".
  20
  21 (* GENERIC EXTENSION ON REFERRED ENTRIES OF A CONTEXT-SENSITIVE REALTION ****)
  22
  23 definition lfxs (R) (T): relation lenv ≝
  24                 λL1,L2. ∃∃f. L1 ⊢ 𝐅*⦃T⦄ ≡ f & L1 ⪤*[cext2 R, cfull, f] L2.
  25
  26 interpretation "generic extension on referred entries (local environment)"
  27    'RelationStar R T L1 L2 = (lfxs R T L1 L2).
  28
  29 definition R_frees_confluent: predicate (relation3 …) ≝
  30                               λRN.
  31                               ∀f1,L,T1. L ⊢ 𝐅*⦃T1⦄ ≡ f1 → ∀T2. RN L T1 T2 →
  32                               ∃∃f2. L ⊢ 𝐅*⦃T2⦄ ≡ f2 & f2 ⊆ f1.
  33
  34 definition lexs_frees_confluent: relation (relation3 …) ≝
  35                                  λRN,RP.
  36                                  ∀f1,L1,T. L1 ⊢ 𝐅*⦃T⦄ ≡ f1 →
  37                                  ∀L2. L1 ⪤*[RN, RP, f1] L2 →
  38                                  ∃∃f2. L2 ⊢ 𝐅*⦃T⦄ ≡ f2 & f2 ⊆ f1.
  39
  40 definition R_confluent2_lfxs: relation4 (relation3 lenv term term)
  41                                         (relation3 lenv term term) … ≝
  42                               λR1,R2,RP1,RP2.
  43                               ∀L0,T0,T1. R1 L0 T0 T1 → ∀T2. R2 L0 T0 T2 →
  44                               ∀L1. L0 ⪤*[RP1, T0] L1 → ∀L2. L0 ⪤*[RP2, T0] L2 →
  45                               ∃∃T. R2 L1 T1 T & R1 L2 T2 T.
  46
  47 definition lfxs_confluent: relation … ≝
  48                            λR1,R2.
  49                            ∀K1,K,V1. K1 ⪤*[R1, V1] K → ∀V. R1 K1 V1 V →
  50                            ∀K2. K ⪤*[R2, V] K2 → K ⪤*[R2, V1] K2.
  51
  52 definition lfxs_transitive: relation3 ? (relation3 ?? term) ? ≝
  53                             λR1,R2,R3.
  54                             ∀K1,K,V1. K1 ⪤*[R1, V1] K →
  55                             ∀V. R1 K1 V1 V → ∀V2. R2 K V V2 → R3 K1 V1 V2.
  56
  57 (* Basic inversion lemmas ***************************************************)
  58
  59 lemma lfxs_inv_atom_sn: ∀R,Y2,T. ⋆ ⪤*[R, T] Y2 → Y2 = ⋆.
  60 #R #Y2 #T * /2 width=4 by lexs_inv_atom1/
  61 qed-.
  62
  63 lemma lfxs_inv_atom_dx: ∀R,Y1,T. Y1 ⪤*[R, T] ⋆ → Y1 = ⋆.
  64 #R #I #Y1 * /2 width=4 by lexs_inv_atom2/
  65 qed-.
  66
  67 lemma lfxs_inv_sort: ∀R,Y1,Y2,s. Y1 ⪤*[R, ⋆s] Y2 →
  68                      ∨∨ Y1 = ⋆ ∧ Y2 = ⋆
  69                       | ∃∃I1,I2,L1,L2. L1 ⪤*[R, ⋆s] L2 &
  70                                        Y1 = L1.ⓘ{I1} & Y2 = L2.ⓘ{I2}.
  71 #R * [ | #Y1 #I1 ] #Y2 #s * #f #H1 #H2
  72 [ lapply (lexs_inv_atom1 … H2) -H2 /3 width=1 by or_introl, conj/
  73 | lapply (frees_inv_sort … H1) -H1 #Hf
  74   elim (isid_inv_gen … Hf) -Hf #g #Hg #H destruct
  75   elim (lexs_inv_push1 … H2) -H2 #I2 #L2 #H12 #_ #H destruct
  76   /5 width=7 by frees_sort, ex3_4_intro, ex2_intro, or_intror/
  77 ]
  78 qed-.
  79
  80 lemma lfxs_inv_zero: ∀R,Y1,Y2. Y1 ⪤*[R, #0] Y2 →
  81                      ∨∨ Y1 = ⋆ ∧ Y2 = ⋆
  82                       | ∃∃I,L1,L2,V1,V2. L1 ⪤*[R, V1] L2 & R L1 V1 V2 &
  83                                          Y1 = L1.ⓑ{I}V1 & Y2 = L2.ⓑ{I}V2
  84                       | ∃∃f,I,L1,L2. 𝐈⦃f⦄ & L1 ⪤*[cext2 R, cfull, f] L2 &
  85                                      Y1 = L1.ⓤ{I} & Y2 = L2.ⓤ{I}.
  86 #R * [ | #Y1 * #I1 [ | #X ] ] #Y2 * #f #H1 #H2
  87 [ lapply (lexs_inv_atom1 … H2) -H2 /3 width=1 by or3_intro0, conj/
  88 | elim (frees_inv_unit … H1) -H1 #g #HX #H destruct
  89   elim (lexs_inv_next1 … H2) -H2 #I2 #L2 #HL12 #H #H2 destruct
  90   >(ext2_inv_unit_sn … H) -H /3 width=8 by or3_intro2, ex4_4_intro/
  91 | elim (frees_inv_pair … H1) -H1 #g #Hg #H destruct
  92   elim (lexs_inv_next1 … H2) -H2 #Z2 #L2 #HL12 #H
  93   elim (ext2_inv_pair_sn … H) -H
  94   /4 width=9 by or3_intro1, ex4_5_intro, ex2_intro/
  95 ]
  96 qed-.
  97
  98 lemma lfxs_inv_lref: ∀R,Y1,Y2,i. Y1 ⪤*[R, #⫯i] Y2 →
  99                      ∨∨ Y1 = ⋆ ∧ Y2 = ⋆
 100                       | ∃∃I1,I2,L1,L2. L1 ⪤*[R, #i] L2 &
 101                                        Y1 = L1.ⓘ{I1} & Y2 = L2.ⓘ{I2}.
 102 #R * [ | #Y1 #I1 ] #Y2 #i * #f #H1 #H2
 103 [ lapply (lexs_inv_atom1 … H2) -H2 /3 width=1 by or_introl, conj/
 104 | elim (frees_inv_lref … H1) -H1 #g #Hg #H destruct
 105   elim (lexs_inv_push1 … H2) -H2
 106   /4 width=7 by ex3_4_intro, ex2_intro, or_intror/
 107 ]
 108 qed-.
 109
 110 lemma lfxs_inv_gref: ∀R,Y1,Y2,l. Y1 ⪤*[R, §l] Y2 →
 111                      ∨∨ Y1 = ⋆ ∧ Y2 = ⋆
 112                       | ∃∃I1,I2,L1,L2. L1 ⪤*[R, §l] L2 &
 113                                        Y1 = L1.ⓘ{I1} & Y2 = L2.ⓘ{I2}.
 114 #R * [ | #Y1 #I1 ] #Y2 #l * #f #H1 #H2
 115 [ lapply (lexs_inv_atom1 … H2) -H2 /3 width=1 by or_introl, conj/
 116 | lapply (frees_inv_gref … H1) -H1 #Hf
 117   elim (isid_inv_gen … Hf) -Hf #g #Hg #H destruct
 118   elim (lexs_inv_push1 … H2) -H2 #I2 #L2 #H12 #_ #H destruct
 119   /5 width=7 by frees_gref, ex3_4_intro, ex2_intro, or_intror/
 120 ]
 121 qed-.
 122
 123 (* Basic_2A1: uses: llpx_sn_inv_bind llpx_sn_inv_bind_O *)
 124 lemma lfxs_inv_bind: ∀R,p,I,L1,L2,V1,V2,T. L1 ⪤*[R, ⓑ{p,I}V1.T] L2 → R L1 V1 V2 →
 125                      L1 ⪤*[R, V1] L2 ∧ L1.ⓑ{I}V1 ⪤*[R, T] L2.ⓑ{I}V2.
 126 #R #p #I #L1 #L2 #V1 #V2 #T * #f #Hf #HL #HV elim (frees_inv_bind … Hf) -Hf
 127 /6 width=6 by sle_lexs_trans, lexs_inv_tl, ext2_pair, sor_inv_sle_dx, sor_inv_sle_sn, ex2_intro, conj/
 128 qed-.
 129
 130 (* Basic_2A1: uses: llpx_sn_inv_flat *)
 131 lemma lfxs_inv_flat: ∀R,I,L1,L2,V,T. L1 ⪤*[R, ⓕ{I}V.T] L2 →
 132                      L1 ⪤*[R, V] L2 ∧ L1 ⪤*[R, T] L2.
 133 #R #I #L1 #L2 #V #T * #f #Hf #HL elim (frees_inv_flat … Hf) -Hf
 134 /5 width=6 by sle_lexs_trans, sor_inv_sle_dx, sor_inv_sle_sn, ex2_intro, conj/
 135 qed-.
 136
 137 (* Advanced inversion lemmas ************************************************)
 138
 139 lemma lfxs_inv_sort_bind_sn: ∀R,I1,K1,L2,s. K1.ⓘ{I1} ⪤*[R, ⋆s] L2 →
 140                              ∃∃I2,K2. K1 ⪤*[R, ⋆s] K2 & L2 = K2.ⓘ{I2}.
 141 #R #I1 #K1 #L2 #s #H elim (lfxs_inv_sort … H) -H *
 142 [ #H destruct
 143 | #Z1 #I2 #Y1 #K2 #Hs #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 144 ]
 145 qed-.
 146
 147 lemma lfxs_inv_sort_bind_dx: ∀R,I2,K2,L1,s. L1 ⪤*[R, ⋆s] K2.ⓘ{I2} →
 148                              ∃∃I1,K1. K1 ⪤*[R, ⋆s] K2 & L1 = K1.ⓘ{I1}.
 149 #R #I2 #K2 #L1 #s #H elim (lfxs_inv_sort … H) -H *
 150 [ #_ #H destruct
 151 | #I1 #Z2 #K1 #Y2 #Hs #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 152 ]
 153 qed-.
 154
 155 lemma lfxs_inv_zero_pair_sn: ∀R,I,L2,K1,V1. K1.ⓑ{I}V1 ⪤*[R, #0] L2 →
 156                              ∃∃K2,V2. K1 ⪤*[R, V1] K2 & R K1 V1 V2 &
 157                                       L2 = K2.ⓑ{I}V2.
 158 #R #I #L2 #K1 #V1 #H elim (lfxs_inv_zero … H) -H *
 159 [ #H destruct
 160 | #Z #Y1 #K2 #X1 #V2 #HK12 #HV12 #H1 #H2 destruct
 161   /2 width=5 by ex3_2_intro/
 162 | #f #Z #Y1 #Y2 #_ #_ #H destruct
 163 ]
 164 qed-.
 165
 166 lemma lfxs_inv_zero_pair_dx: ∀R,I,L1,K2,V2. L1 ⪤*[R, #0] K2.ⓑ{I}V2 →
 167                              ∃∃K1,V1. K1 ⪤*[R, V1] K2 & R K1 V1 V2 &
 168                                       L1 = K1.ⓑ{I}V1.
 169 #R #I #L1 #K2 #V2 #H elim (lfxs_inv_zero … H) -H *
 170 [ #_ #H destruct
 171 | #Z #K1 #Y2 #V1 #X2 #HK12 #HV12 #H1 #H2 destruct
 172   /2 width=5 by ex3_2_intro/
 173 | #f #Z #Y1 #Y2 #_ #_ #_ #H destruct
 174 ]
 175 qed-.
 176
 177 lemma lfxs_inv_zero_unit_sn: ∀R,I,K1,L2. K1.ⓤ{I} ⪤*[R, #0] L2 →
 178                              ∃∃f,K2. 𝐈⦃f⦄ & K1 ⪤*[cext2 R, cfull, f] K2 &
 179                                      L2 = K2.ⓤ{I}.
 180 #R #I #K1 #L2 #H elim (lfxs_inv_zero … H) -H *
 181 [ #H destruct
 182 | #Z #Y1 #Y2 #X1 #X2 #_ #_ #H destruct
 183 | #f #Z #Y1 #K2 #Hf #HK12 #H1 #H2 destruct /2 width=5 by ex3_2_intro/
 184 ]
 185 qed-.
 186
 187 lemma lfxs_inv_zero_unit_dx: ∀R,I,L1,K2. L1 ⪤*[R, #0] K2.ⓤ{I} →
 188                              ∃∃f,K1. 𝐈⦃f⦄ & K1 ⪤*[cext2 R, cfull, f] K2 &
 189                                      L1 = K1.ⓤ{I}.
 190 #R #I #L1 #K2 #H elim (lfxs_inv_zero … H) -H *
 191 [ #_ #H destruct
 192 | #Z #Y1 #Y2 #X1 #X2 #_ #_ #_ #H destruct
 193 | #f #Z #K1 #Y2 #Hf #HK12 #H1 #H2 destruct /2 width=5 by ex3_2_intro/
 194 ]
 195 qed-.
 196
 197 lemma lfxs_inv_lref_bind_sn: ∀R,I1,K1,L2,i. K1.ⓘ{I1} ⪤*[R, #⫯i] L2 →
 198                              ∃∃I2,K2. K1 ⪤*[R, #i] K2 & L2 = K2.ⓘ{I2}.
 199 #R #I1 #K1 #L2 #i #H elim (lfxs_inv_lref … H) -H *
 200 [ #H destruct
 201 | #Z1 #I2 #Y1 #K2 #Hi #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 202 ]
 203 qed-.
 204
 205 lemma lfxs_inv_lref_bind_dx: ∀R,I2,K2,L1,i. L1 ⪤*[R, #⫯i] K2.ⓘ{I2} →
 206                              ∃∃I1,K1. K1 ⪤*[R, #i] K2 & L1 = K1.ⓘ{I1}.
 207 #R #I2 #K2 #L1 #i #H elim (lfxs_inv_lref … H) -H *
 208 [ #_ #H destruct
 209 | #I1 #Z2 #K1 #Y2 #Hi #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 210 ]
 211 qed-.
 212
 213 lemma lfxs_inv_gref_bind_sn: ∀R,I1,K1,L2,l. K1.ⓘ{I1} ⪤*[R, §l] L2 →
 214                              ∃∃I2,K2. K1 ⪤*[R, §l] K2 & L2 = K2.ⓘ{I2}.
 215 #R #I1 #K1 #L2 #l #H elim (lfxs_inv_gref … H) -H *
 216 [ #H destruct
 217 | #Z1 #I2 #Y1 #K2 #Hl #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 218 ]
 219 qed-.
 220
 221 lemma lfxs_inv_gref_bind_dx: ∀R,I2,K2,L1,l. L1 ⪤*[R, §l] K2.ⓘ{I2} →
 222                              ∃∃I1,K1. K1 ⪤*[R, §l] K2 & L1 = K1.ⓘ{I1}.
 223 #R #I2 #K2 #L1 #l #H elim (lfxs_inv_gref … H) -H *
 224 [ #_ #H destruct
 225 | #I1 #Z2 #K1 #Y2 #Hl #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 226 ]
 227 qed-.
 228
 229 (* Basic forward lemmas *****************************************************)
 230
 231 lemma lfxs_fwd_zero_pair: ∀R,I,K1,K2,V1,V2.
 232                           K1.ⓑ{I}V1 ⪤*[R, #0] K2.ⓑ{I}V2 → K1 ⪤*[R, V1] K2.
 233 #R #I #K1 #K2 #V1 #V2 #H
 234 elim (lfxs_inv_zero_pair_sn … H) -H #Y #X #HK12 #_ #H destruct //
 235 qed-.
 236
 237 (* Basic_2A1: uses: llpx_sn_fwd_pair_sn llpx_sn_fwd_bind_sn llpx_sn_fwd_flat_sn *)
 238 lemma lfxs_fwd_pair_sn: ∀R,I,L1,L2,V,T. L1 ⪤*[R, ②{I}V.T] L2 → L1 ⪤*[R, V] L2.
 239 #R * [ #p ] #I #L1 #L2 #V #T * #f #Hf #HL
 240 [ elim (frees_inv_bind … Hf) | elim (frees_inv_flat … Hf) ] -Hf
 241 /4 width=6 by sle_lexs_trans, sor_inv_sle_sn, ex2_intro/
 242 qed-.
 243
 244 (* Basic_2A1: uses: llpx_sn_fwd_bind_dx llpx_sn_fwd_bind_O_dx *)
 245 lemma lfxs_fwd_bind_dx: ∀R,p,I,L1,L2,V1,V2,T. L1 ⪤*[R, ⓑ{p,I}V1.T] L2 →
 246                         R L1 V1 V2 → L1.ⓑ{I}V1 ⪤*[R, T] L2.ⓑ{I}V2.
 247 #R #p #I #L1 #L2 #V1 #V2 #T #H #HV elim (lfxs_inv_bind … H HV) -H -HV //
 248 qed-.
 249
 250 (* Basic_2A1: uses: llpx_sn_fwd_flat_dx *)
 251 lemma lfxs_fwd_flat_dx: ∀R,I,L1,L2,V,T. L1 ⪤*[R, ⓕ{I}V.T] L2 → L1 ⪤*[R, T] L2.
 252 #R #I #L1 #L2 #V #T #H elim (lfxs_inv_flat … H) -H //
 253 qed-.
 254
 255 lemma lfxs_fwd_dx: ∀R,I2,L1,K2,T. L1 ⪤*[R, T] K2.ⓘ{I2} →
 256                    ∃∃I1,K1. L1 = K1.ⓘ{I1}.
 257 #R #I2 #L1 #K2 #T * #f elim (pn_split f) * #g #Hg #_ #Hf destruct
 258 [ elim (lexs_inv_push2 … Hf) | elim (lexs_inv_next2 … Hf) ] -Hf #I1 #K1 #_ #_ #H destruct
 259 /2 width=3 by ex1_2_intro/
 260 qed-.
 261
 262 (* Basic properties *********************************************************)
 263
 264 lemma lfxs_atom: ∀R,I. ⋆ ⪤*[R, ⓪{I}] ⋆.
 265 #R * /3 width=3 by frees_sort, frees_atom, frees_gref, lexs_atom, ex2_intro/
 266 qed.
 267
 268 (* Basic_2A1: uses: llpx_sn_sort *)
 269 lemma lfxs_sort: ∀R,I1,I2,L1,L2,s.
 270                  L1 ⪤*[R, ⋆s] L2 → L1.ⓘ{I1} ⪤*[R, ⋆s] L2.ⓘ{I2}.
 271 #R #I1 #I2 #L1 #L2 #s * #f #Hf #H12
 272 lapply (frees_inv_sort … Hf) -Hf
 273 /4 width=3 by frees_sort, lexs_push, isid_push, ex2_intro/
 274 qed.
 275
 276 lemma lfxs_pair: ∀R,I,L1,L2,V1,V2. L1 ⪤*[R, V1] L2 →
 277                  R L1 V1 V2 → L1.ⓑ{I}V1 ⪤*[R, #0] L2.ⓑ{I}V2.
 278 #R #I1 #I2 #L1 #L2 #V1 *
 279 /4 width=3 by ext2_pair, frees_pair, lexs_next, ex2_intro/
 280 qed.
 281
 282 lemma lfxs_unit: ∀R,f,I,L1,L2. 𝐈⦃f⦄ → L1 ⪤*[cext2 R, cfull, f] L2 →
 283                  L1.ⓤ{I} ⪤*[R, #0] L2.ⓤ{I}.
 284 /4 width=3 by frees_unit, lexs_next, ext2_unit, ex2_intro/ qed.
 285
 286 lemma lfxs_lref: ∀R,I1,I2,L1,L2,i.
 287                  L1 ⪤*[R, #i] L2 → L1.ⓘ{I1} ⪤*[R, #⫯i] L2.ⓘ{I2}.
 288 #R #I1 #I2 #L1 #L2 #i * /3 width=3 by lexs_push, frees_lref, ex2_intro/
 289 qed.
 290
 291 (* Basic_2A1: uses: llpx_sn_gref *)
 292 lemma lfxs_gref: ∀R,I1,I2,L1,L2,l.
 293                  L1 ⪤*[R, §l] L2 → L1.ⓘ{I1} ⪤*[R, §l] L2.ⓘ{I2}.
 294 #R #I1 #I2 #L1 #L2 #l * #f #Hf #H12
 295 lapply (frees_inv_gref … Hf) -Hf
 296 /4 width=3 by frees_gref, lexs_push, isid_push, ex2_intro/
 297 qed.
 298
 299 lemma lfxs_bind_repl_dx: ∀R,I,I1,L1,L2,T.
 300                          L1.ⓘ{I} ⪤*[R, T] L2.ⓘ{I1} →
 301                          ∀I2. cext2 R L1 I I2 →
 302                          L1.ⓘ{I} ⪤*[R, T] L2.ⓘ{I2}.
 303 #R #I #I1 #L1 #L2 #T * #f #Hf #HL12 #I2 #HR
 304 /3 width=5 by lexs_pair_repl, ex2_intro/
 305 qed-.
 306
 307 lemma lfxs_sym: ∀R. lexs_frees_confluent (cext2 R) cfull →
 308                 (∀L1,L2,T1,T2. R L1 T1 T2 → R L2 T2 T1) →
 309                 ∀T. symmetric … (lfxs R T).
 310 #R #H1R #H2R #T #L1 #L2 * #f1 #Hf1 #HL12 elim (H1R … Hf1 … HL12) -Hf1
 311 /5 width=5 by sle_lexs_trans, lexs_sym, cext2_sym, ex2_intro/
 312 qed-.
 313
 314 (* Basic_2A1: uses: llpx_sn_co *)
 315 lemma lfxs_co: ∀R1,R2. (∀L,T1,T2. R1 L T1 T2 → R2 L T1 T2) →
 316                ∀L1,L2,T. L1 ⪤*[R1, T] L2 → L1 ⪤*[R2, T] L2.
 317 #R1 #R2 #HR #L1 #L2 #T * /5 width=7 by lexs_co, cext2_co, ex2_intro/
 318 qed-.
 319
 320 lemma lfxs_isid: ∀R1,R2,L1,L2,T1,T2.
 321                  (∀f. L1 ⊢ 𝐅*⦃T1⦄ ≡ f → 𝐈⦃f⦄) →
 322                  (∀f. 𝐈⦃f⦄ → L1 ⊢ 𝐅*⦃T2⦄ ≡ f) →
 323                  L1 ⪤*[R1, T1] L2 → L1 ⪤*[R2, T2] L2.
 324 #R1 #R2 #L1 #L2 #T1 #T2 #H1 #H2 *
 325 /4 width=7 by lexs_co_isid, ex2_intro/
 326 qed-.
 327
 328 lemma lfxs_unit_sn: ∀R1,R2,I,K1,L2.
 329                     K1.ⓤ{I} ⪤*[R1, #0] L2 → K1.ⓤ{I} ⪤*[R2, #0] L2.
 330 #R1 #R2 #I #K1 #L2 #H
 331 elim (lfxs_inv_zero_unit_sn … H) -H #f #K2 #Hf #HK12 #H destruct
 332 /3 width=7 by lfxs_unit, lexs_co_isid/
 333 qed-.
 334
 335 (* Basic_2A1: removed theorems 9:
 336               llpx_sn_skip llpx_sn_lref llpx_sn_free
 337               llpx_sn_fwd_lref
 338               llpx_sn_Y llpx_sn_ge_up llpx_sn_ge
 339               llpx_sn_fwd_drop_sn llpx_sn_fwd_drop_dx
 340 *)