matita/matita/contribs/lambdadelta/basic_2/static/lfxs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/relocation/rtmap_id.ma".
  16 include "basic_2/notation/relations/relationstar_4.ma".
  17 include "basic_2/grammar/ceq.ma".
  18 include "basic_2/relocation/lexs.ma".
  19 include "basic_2/static/frees.ma".
  20
  21 (* GENERIC EXTENSION ON REFERRED ENTRIES OF A CONTEXT-SENSITIVE REALTION ****)
  22
  23 definition lfxs (R) (T): relation lenv ≝
  24                 λL1,L2. ∃∃f. L1 ⊢ 𝐅*⦃T⦄ ≡ f & L1 ⦻*[R, cfull, f] L2.
  25
  26 interpretation "generic extension on referred entries (local environment)"
  27    'RelationStar R T L1 L2 = (lfxs R T L1 L2).
  28
  29 definition R_confluent2_lfxs: relation4 (relation3 lenv term term)
  30                                         (relation3 lenv term term) … ≝
  31                               λR1,R2,RP1,RP2.
  32                               ∀L0,T0,T1. R1 L0 T0 T1 → ∀T2. R2 L0 T0 T2 →
  33                               ∀L1. L0 ⦻*[RP1, T0] L1 → ∀L2. L0 ⦻*[RP2, T0] L2 →
  34                               ∃∃T. R2 L1 T1 T & R1 L2 T2 T.
  35
  36 (* Basic properties ***********************************************************)
  37
  38 lemma lfxs_atom: ∀R,I. ⋆ ⦻*[R, ⓪{I}] ⋆.
  39 /3 width=3 by lexs_atom, frees_atom, ex2_intro/
  40 qed.
  41
  42 lemma lfxs_sort: ∀R,I,L1,L2,V1,V2,s.
  43                  L1 ⦻*[R, ⋆s] L2 → L1.ⓑ{I}V1 ⦻*[R, ⋆s] L2.ⓑ{I}V2.
  44 #R #I #L1 #L2 #V1 #V2 #s * /3 width=3 by lexs_push, frees_sort, ex2_intro/
  45 qed.
  46
  47 lemma lfxs_zero: ∀R,I,L1,L2,V1,V2. L1 ⦻*[R, V1] L2 →
  48                  R L1 V1 V2 → L1.ⓑ{I}V1 ⦻*[R, #0] L2.ⓑ{I}V2.
  49 #R #I #L1 #L2 #V1 #V2 * /3 width=3 by lexs_next, frees_zero, ex2_intro/
  50 qed.
  51
  52 lemma lfxs_lref: ∀R,I,L1,L2,V1,V2,i.
  53                  L1 ⦻*[R, #i] L2 → L1.ⓑ{I}V1 ⦻*[R, #⫯i] L2.ⓑ{I}V2.
  54 #R #I #L1 #L2 #V1 #V2 #i * /3 width=3 by lexs_push, frees_lref, ex2_intro/
  55 qed.
  56
  57 lemma lfxs_gref: ∀R,I,L1,L2,V1,V2,l.
  58                  L1 ⦻*[R, §l] L2 → L1.ⓑ{I}V1 ⦻*[R, §l] L2.ⓑ{I}V2.
  59 #R #I #L1 #L2 #V1 #V2 #l * /3 width=3 by lexs_push, frees_gref, ex2_intro/
  60 qed.
  61
  62 lemma lfxs_pair_repl_dx: ∀R,I,L1,L2,T,V,V1.
  63                          L1.ⓑ{I}V ⦻*[R, T] L2.ⓑ{I}V1 →
  64                          ∀V2. R L1 V V2 →
  65                          L1.ⓑ{I}V ⦻*[R, T] L2.ⓑ{I}V2.
  66 #R #I #L1 #L2 #T #V #V1 * #f #Hf #HL12 #V2 #HR
  67 /3 width=5 by lexs_pair_repl, ex2_intro/
  68 qed-.
  69
  70 lemma lfxs_co: ∀R1,R2. (∀L,T1,T2. R1 L T1 T2 → R2 L T1 T2) →
  71                ∀L1,L2,T. L1 ⦻*[R1, T] L2 → L1 ⦻*[R2, T] L2.
  72 #R1 #R2 #HR #L1 #L2 #T * /4 width=7 by lexs_co, ex2_intro/
  73 qed-.
  74
  75 (* Basic inversion lemmas ***************************************************)
  76
  77 lemma lfxs_inv_atom_sn: ∀R,I,Y2. ⋆ ⦻*[R, ⓪{I}] Y2 → Y2 = ⋆.
  78 #R #I #Y2 * /2 width=4 by lexs_inv_atom1/
  79 qed-.
  80
  81 lemma lfxs_inv_atom_dx: ∀R,I,Y1. Y1 ⦻*[R, ⓪{I}] ⋆ → Y1 = ⋆.
  82 #R #I #Y1 * /2 width=4 by lexs_inv_atom2/
  83 qed-.
  84
  85 lemma lfxs_inv_sort: ∀R,Y1,Y2,s. Y1 ⦻*[R, ⋆s] Y2 →
  86                      (Y1 = ⋆ ∧ Y2 = ⋆) ∨
  87                      ∃∃I,L1,L2,V1,V2. L1 ⦻*[R, ⋆s] L2 &
  88                                       Y1 = L1.ⓑ{I}V1 & Y2 = L2.ⓑ{I}V2.
  89 #R * [ | #Y1 #I #V1 ] #Y2 #s * #f #H1 #H2
  90 [ lapply (lexs_inv_atom1 … H2) -H2 /3 width=1 by or_introl, conj/
  91 | lapply (frees_inv_sort … H1) -H1 #Hf
  92   elim (isid_inv_gen … Hf) -Hf #g #Hg #H destruct
  93   elim (lexs_inv_push1 … H2) -H2 #L2 #V2 #H12 #_ #H destruct
  94   /5 width=8 by frees_sort_gen, ex3_5_intro, ex2_intro, or_intror/
  95 ]
  96 qed-.
  97
  98 lemma lfxs_inv_zero: ∀R,Y1,Y2. Y1 ⦻*[R, #0] Y2 →
  99                      (Y1 = ⋆ ∧ Y2 = ⋆) ∨
 100                      ∃∃I,L1,L2,V1,V2. L1 ⦻*[R, V1] L2 & R L1 V1 V2 &
 101                                       Y1 = L1.ⓑ{I}V1 & Y2 = L2.ⓑ{I}V2.
 102 #R #Y1 #Y2 * #f #H1 #H2 elim (frees_inv_zero … H1) -H1 *
 103 [ #H #_ lapply (lexs_inv_atom1_aux … H2 H) -H2 /3 width=1 by or_introl, conj/
 104 | #I1 #L1 #V1 #g #HV1 #HY1 #Hg elim (lexs_inv_next1_aux … H2 … HY1 Hg) -H2 -Hg
 105   /4 width=9 by ex4_5_intro, ex2_intro, or_intror/
 106 ]
 107 qed-.
 108
 109 lemma lfxs_inv_lref: ∀R,Y1,Y2,i. Y1 ⦻*[R, #⫯i] Y2 →
 110                      (Y1 = ⋆ ∧ Y2 = ⋆) ∨
 111                      ∃∃I,L1,L2,V1,V2. L1 ⦻*[R, #i] L2 &
 112                                       Y1 = L1.ⓑ{I}V1 & Y2 = L2.ⓑ{I}V2.
 113 #R #Y1 #Y2 #i * #f #H1 #H2 elim (frees_inv_lref … H1) -H1 *
 114 [ #H #_ lapply (lexs_inv_atom1_aux … H2 H) -H2 /3 width=1 by or_introl, conj/
 115 | #I1 #L1 #V1 #g #HV1 #HY1 #Hg elim (lexs_inv_push1_aux … H2 … HY1 Hg) -H2 -Hg
 116   /4 width=8 by ex3_5_intro, ex2_intro, or_intror/
 117 ]
 118 qed-.
 119
 120 lemma lfxs_inv_gref: ∀R,Y1,Y2,l. Y1 ⦻*[R, §l] Y2 →
 121                      (Y1 = ⋆ ∧ Y2 = ⋆) ∨
 122                      ∃∃I,L1,L2,V1,V2. L1 ⦻*[R, §l] L2 &
 123                                       Y1 = L1.ⓑ{I}V1 & Y2 = L2.ⓑ{I}V2.
 124 #R * [ | #Y1 #I #V1 ] #Y2 #l * #f #H1 #H2
 125 [ lapply (lexs_inv_atom1 … H2) -H2 /3 width=1 by or_introl, conj/
 126 | lapply (frees_inv_gref … H1) -H1 #Hf
 127   elim (isid_inv_gen … Hf) -Hf #g #Hg #H destruct
 128   elim (lexs_inv_push1 … H2) -H2 #L2 #V2 #H12 #_ #H destruct
 129   /5 width=8 by frees_gref_gen, ex3_5_intro, ex2_intro, or_intror/
 130 ]
 131 qed-.
 132
 133 lemma lfxs_inv_bind: ∀R,p,I,L1,L2,V1,V2,T. L1 ⦻*[R, ⓑ{p,I}V1.T] L2 → R L1 V1 V2 →
 134                      L1 ⦻*[R, V1] L2 ∧ L1.ⓑ{I}V1 ⦻*[R, T] L2.ⓑ{I}V2.
 135 #R #p #I #L1 #L2 #V1 #V2 #T * #f #Hf #HL #HV elim (frees_inv_bind … Hf) -Hf
 136 /6 width=6 by sle_lexs_trans, lexs_inv_tl, sor_inv_sle_dx, sor_inv_sle_sn, ex2_intro, conj/
 137 qed-.
 138
 139 lemma lfxs_inv_flat: ∀R,I,L1,L2,V,T. L1 ⦻*[R, ⓕ{I}V.T] L2 →
 140                      L1 ⦻*[R, V] L2 ∧ L1 ⦻*[R, T] L2.
 141 #R #I #L1 #L2 #V #T * #f #Hf #HL elim (frees_inv_flat … Hf) -Hf
 142 /5 width=6 by sle_lexs_trans, sor_inv_sle_dx, sor_inv_sle_sn, ex2_intro, conj/
 143 qed-.
 144
 145 (* Advanced inversion lemmas ************************************************)
 146
 147 lemma lfxs_inv_sort_pair_sn: ∀R,I,Y2,L1,V1,s. L1.ⓑ{I}V1 ⦻*[R, ⋆s] Y2 →
 148                              ∃∃L2,V2. L1 ⦻*[R, ⋆s] L2 & Y2 = L2.ⓑ{I}V2.
 149 #R #I #Y2 #L1 #V1 #s #H elim (lfxs_inv_sort … H) -H *
 150 [ #H destruct
 151 | #J #Y1 #L2 #X1 #V2 #Hs #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 152 ]
 153 qed-.
 154
 155 lemma lfxs_inv_sort_pair_dx: ∀R,I,Y1,L2,V2,s. Y1 ⦻*[R, ⋆s] L2.ⓑ{I}V2 →
 156                              ∃∃L1,V1. L1 ⦻*[R, ⋆s] L2 & Y1 = L1.ⓑ{I}V1.
 157 #R #I #Y1 #L2 #V2 #s #H elim (lfxs_inv_sort … H) -H *
 158 [ #_ #H destruct
 159 | #J #L1 #Y2 #V1 #X2 #Hs #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 160 ]
 161 qed-.
 162
 163 lemma lfxs_inv_zero_pair_sn: ∀R,I,Y2,L1,V1. L1.ⓑ{I}V1 ⦻*[R, #0] Y2 →
 164                              ∃∃L2,V2. L1 ⦻*[R, V1] L2 & R L1 V1 V2 &
 165                                       Y2 = L2.ⓑ{I}V2.
 166 #R #I #Y2 #L1 #V1 #H elim (lfxs_inv_zero … H) -H *
 167 [ #H destruct
 168 | #J #Y1 #L2 #X1 #V2 #HV1 #HV12 #H1 #H2 destruct
 169   /2 width=5 by ex3_2_intro/
 170 ]
 171 qed-.
 172
 173 lemma lfxs_inv_zero_pair_dx: ∀R,I,Y1,L2,V2. Y1 ⦻*[R, #0] L2.ⓑ{I}V2 →
 174                              ∃∃L1,V1. L1 ⦻*[R, V1] L2 & R L1 V1 V2 &
 175                                       Y1 = L1.ⓑ{I}V1.
 176 #R #I #Y1 #L2 #V2 #H elim (lfxs_inv_zero … H) -H *
 177 [ #_ #H destruct
 178 | #J #L1 #Y2 #V1 #X2 #HV1 #HV12 #H1 #H2 destruct
 179   /2 width=5 by ex3_2_intro/
 180 ]
 181 qed-.
 182
 183 lemma lfxs_inv_lref_pair_sn: ∀R,I,Y2,L1,V1,i. L1.ⓑ{I}V1 ⦻*[R, #⫯i] Y2 →
 184                              ∃∃L2,V2. L1 ⦻*[R, #i] L2 & Y2 = L2.ⓑ{I}V2.
 185 #R #I #Y2 #L1 #V1 #i #H elim (lfxs_inv_lref … H) -H *
 186 [ #H destruct
 187 | #J #Y1 #L2 #X1 #V2 #Hi #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 188 ]
 189 qed-.
 190
 191 lemma lfxs_inv_lref_pair_dx: ∀R,I,Y1,L2,V2,i. Y1 ⦻*[R, #⫯i] L2.ⓑ{I}V2 →
 192                              ∃∃L1,V1. L1 ⦻*[R, #i] L2 & Y1 = L1.ⓑ{I}V1.
 193 #R #I #Y1 #L2 #V2 #i #H elim (lfxs_inv_lref … H) -H *
 194 [ #_ #H destruct
 195 | #J #L1 #Y2 #V1 #X2 #Hi #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 196 ]
 197 qed-.
 198
 199 lemma lfxs_inv_gref_pair_sn: ∀R,I,Y2,L1,V1,l. L1.ⓑ{I}V1 ⦻*[R, §l] Y2 →
 200                              ∃∃L2,V2. L1 ⦻*[R, §l] L2 & Y2 = L2.ⓑ{I}V2.
 201 #R #I #Y2 #L1 #V1 #l #H elim (lfxs_inv_gref … H) -H *
 202 [ #H destruct
 203 | #J #Y1 #L2 #X1 #V2 #Hl #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 204 ]
 205 qed-.
 206
 207 lemma lfxs_inv_gref_pair_dx: ∀R,I,Y1,L2,V2,l. Y1 ⦻*[R, §l] L2.ⓑ{I}V2 →
 208                              ∃∃L1,V1. L1 ⦻*[R, §l] L2 & Y1 = L1.ⓑ{I}V1.
 209 #R #I #Y1 #L2 #V2 #l #H elim (lfxs_inv_gref … H) -H *
 210 [ #_ #H destruct
 211 | #J #L1 #Y2 #V1 #X2 #Hl #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 212 ]
 213 qed-.
 214
 215 (* Basic forward lemmas *****************************************************)
 216
 217 lemma lfxs_fwd_bind_sn: ∀R,p,I,L1,L2,V,T. L1 ⦻*[R, ⓑ{p,I}V.T] L2 → L1 ⦻*[R, V] L2.
 218 #R #p #I #L1 #L2 #V #T * #f #Hf #HL elim (frees_inv_bind … Hf) -Hf
 219 /4 width=6 by sle_lexs_trans, sor_inv_sle_sn, ex2_intro/
 220 qed-.
 221
 222 lemma lfxs_fwd_bind_dx: ∀R,p,I,L1,L2,V1,V2,T. L1 ⦻*[R, ⓑ{p,I}V1.T] L2 →
 223                         R L1 V1 V2 → L1.ⓑ{I}V1 ⦻*[R, T] L2.ⓑ{I}V2.
 224 #R #p #I #L1 #L2 #V1 #V2 #T #H #HV elim (lfxs_inv_bind … H HV) -H -HV //
 225 qed-.
 226
 227 lemma lfxs_fwd_flat_sn: ∀R,I,L1,L2,V,T. L1 ⦻*[R, ⓕ{I}V.T] L2 → L1 ⦻*[R, V] L2.
 228 #R #I #L1 #L2 #V #T #H elim (lfxs_inv_flat … H) -H //
 229 qed-.
 230
 231 lemma lfxs_fwd_flat_dx: ∀R,I,L1,L2,V,T. L1 ⦻*[R, ⓕ{I}V.T] L2 → L1 ⦻*[R, T] L2.
 232 #R #I #L1 #L2 #V #T #H elim (lfxs_inv_flat … H) -H //
 233 qed-.
 234
 235 lemma lfxs_fwd_pair_sn: ∀R,I,L1,L2,V,T. L1 ⦻*[R, ②{I}V.T] L2 → L1 ⦻*[R, V] L2.
 236 #R * /2 width=4 by lfxs_fwd_flat_sn, lfxs_fwd_bind_sn/
 237 qed-.
 238
 239 (* Basic_2A1: removed theorems 24:
 240               llpx_sn_sort llpx_sn_skip llpx_sn_lref llpx_sn_free llpx_sn_gref
 241               llpx_sn_bind llpx_sn_flat
 242               llpx_sn_inv_bind llpx_sn_inv_flat
 243               llpx_sn_fwd_lref llpx_sn_fwd_pair_sn llpx_sn_fwd_length
 244               llpx_sn_fwd_bind_sn llpx_sn_fwd_bind_dx llpx_sn_fwd_flat_sn llpx_sn_fwd_flat_dx
 245               llpx_sn_refl llpx_sn_Y llpx_sn_bind_O llpx_sn_ge_up llpx_sn_ge llpx_sn_co
 246               llpx_sn_fwd_drop_sn llpx_sn_fwd_drop_dx
 247 *)