matita/matita/contribs/lambdadelta/basic_2/static/lfxs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/relocation/rtmap_id.ma".
  16 include "basic_2/notation/relations/relationstar_4.ma".
  17 include "basic_2/relocation/lexs.ma".
  18 include "basic_2/static/frees.ma".
  19
  20 (* GENERIC EXTENSION ON REFERRED ENTRIES OF A CONTEXT-SENSITIVE REALTION ****)
  21
  22 definition lfxs (R) (T): relation lenv ≝
  23                 λL1,L2. ∃∃f. L1 ⊢ 𝐅*⦃T⦄ ≡ f & L1 ⦻*[R, cfull, f] L2.
  24
  25 interpretation "generic extension on referred entries (local environment)"
  26    'RelationStar R T L1 L2 = (lfxs R T L1 L2).
  27
  28 definition R_frees_confluent: predicate (relation3 lenv term term) ≝
  29                               λRN.
  30                               ∀f1,L,T1. L ⊢ 𝐅*⦃T1⦄ ≡ f1 → ∀T2. RN L T1 T2 →
  31                               ∃∃f2. L ⊢ 𝐅*⦃T2⦄ ≡ f2 & f2 ⊆ f1.
  32
  33 definition lexs_frees_confluent: relation (relation3 lenv term term) ≝
  34                                  λRN,RP.
  35                                  ∀f1,L1,T. L1 ⊢ 𝐅*⦃T⦄ ≡ f1 →
  36                                  ∀L2. L1 ⦻*[RN, RP, f1] L2 →
  37                                  ∃∃f2. L2 ⊢ 𝐅*⦃T⦄ ≡ f2 & f2 ⊆ f1.
  38
  39 definition R_confluent2_lfxs: relation4 (relation3 lenv term term)
  40                                         (relation3 lenv term term) … ≝
  41                               λR1,R2,RP1,RP2.
  42                               ∀L0,T0,T1. R1 L0 T0 T1 → ∀T2. R2 L0 T0 T2 →
  43                               ∀L1. L0 ⦻*[RP1, T0] L1 → ∀L2. L0 ⦻*[RP2, T0] L2 →
  44                               ∃∃T. R2 L1 T1 T & R1 L2 T2 T.
  45
  46 (* Basic properties ***********************************************************)
  47
  48 lemma lfxs_atom: ∀R,I. ⋆ ⦻*[R, ⓪{I}] ⋆.
  49 /3 width=3 by lexs_atom, frees_atom, ex2_intro/
  50 qed.
  51
  52 lemma lfxs_sort: ∀R,I,L1,L2,V1,V2,s.
  53                  L1 ⦻*[R, ⋆s] L2 → L1.ⓑ{I}V1 ⦻*[R, ⋆s] L2.ⓑ{I}V2.
  54 #R #I #L1 #L2 #V1 #V2 #s * /3 width=3 by lexs_push, frees_sort, ex2_intro/
  55 qed.
  56
  57 lemma lfxs_zero: ∀R,I,L1,L2,V1,V2. L1 ⦻*[R, V1] L2 →
  58                  R L1 V1 V2 → L1.ⓑ{I}V1 ⦻*[R, #0] L2.ⓑ{I}V2.
  59 #R #I #L1 #L2 #V1 #V2 * /3 width=3 by lexs_next, frees_zero, ex2_intro/
  60 qed.
  61
  62 lemma lfxs_lref: ∀R,I,L1,L2,V1,V2,i.
  63                  L1 ⦻*[R, #i] L2 → L1.ⓑ{I}V1 ⦻*[R, #⫯i] L2.ⓑ{I}V2.
  64 #R #I #L1 #L2 #V1 #V2 #i * /3 width=3 by lexs_push, frees_lref, ex2_intro/
  65 qed.
  66
  67 lemma lfxs_gref: ∀R,I,L1,L2,V1,V2,l.
  68                  L1 ⦻*[R, §l] L2 → L1.ⓑ{I}V1 ⦻*[R, §l] L2.ⓑ{I}V2.
  69 #R #I #L1 #L2 #V1 #V2 #l * /3 width=3 by lexs_push, frees_gref, ex2_intro/
  70 qed.
  71
  72 lemma lfxs_pair_repl_dx: ∀R,I,L1,L2,T,V,V1.
  73                          L1.ⓑ{I}V ⦻*[R, T] L2.ⓑ{I}V1 →
  74                          ∀V2. R L1 V V2 →
  75                          L1.ⓑ{I}V ⦻*[R, T] L2.ⓑ{I}V2.
  76 #R #I #L1 #L2 #T #V #V1 * #f #Hf #HL12 #V2 #HR
  77 /3 width=5 by lexs_pair_repl, ex2_intro/
  78 qed-.
  79
  80 lemma lfxs_co: ∀R1,R2. (∀L,T1,T2. R1 L T1 T2 → R2 L T1 T2) →
  81                ∀L1,L2,T. L1 ⦻*[R1, T] L2 → L1 ⦻*[R2, T] L2.
  82 #R1 #R2 #HR #L1 #L2 #T * /4 width=7 by lexs_co, ex2_intro/
  83 qed-.
  84
  85 (* Basic inversion lemmas ***************************************************)
  86
  87 lemma lfxs_inv_atom_sn: ∀R,I,Y2. ⋆ ⦻*[R, ⓪{I}] Y2 → Y2 = ⋆.
  88 #R #I #Y2 * /2 width=4 by lexs_inv_atom1/
  89 qed-.
  90
  91 lemma lfxs_inv_atom_dx: ∀R,I,Y1. Y1 ⦻*[R, ⓪{I}] ⋆ → Y1 = ⋆.
  92 #R #I #Y1 * /2 width=4 by lexs_inv_atom2/
  93 qed-.
  94
  95 lemma lfxs_inv_sort: ∀R,Y1,Y2,s. Y1 ⦻*[R, ⋆s] Y2 →
  96                      (Y1 = ⋆ ∧ Y2 = ⋆) ∨
  97                      ∃∃I,L1,L2,V1,V2. L1 ⦻*[R, ⋆s] L2 &
  98                                       Y1 = L1.ⓑ{I}V1 & Y2 = L2.ⓑ{I}V2.
  99 #R * [ | #Y1 #I #V1 ] #Y2 #s * #f #H1 #H2
 100 [ lapply (lexs_inv_atom1 … H2) -H2 /3 width=1 by or_introl, conj/
 101 | lapply (frees_inv_sort … H1) -H1 #Hf
 102   elim (isid_inv_gen … Hf) -Hf #g #Hg #H destruct
 103   elim (lexs_inv_push1 … H2) -H2 #L2 #V2 #H12 #_ #H destruct
 104   /5 width=8 by frees_sort_gen, ex3_5_intro, ex2_intro, or_intror/
 105 ]
 106 qed-.
 107
 108 lemma lfxs_inv_zero: ∀R,Y1,Y2. Y1 ⦻*[R, #0] Y2 →
 109                      (Y1 = ⋆ ∧ Y2 = ⋆) ∨
 110                      ∃∃I,L1,L2,V1,V2. L1 ⦻*[R, V1] L2 & R L1 V1 V2 &
 111                                       Y1 = L1.ⓑ{I}V1 & Y2 = L2.ⓑ{I}V2.
 112 #R #Y1 #Y2 * #f #H1 #H2 elim (frees_inv_zero … H1) -H1 *
 113 [ #H #_ lapply (lexs_inv_atom1_aux … H2 H) -H2 /3 width=1 by or_introl, conj/
 114 | #I1 #L1 #V1 #g #HV1 #HY1 #Hg elim (lexs_inv_next1_aux … H2 … HY1 Hg) -H2 -Hg
 115   /4 width=9 by ex4_5_intro, ex2_intro, or_intror/
 116 ]
 117 qed-.
 118
 119 lemma lfxs_inv_lref: ∀R,Y1,Y2,i. Y1 ⦻*[R, #⫯i] Y2 →
 120                      (Y1 = ⋆ ∧ Y2 = ⋆) ∨
 121                      ∃∃I,L1,L2,V1,V2. L1 ⦻*[R, #i] L2 &
 122                                       Y1 = L1.ⓑ{I}V1 & Y2 = L2.ⓑ{I}V2.
 123 #R #Y1 #Y2 #i * #f #H1 #H2 elim (frees_inv_lref … H1) -H1 *
 124 [ #H #_ lapply (lexs_inv_atom1_aux … H2 H) -H2 /3 width=1 by or_introl, conj/
 125 | #I1 #L1 #V1 #g #HV1 #HY1 #Hg elim (lexs_inv_push1_aux … H2 … HY1 Hg) -H2 -Hg
 126   /4 width=8 by ex3_5_intro, ex2_intro, or_intror/
 127 ]
 128 qed-.
 129
 130 lemma lfxs_inv_gref: ∀R,Y1,Y2,l. Y1 ⦻*[R, §l] Y2 →
 131                      (Y1 = ⋆ ∧ Y2 = ⋆) ∨
 132                      ∃∃I,L1,L2,V1,V2. L1 ⦻*[R, §l] L2 &
 133                                       Y1 = L1.ⓑ{I}V1 & Y2 = L2.ⓑ{I}V2.
 134 #R * [ | #Y1 #I #V1 ] #Y2 #l * #f #H1 #H2
 135 [ lapply (lexs_inv_atom1 … H2) -H2 /3 width=1 by or_introl, conj/
 136 | lapply (frees_inv_gref … H1) -H1 #Hf
 137   elim (isid_inv_gen … Hf) -Hf #g #Hg #H destruct
 138   elim (lexs_inv_push1 … H2) -H2 #L2 #V2 #H12 #_ #H destruct
 139   /5 width=8 by frees_gref_gen, ex3_5_intro, ex2_intro, or_intror/
 140 ]
 141 qed-.
 142
 143 lemma lfxs_inv_bind: ∀R,p,I,L1,L2,V1,V2,T. L1 ⦻*[R, ⓑ{p,I}V1.T] L2 → R L1 V1 V2 →
 144                      L1 ⦻*[R, V1] L2 ∧ L1.ⓑ{I}V1 ⦻*[R, T] L2.ⓑ{I}V2.
 145 #R #p #I #L1 #L2 #V1 #V2 #T * #f #Hf #HL #HV elim (frees_inv_bind … Hf) -Hf
 146 /6 width=6 by sle_lexs_trans, lexs_inv_tl, sor_inv_sle_dx, sor_inv_sle_sn, ex2_intro, conj/
 147 qed-.
 148
 149 lemma lfxs_inv_flat: ∀R,I,L1,L2,V,T. L1 ⦻*[R, ⓕ{I}V.T] L2 →
 150                      L1 ⦻*[R, V] L2 ∧ L1 ⦻*[R, T] L2.
 151 #R #I #L1 #L2 #V #T * #f #Hf #HL elim (frees_inv_flat … Hf) -Hf
 152 /5 width=6 by sle_lexs_trans, sor_inv_sle_dx, sor_inv_sle_sn, ex2_intro, conj/
 153 qed-.
 154
 155 (* Advanced inversion lemmas ************************************************)
 156
 157 lemma lfxs_inv_sort_pair_sn: ∀R,I,Y2,L1,V1,s. L1.ⓑ{I}V1 ⦻*[R, ⋆s] Y2 →
 158                              ∃∃L2,V2. L1 ⦻*[R, ⋆s] L2 & Y2 = L2.ⓑ{I}V2.
 159 #R #I #Y2 #L1 #V1 #s #H elim (lfxs_inv_sort … H) -H *
 160 [ #H destruct
 161 | #J #Y1 #L2 #X1 #V2 #Hs #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 162 ]
 163 qed-.
 164
 165 lemma lfxs_inv_sort_pair_dx: ∀R,I,Y1,L2,V2,s. Y1 ⦻*[R, ⋆s] L2.ⓑ{I}V2 →
 166                              ∃∃L1,V1. L1 ⦻*[R, ⋆s] L2 & Y1 = L1.ⓑ{I}V1.
 167 #R #I #Y1 #L2 #V2 #s #H elim (lfxs_inv_sort … H) -H *
 168 [ #_ #H destruct
 169 | #J #L1 #Y2 #V1 #X2 #Hs #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 170 ]
 171 qed-.
 172
 173 lemma lfxs_inv_zero_pair_sn: ∀R,I,Y2,L1,V1. L1.ⓑ{I}V1 ⦻*[R, #0] Y2 →
 174                              ∃∃L2,V2. L1 ⦻*[R, V1] L2 & R L1 V1 V2 &
 175                                       Y2 = L2.ⓑ{I}V2.
 176 #R #I #Y2 #L1 #V1 #H elim (lfxs_inv_zero … H) -H *
 177 [ #H destruct
 178 | #J #Y1 #L2 #X1 #V2 #HV1 #HV12 #H1 #H2 destruct
 179   /2 width=5 by ex3_2_intro/
 180 ]
 181 qed-.
 182
 183 lemma lfxs_inv_zero_pair_dx: ∀R,I,Y1,L2,V2. Y1 ⦻*[R, #0] L2.ⓑ{I}V2 →
 184                              ∃∃L1,V1. L1 ⦻*[R, V1] L2 & R L1 V1 V2 &
 185                                       Y1 = L1.ⓑ{I}V1.
 186 #R #I #Y1 #L2 #V2 #H elim (lfxs_inv_zero … H) -H *
 187 [ #_ #H destruct
 188 | #J #L1 #Y2 #V1 #X2 #HV1 #HV12 #H1 #H2 destruct
 189   /2 width=5 by ex3_2_intro/
 190 ]
 191 qed-.
 192
 193 lemma lfxs_inv_lref_pair_sn: ∀R,I,Y2,L1,V1,i. L1.ⓑ{I}V1 ⦻*[R, #⫯i] Y2 →
 194                              ∃∃L2,V2. L1 ⦻*[R, #i] L2 & Y2 = L2.ⓑ{I}V2.
 195 #R #I #Y2 #L1 #V1 #i #H elim (lfxs_inv_lref … H) -H *
 196 [ #H destruct
 197 | #J #Y1 #L2 #X1 #V2 #Hi #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 198 ]
 199 qed-.
 200
 201 lemma lfxs_inv_lref_pair_dx: ∀R,I,Y1,L2,V2,i. Y1 ⦻*[R, #⫯i] L2.ⓑ{I}V2 →
 202                              ∃∃L1,V1. L1 ⦻*[R, #i] L2 & Y1 = L1.ⓑ{I}V1.
 203 #R #I #Y1 #L2 #V2 #i #H elim (lfxs_inv_lref … H) -H *
 204 [ #_ #H destruct
 205 | #J #L1 #Y2 #V1 #X2 #Hi #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 206 ]
 207 qed-.
 208
 209 lemma lfxs_inv_gref_pair_sn: ∀R,I,Y2,L1,V1,l. L1.ⓑ{I}V1 ⦻*[R, §l] Y2 →
 210                              ∃∃L2,V2. L1 ⦻*[R, §l] L2 & Y2 = L2.ⓑ{I}V2.
 211 #R #I #Y2 #L1 #V1 #l #H elim (lfxs_inv_gref … H) -H *
 212 [ #H destruct
 213 | #J #Y1 #L2 #X1 #V2 #Hl #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 214 ]
 215 qed-.
 216
 217 lemma lfxs_inv_gref_pair_dx: ∀R,I,Y1,L2,V2,l. Y1 ⦻*[R, §l] L2.ⓑ{I}V2 →
 218                              ∃∃L1,V1. L1 ⦻*[R, §l] L2 & Y1 = L1.ⓑ{I}V1.
 219 #R #I #Y1 #L2 #V2 #l #H elim (lfxs_inv_gref … H) -H *
 220 [ #_ #H destruct
 221 | #J #L1 #Y2 #V1 #X2 #Hl #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 222 ]
 223 qed-.
 224
 225 (* Basic forward lemmas *****************************************************)
 226
 227 lemma lfxs_fwd_bind_sn: ∀R,p,I,L1,L2,V,T. L1 ⦻*[R, ⓑ{p,I}V.T] L2 → L1 ⦻*[R, V] L2.
 228 #R #p #I #L1 #L2 #V #T * #f #Hf #HL elim (frees_inv_bind … Hf) -Hf
 229 /4 width=6 by sle_lexs_trans, sor_inv_sle_sn, ex2_intro/
 230 qed-.
 231
 232 lemma lfxs_fwd_bind_dx: ∀R,p,I,L1,L2,V1,V2,T. L1 ⦻*[R, ⓑ{p,I}V1.T] L2 →
 233                         R L1 V1 V2 → L1.ⓑ{I}V1 ⦻*[R, T] L2.ⓑ{I}V2.
 234 #R #p #I #L1 #L2 #V1 #V2 #T #H #HV elim (lfxs_inv_bind … H HV) -H -HV //
 235 qed-.
 236
 237 lemma lfxs_fwd_flat_sn: ∀R,I,L1,L2,V,T. L1 ⦻*[R, ⓕ{I}V.T] L2 → L1 ⦻*[R, V] L2.
 238 #R #I #L1 #L2 #V #T #H elim (lfxs_inv_flat … H) -H //
 239 qed-.
 240
 241 lemma lfxs_fwd_flat_dx: ∀R,I,L1,L2,V,T. L1 ⦻*[R, ⓕ{I}V.T] L2 → L1 ⦻*[R, T] L2.
 242 #R #I #L1 #L2 #V #T #H elim (lfxs_inv_flat … H) -H //
 243 qed-.
 244
 245 lemma lfxs_fwd_pair_sn: ∀R,I,L1,L2,V,T. L1 ⦻*[R, ②{I}V.T] L2 → L1 ⦻*[R, V] L2.
 246 #R * /2 width=4 by lfxs_fwd_flat_sn, lfxs_fwd_bind_sn/
 247 qed-.
 248
 249 (* Basic_2A1: removed theorems 24:
 250               llpx_sn_sort llpx_sn_skip llpx_sn_lref llpx_sn_free llpx_sn_gref
 251               llpx_sn_bind llpx_sn_flat
 252               llpx_sn_inv_bind llpx_sn_inv_flat
 253               llpx_sn_fwd_lref llpx_sn_fwd_pair_sn llpx_sn_fwd_length
 254               llpx_sn_fwd_bind_sn llpx_sn_fwd_bind_dx llpx_sn_fwd_flat_sn llpx_sn_fwd_flat_dx
 255               llpx_sn_refl llpx_sn_Y llpx_sn_bind_O llpx_sn_ge_up llpx_sn_ge llpx_sn_co
 256               llpx_sn_fwd_drop_sn llpx_sn_fwd_drop_dx
 257 *)