matita/matita/contribs/lambdadelta/basic_2/static/lfxs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/relocation/rtmap_id.ma".
  16 include "basic_2/notation/relations/relationstar_4.ma".
  17 include "basic_2/syntax/cext2.ma".
  18 include "basic_2/relocation/lexs.ma".
  19 include "basic_2/static/frees.ma".
  20
  21 (* GENERIC EXTENSION ON REFERRED ENTRIES OF A CONTEXT-SENSITIVE REALTION ****)
  22
  23 definition lfxs (R) (T): relation lenv ≝
  24                 λL1,L2. ∃∃f. L1 ⊢ 𝐅*⦃T⦄ ≡ f & L1 ⪤*[cext2 R, cfull, f] L2.
  25
  26 interpretation "generic extension on referred entries (local environment)"
  27    'RelationStar R T L1 L2 = (lfxs R T L1 L2).
  28
  29 definition R_confluent2_lfxs: relation4 (relation3 lenv term term)
  30                                         (relation3 lenv term term) … ≝
  31                               λR1,R2,RP1,RP2.
  32                               ∀L0,T0,T1. R1 L0 T0 T1 → ∀T2. R2 L0 T0 T2 →
  33                               ∀L1. L0 ⪤*[RP1, T0] L1 → ∀L2. L0 ⪤*[RP2, T0] L2 →
  34                               ∃∃T. R2 L1 T1 T & R1 L2 T2 T.
  35
  36 definition lfxs_confluent: relation … ≝
  37                            λR1,R2.
  38                            ∀K1,K,V1. K1 ⪤*[R1, V1] K → ∀V. R1 K1 V1 V →
  39                            ∀K2. K ⪤*[R2, V] K2 → K ⪤*[R2, V1] K2.
  40
  41 definition lfxs_transitive: relation3 ? (relation3 ?? term) ? ≝
  42                             λR1,R2,R3.
  43                             ∀K1,K,V1. K1 ⪤*[R1, V1] K →
  44                             ∀V. R1 K1 V1 V → ∀V2. R2 K V V2 → R3 K1 V1 V2.
  45
  46 (* Basic inversion lemmas ***************************************************)
  47
  48 lemma lfxs_inv_atom_sn: ∀R,Y2,T. ⋆ ⪤*[R, T] Y2 → Y2 = ⋆.
  49 #R #Y2 #T * /2 width=4 by lexs_inv_atom1/
  50 qed-.
  51
  52 lemma lfxs_inv_atom_dx: ∀R,Y1,T. Y1 ⪤*[R, T] ⋆ → Y1 = ⋆.
  53 #R #I #Y1 * /2 width=4 by lexs_inv_atom2/
  54 qed-.
  55
  56 lemma lfxs_inv_sort: ∀R,Y1,Y2,s. Y1 ⪤*[R, ⋆s] Y2 →
  57                      ∨∨ Y1 = ⋆ ∧ Y2 = ⋆
  58                       | ∃∃I1,I2,L1,L2. L1 ⪤*[R, ⋆s] L2 &
  59                                        Y1 = L1.ⓘ{I1} & Y2 = L2.ⓘ{I2}.
  60 #R * [ | #Y1 #I1 ] #Y2 #s * #f #H1 #H2
  61 [ lapply (lexs_inv_atom1 … H2) -H2 /3 width=1 by or_introl, conj/
  62 | lapply (frees_inv_sort … H1) -H1 #Hf
  63   elim (isid_inv_gen … Hf) -Hf #g #Hg #H destruct
  64   elim (lexs_inv_push1 … H2) -H2 #I2 #L2 #H12 #_ #H destruct
  65   /5 width=7 by frees_sort, ex3_4_intro, ex2_intro, or_intror/
  66 ]
  67 qed-.
  68
  69 lemma lfxs_inv_zero: ∀R,Y1,Y2. Y1 ⪤*[R, #0] Y2 →
  70                      ∨∨ Y1 = ⋆ ∧ Y2 = ⋆
  71                       | ∃∃I,L1,L2,V1,V2. L1 ⪤*[R, V1] L2 & R L1 V1 V2 &
  72                                          Y1 = L1.ⓑ{I}V1 & Y2 = L2.ⓑ{I}V2
  73                       | ∃∃f,I,L1,L2. 𝐈⦃f⦄ & L1 ⪤*[cext2 R, cfull, f] L2 &
  74                                      Y1 = L1.ⓤ{I} & Y2 = L2.ⓤ{I}.
  75 #R * [ | #Y1 * #I1 [ | #X ] ] #Y2 * #f #H1 #H2
  76 [ lapply (lexs_inv_atom1 … H2) -H2 /3 width=1 by or3_intro0, conj/
  77 | elim (frees_inv_unit … H1) -H1 #g #HX #H destruct
  78   elim (lexs_inv_next1 … H2) -H2 #I2 #L2 #HL12 #H #H2 destruct
  79   >(ext2_inv_unit_sn … H) -H /3 width=8 by or3_intro2, ex4_4_intro/
  80 | elim (frees_inv_pair … H1) -H1 #g #Hg #H destruct
  81   elim (lexs_inv_next1 … H2) -H2 #Z2 #L2 #HL12 #H
  82   elim (ext2_inv_pair_sn … H) -H
  83   /4 width=9 by or3_intro1, ex4_5_intro, ex2_intro/
  84 ]
  85 qed-.
  86
  87 lemma lfxs_inv_lref: ∀R,Y1,Y2,i. Y1 ⪤*[R, #⫯i] Y2 →
  88                      ∨∨ Y1 = ⋆ ∧ Y2 = ⋆
  89                       | ∃∃I1,I2,L1,L2. L1 ⪤*[R, #i] L2 &
  90                                        Y1 = L1.ⓘ{I1} & Y2 = L2.ⓘ{I2}.
  91 #R * [ | #Y1 #I1 ] #Y2 #i * #f #H1 #H2
  92 [ lapply (lexs_inv_atom1 … H2) -H2 /3 width=1 by or_introl, conj/
  93 | elim (frees_inv_lref … H1) -H1 #g #Hg #H destruct
  94   elim (lexs_inv_push1 … H2) -H2
  95   /4 width=7 by ex3_4_intro, ex2_intro, or_intror/
  96 ]
  97 qed-.
  98
  99 lemma lfxs_inv_gref: ∀R,Y1,Y2,l. Y1 ⪤*[R, §l] Y2 →
 100                      ∨∨ Y1 = ⋆ ∧ Y2 = ⋆
 101                       | ∃∃I1,I2,L1,L2. L1 ⪤*[R, §l] L2 &
 102                                        Y1 = L1.ⓘ{I1} & Y2 = L2.ⓘ{I2}.
 103 #R * [ | #Y1 #I1 ] #Y2 #l * #f #H1 #H2
 104 [ lapply (lexs_inv_atom1 … H2) -H2 /3 width=1 by or_introl, conj/
 105 | lapply (frees_inv_gref … H1) -H1 #Hf
 106   elim (isid_inv_gen … Hf) -Hf #g #Hg #H destruct
 107   elim (lexs_inv_push1 … H2) -H2 #I2 #L2 #H12 #_ #H destruct
 108   /5 width=7 by frees_gref, ex3_4_intro, ex2_intro, or_intror/
 109 ]
 110 qed-.
 111
 112 (* Basic_2A1: uses: llpx_sn_inv_bind llpx_sn_inv_bind_O *)
 113 lemma lfxs_inv_bind: ∀R,p,I,L1,L2,V1,V2,T. L1 ⪤*[R, ⓑ{p,I}V1.T] L2 → R L1 V1 V2 →
 114                      L1 ⪤*[R, V1] L2 ∧ L1.ⓑ{I}V1 ⪤*[R, T] L2.ⓑ{I}V2.
 115 #R #p #I #L1 #L2 #V1 #V2 #T * #f #Hf #HL #HV elim (frees_inv_bind … Hf) -Hf
 116 /6 width=6 by sle_lexs_trans, lexs_inv_tl, ext2_pair, sor_inv_sle_dx, sor_inv_sle_sn, ex2_intro, conj/
 117 qed-.
 118
 119 (* Basic_2A1: uses: llpx_sn_inv_flat *)
 120 lemma lfxs_inv_flat: ∀R,I,L1,L2,V,T. L1 ⪤*[R, ⓕ{I}V.T] L2 →
 121                      L1 ⪤*[R, V] L2 ∧ L1 ⪤*[R, T] L2.
 122 #R #I #L1 #L2 #V #T * #f #Hf #HL elim (frees_inv_flat … Hf) -Hf
 123 /5 width=6 by sle_lexs_trans, sor_inv_sle_dx, sor_inv_sle_sn, ex2_intro, conj/
 124 qed-.
 125
 126 (* Advanced inversion lemmas ************************************************)
 127
 128 lemma lfxs_inv_sort_bind_sn: ∀R,I1,K1,L2,s. K1.ⓘ{I1} ⪤*[R, ⋆s] L2 →
 129                              ∃∃I2,K2. K1 ⪤*[R, ⋆s] K2 & L2 = K2.ⓘ{I2}.
 130 #R #I1 #K1 #L2 #s #H elim (lfxs_inv_sort … H) -H *
 131 [ #H destruct
 132 | #Z1 #I2 #Y1 #K2 #Hs #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 133 ]
 134 qed-.
 135
 136 lemma lfxs_inv_sort_bind_dx: ∀R,I2,K2,L1,s. L1 ⪤*[R, ⋆s] K2.ⓘ{I2} →
 137                              ∃∃I1,K1. K1 ⪤*[R, ⋆s] K2 & L1 = K1.ⓘ{I1}.
 138 #R #I2 #K2 #L1 #s #H elim (lfxs_inv_sort … H) -H *
 139 [ #_ #H destruct
 140 | #I1 #Z2 #K1 #Y2 #Hs #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 141 ]
 142 qed-.
 143
 144 lemma lfxs_inv_zero_pair_sn: ∀R,I,L2,K1,V1. K1.ⓑ{I}V1 ⪤*[R, #0] L2 →
 145                              ∃∃K2,V2. K1 ⪤*[R, V1] K2 & R K1 V1 V2 &
 146                                       L2 = K2.ⓑ{I}V2.
 147 #R #I #L2 #K1 #V1 #H elim (lfxs_inv_zero … H) -H *
 148 [ #H destruct
 149 | #Z #Y1 #K2 #X1 #V2 #HK12 #HV12 #H1 #H2 destruct
 150   /2 width=5 by ex3_2_intro/
 151 | #f #Z #Y1 #Y2 #_ #_ #H destruct
 152 ]
 153 qed-.
 154
 155 lemma lfxs_inv_zero_pair_dx: ∀R,I,L1,K2,V2. L1 ⪤*[R, #0] K2.ⓑ{I}V2 →
 156                              ∃∃K1,V1. K1 ⪤*[R, V1] K2 & R K1 V1 V2 &
 157                                       L1 = K1.ⓑ{I}V1.
 158 #R #I #L1 #K2 #V2 #H elim (lfxs_inv_zero … H) -H *
 159 [ #_ #H destruct
 160 | #Z #K1 #Y2 #V1 #X2 #HK12 #HV12 #H1 #H2 destruct
 161   /2 width=5 by ex3_2_intro/
 162 | #f #Z #Y1 #Y2 #_ #_ #_ #H destruct
 163 ]
 164 qed-.
 165
 166 lemma lfxs_inv_zero_unit_sn: ∀R,I,K1,L2. K1.ⓤ{I} ⪤*[R, #0] L2 →
 167                              ∃∃f,K2. 𝐈⦃f⦄ & K1 ⪤*[cext2 R, cfull, f] K2 &
 168                                      L2 = K2.ⓤ{I}.
 169 #R #I #K1 #L2 #H elim (lfxs_inv_zero … H) -H *
 170 [ #H destruct
 171 | #Z #Y1 #Y2 #X1 #X2 #_ #_ #H destruct
 172 | #f #Z #Y1 #K2 #Hf #HK12 #H1 #H2 destruct /2 width=5 by ex3_2_intro/
 173 ]
 174 qed-.
 175
 176 lemma lfxs_inv_zero_unit_dx: ∀R,I,L1,K2. L1 ⪤*[R, #0] K2.ⓤ{I} →
 177                              ∃∃f,K1. 𝐈⦃f⦄ & K1 ⪤*[cext2 R, cfull, f] K2 &
 178                                      L1 = K1.ⓤ{I}.
 179 #R #I #L1 #K2 #H elim (lfxs_inv_zero … H) -H *
 180 [ #_ #H destruct
 181 | #Z #Y1 #Y2 #X1 #X2 #_ #_ #_ #H destruct
 182 | #f #Z #K1 #Y2 #Hf #HK12 #H1 #H2 destruct /2 width=5 by ex3_2_intro/
 183 ]
 184 qed-.
 185
 186 lemma lfxs_inv_lref_bind_sn: ∀R,I1,K1,L2,i. K1.ⓘ{I1} ⪤*[R, #⫯i] L2 →
 187                              ∃∃I2,K2. K1 ⪤*[R, #i] K2 & L2 = K2.ⓘ{I2}.
 188 #R #I1 #K1 #L2 #i #H elim (lfxs_inv_lref … H) -H *
 189 [ #H destruct
 190 | #Z1 #I2 #Y1 #K2 #Hi #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 191 ]
 192 qed-.
 193
 194 lemma lfxs_inv_lref_bind_dx: ∀R,I2,K2,L1,i. L1 ⪤*[R, #⫯i] K2.ⓘ{I2} →
 195                              ∃∃I1,K1. K1 ⪤*[R, #i] K2 & L1 = K1.ⓘ{I1}.
 196 #R #I2 #K2 #L1 #i #H elim (lfxs_inv_lref … H) -H *
 197 [ #_ #H destruct
 198 | #I1 #Z2 #K1 #Y2 #Hi #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 199 ]
 200 qed-.
 201
 202 lemma lfxs_inv_gref_bind_sn: ∀R,I1,K1,L2,l. K1.ⓘ{I1} ⪤*[R, §l] L2 →
 203                              ∃∃I2,K2. K1 ⪤*[R, §l] K2 & L2 = K2.ⓘ{I2}.
 204 #R #I1 #K1 #L2 #l #H elim (lfxs_inv_gref … H) -H *
 205 [ #H destruct
 206 | #Z1 #I2 #Y1 #K2 #Hl #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 207 ]
 208 qed-.
 209
 210 lemma lfxs_inv_gref_bind_dx: ∀R,I2,K2,L1,l. L1 ⪤*[R, §l] K2.ⓘ{I2} →
 211                              ∃∃I1,K1. K1 ⪤*[R, §l] K2 & L1 = K1.ⓘ{I1}.
 212 #R #I2 #K2 #L1 #l #H elim (lfxs_inv_gref … H) -H *
 213 [ #_ #H destruct
 214 | #I1 #Z2 #K1 #Y2 #Hl #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 215 ]
 216 qed-.
 217
 218 (* Basic forward lemmas *****************************************************)
 219
 220 lemma lfxs_fwd_zero_pair: ∀R,I,K1,K2,V1,V2.
 221                           K1.ⓑ{I}V1 ⪤*[R, #0] K2.ⓑ{I}V2 → K1 ⪤*[R, V1] K2.
 222 #R #I #K1 #K2 #V1 #V2 #H
 223 elim (lfxs_inv_zero_pair_sn … H) -H #Y #X #HK12 #_ #H destruct //
 224 qed-.
 225
 226 (* Basic_2A1: uses: llpx_sn_fwd_pair_sn llpx_sn_fwd_bind_sn llpx_sn_fwd_flat_sn *)
 227 lemma lfxs_fwd_pair_sn: ∀R,I,L1,L2,V,T. L1 ⪤*[R, ②{I}V.T] L2 → L1 ⪤*[R, V] L2.
 228 #R * [ #p ] #I #L1 #L2 #V #T * #f #Hf #HL
 229 [ elim (frees_inv_bind … Hf) | elim (frees_inv_flat … Hf) ] -Hf
 230 /4 width=6 by sle_lexs_trans, sor_inv_sle_sn, ex2_intro/
 231 qed-.
 232
 233 (* Basic_2A1: uses: llpx_sn_fwd_bind_dx llpx_sn_fwd_bind_O_dx *)
 234 lemma lfxs_fwd_bind_dx: ∀R,p,I,L1,L2,V1,V2,T. L1 ⪤*[R, ⓑ{p,I}V1.T] L2 →
 235                         R L1 V1 V2 → L1.ⓑ{I}V1 ⪤*[R, T] L2.ⓑ{I}V2.
 236 #R #p #I #L1 #L2 #V1 #V2 #T #H #HV elim (lfxs_inv_bind … H HV) -H -HV //
 237 qed-.
 238
 239 (* Basic_2A1: uses: llpx_sn_fwd_flat_dx *)
 240 lemma lfxs_fwd_flat_dx: ∀R,I,L1,L2,V,T. L1 ⪤*[R, ⓕ{I}V.T] L2 → L1 ⪤*[R, T] L2.
 241 #R #I #L1 #L2 #V #T #H elim (lfxs_inv_flat … H) -H //
 242 qed-.
 243
 244 lemma lfxs_fwd_dx: ∀R,I2,L1,K2,T. L1 ⪤*[R, T] K2.ⓘ{I2} →
 245                    ∃∃I1,K1. L1 = K1.ⓘ{I1}.
 246 #R #I2 #L1 #K2 #T * #f elim (pn_split f) * #g #Hg #_ #Hf destruct
 247 [ elim (lexs_inv_push2 … Hf) | elim (lexs_inv_next2 … Hf) ] -Hf #I1 #K1 #_ #_ #H destruct
 248 /2 width=3 by ex1_2_intro/
 249 qed-.
 250
 251 (* Basic properties *********************************************************)
 252
 253 lemma lfxs_atom: ∀R,I. ⋆ ⪤*[R, ⓪{I}] ⋆.
 254 #R * /3 width=3 by frees_sort, frees_atom, frees_gref, lexs_atom, ex2_intro/
 255 qed.
 256
 257 (* Basic_2A1: uses: llpx_sn_sort *)
 258 lemma lfxs_sort: ∀R,I1,I2,L1,L2,s.
 259                  L1 ⪤*[R, ⋆s] L2 → L1.ⓘ{I1} ⪤*[R, ⋆s] L2.ⓘ{I2}.
 260 #R #I1 #I2 #L1 #L2 #s * #f #Hf #H12
 261 lapply (frees_inv_sort … Hf) -Hf
 262 /4 width=3 by frees_sort, lexs_push, isid_push, ex2_intro/
 263 qed.
 264
 265 lemma lfxs_pair: ∀R,I,L1,L2,V1,V2. L1 ⪤*[R, V1] L2 →
 266                  R L1 V1 V2 → L1.ⓑ{I}V1 ⪤*[R, #0] L2.ⓑ{I}V2.
 267 #R #I1 #I2 #L1 #L2 #V1 *
 268 /4 width=3 by ext2_pair, frees_pair, lexs_next, ex2_intro/
 269 qed.
 270
 271 lemma lfxs_unit: ∀R,f,I,L1,L2. 𝐈⦃f⦄ → L1 ⪤*[cext2 R, cfull, f] L2 →
 272                  L1.ⓤ{I} ⪤*[R, #0] L2.ⓤ{I}.
 273 /4 width=3 by frees_unit, lexs_next, ext2_unit, ex2_intro/ qed.
 274
 275 lemma lfxs_lref: ∀R,I1,I2,L1,L2,i.
 276                  L1 ⪤*[R, #i] L2 → L1.ⓘ{I1} ⪤*[R, #⫯i] L2.ⓘ{I2}.
 277 #R #I1 #I2 #L1 #L2 #i * /3 width=3 by lexs_push, frees_lref, ex2_intro/
 278 qed.
 279
 280 (* Basic_2A1: uses: llpx_sn_gref *)
 281 lemma lfxs_gref: ∀R,I1,I2,L1,L2,l.
 282                  L1 ⪤*[R, §l] L2 → L1.ⓘ{I1} ⪤*[R, §l] L2.ⓘ{I2}.
 283 #R #I1 #I2 #L1 #L2 #l * #f #Hf #H12
 284 lapply (frees_inv_gref … Hf) -Hf
 285 /4 width=3 by frees_gref, lexs_push, isid_push, ex2_intro/
 286 qed.
 287
 288 lemma lfxs_bind_repl_dx: ∀R,I,I1,L1,L2,T.
 289                          L1.ⓘ{I} ⪤*[R, T] L2.ⓘ{I1} →
 290                          ∀I2. cext2 R L1 I I2 →
 291                          L1.ⓘ{I} ⪤*[R, T] L2.ⓘ{I2}.
 292 #R #I #I1 #L1 #L2 #T * #f #Hf #HL12 #I2 #HR
 293 /3 width=5 by lexs_pair_repl, ex2_intro/
 294 qed-.
 295
 296 (* Basic_2A1: uses: llpx_sn_co *)
 297 lemma lfxs_co: ∀R1,R2. (∀L,T1,T2. R1 L T1 T2 → R2 L T1 T2) →
 298                ∀L1,L2,T. L1 ⪤*[R1, T] L2 → L1 ⪤*[R2, T] L2.
 299 #R1 #R2 #HR #L1 #L2 #T * /5 width=7 by lexs_co, cext2_co, ex2_intro/
 300 qed-.
 301
 302 lemma lfxs_isid: ∀R1,R2,L1,L2,T1,T2.
 303                  (∀f. L1 ⊢ 𝐅*⦃T1⦄ ≡ f → 𝐈⦃f⦄) →
 304                  (∀f. 𝐈⦃f⦄ → L1 ⊢ 𝐅*⦃T2⦄ ≡ f) →
 305                  L1 ⪤*[R1, T1] L2 → L1 ⪤*[R2, T2] L2.
 306 #R1 #R2 #L1 #L2 #T1 #T2 #H1 #H2 *
 307 /4 width=7 by lexs_co_isid, ex2_intro/
 308 qed-.
 309
 310 lemma lfxs_unit_sn: ∀R1,R2,I,K1,L2.
 311                     K1.ⓤ{I} ⪤*[R1, #0] L2 → K1.ⓤ{I} ⪤*[R2, #0] L2.
 312 #R1 #R2 #I #K1 #L2 #H
 313 elim (lfxs_inv_zero_unit_sn … H) -H #f #K2 #Hf #HK12 #H destruct
 314 /3 width=7 by lfxs_unit, lexs_co_isid/
 315 qed-.
 316
 317 (* Basic_2A1: removed theorems 9:
 318               llpx_sn_skip llpx_sn_lref llpx_sn_free
 319               llpx_sn_fwd_lref
 320               llpx_sn_Y llpx_sn_ge_up llpx_sn_ge
 321               llpx_sn_fwd_drop_sn llpx_sn_fwd_drop_dx
 322 *)