matita/matita/contribs/lambdadelta/basic_2/static/lfxs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/relocation/rtmap_id.ma".
  16 include "basic_2/notation/relations/relationstar_4.ma".
  17 include "basic_2/relocation/lexs.ma".
  18 include "basic_2/static/frees.ma".
  19
  20 (* GENERIC EXTENSION ON REFERRED ENTRIES OF A CONTEXT-SENSITIVE REALTION ****)
  21
  22 definition lfxs (R) (T): relation lenv ≝
  23                 λL1,L2. ∃∃f. L1 ⊢ 𝐅*⦃T⦄ ≡ f & L1 ⪤*[R, cfull, f] L2.
  24
  25 interpretation "generic extension on referred entries (local environment)"
  26    'RelationStar R T L1 L2 = (lfxs R T L1 L2).
  27
  28 definition R_frees_confluent: predicate (relation3 lenv term term) ≝
  29                               λRN.
  30                               ∀f1,L,T1. L ⊢ 𝐅*⦃T1⦄ ≡ f1 → ∀T2. RN L T1 T2 →
  31                               ∃∃f2. L ⊢ 𝐅*⦃T2⦄ ≡ f2 & f2 ⊆ f1.
  32
  33 definition lexs_frees_confluent: relation (relation3 lenv term term) ≝
  34                                  λRN,RP.
  35                                  ∀f1,L1,T. L1 ⊢ 𝐅*⦃T⦄ ≡ f1 →
  36                                  ∀L2. L1 ⪤*[RN, RP, f1] L2 →
  37                                  ∃∃f2. L2 ⊢ 𝐅*⦃T⦄ ≡ f2 & f2 ⊆ f1.
  38
  39 definition R_confluent2_lfxs: relation4 (relation3 lenv term term)
  40                                         (relation3 lenv term term) … ≝
  41                               λR1,R2,RP1,RP2.
  42                               ∀L0,T0,T1. R1 L0 T0 T1 → ∀T2. R2 L0 T0 T2 →
  43                               ∀L1. L0 ⪤*[RP1, T0] L1 → ∀L2. L0 ⪤*[RP2, T0] L2 →
  44                               ∃∃T. R2 L1 T1 T & R1 L2 T2 T.
  45
  46 (* Basic properties *********************************************************)
  47
  48 lemma lfxs_atom: ∀R,I. ⋆ ⪤*[R, ⓪{I}] ⋆.
  49 /3 width=3 by lexs_atom, frees_atom, ex2_intro/
  50 qed.
  51
  52 (* Basic_2A1: uses: llpx_sn_sort *)
  53 lemma lfxs_sort: ∀R,I,L1,L2,V1,V2,s.
  54                  L1 ⪤*[R, ⋆s] L2 → L1.ⓑ{I}V1 ⪤*[R, ⋆s] L2.ⓑ{I}V2.
  55 #R #I #L1 #L2 #V1 #V2 #s * /3 width=3 by lexs_push, frees_sort, ex2_intro/
  56 qed.
  57
  58 lemma lfxs_zero: ∀R,I,L1,L2,V1,V2. L1 ⪤*[R, V1] L2 →
  59                  R L1 V1 V2 → L1.ⓑ{I}V1 ⪤*[R, #0] L2.ⓑ{I}V2.
  60 #R #I #L1 #L2 #V1 #V2 * /3 width=3 by lexs_next, frees_zero, ex2_intro/
  61 qed.
  62
  63 lemma lfxs_lref: ∀R,I,L1,L2,V1,V2,i.
  64                  L1 ⪤*[R, #i] L2 → L1.ⓑ{I}V1 ⪤*[R, #⫯i] L2.ⓑ{I}V2.
  65 #R #I #L1 #L2 #V1 #V2 #i * /3 width=3 by lexs_push, frees_lref, ex2_intro/
  66 qed.
  67
  68 (* Basic_2A1: uses: llpx_sn_gref *)
  69 lemma lfxs_gref: ∀R,I,L1,L2,V1,V2,l.
  70                  L1 ⪤*[R, §l] L2 → L1.ⓑ{I}V1 ⪤*[R, §l] L2.ⓑ{I}V2.
  71 #R #I #L1 #L2 #V1 #V2 #l * /3 width=3 by lexs_push, frees_gref, ex2_intro/
  72 qed.
  73
  74 lemma lfxs_pair_repl_dx: ∀R,I,L1,L2,T,V,V1.
  75                          L1.ⓑ{I}V ⪤*[R, T] L2.ⓑ{I}V1 →
  76                          ∀V2. R L1 V V2 →
  77                          L1.ⓑ{I}V ⪤*[R, T] L2.ⓑ{I}V2.
  78 #R #I #L1 #L2 #T #V #V1 * #f #Hf #HL12 #V2 #HR
  79 /3 width=5 by lexs_pair_repl, ex2_intro/
  80 qed-.
  81
  82 lemma lfxs_sym: ∀R. lexs_frees_confluent R cfull →
  83                 (∀L1,L2,T1,T2. R L1 T1 T2 → R L2 T2 T1) →
  84                 ∀T. symmetric … (lfxs R T).
  85 #R #H1R #H2R #T #L1 #L2 * #f1 #Hf1 #HL12 elim (H1R … Hf1 … HL12) -Hf1
  86 /4 width=5 by sle_lexs_trans, lexs_sym, ex2_intro/
  87 qed-.
  88
  89 (* Basic_2A1: uses: llpx_sn_co *)
  90 lemma lfxs_co: ∀R1,R2. (∀L,T1,T2. R1 L T1 T2 → R2 L T1 T2) →
  91                ∀L1,L2,T. L1 ⪤*[R1, T] L2 → L1 ⪤*[R2, T] L2.
  92 #R1 #R2 #HR #L1 #L2 #T * /4 width=7 by lexs_co, ex2_intro/
  93 qed-.
  94
  95 lemma lfxs_isid: ∀R1,R2,L1,L2,T1,T2.
  96                  (∀f. L1 ⊢ 𝐅*⦃T1⦄ ≡ f → 𝐈⦃f⦄) →
  97                  (∀f. 𝐈⦃f⦄ → L1 ⊢ 𝐅*⦃T2⦄ ≡ f) →
  98                  L1 ⪤*[R1, T1] L2 → L1 ⪤*[R2, T2] L2.
  99 #R1 #R2 #L1 #L2 #T1 #T2 #H1 #H2 *
 100 /4 width=7 by lexs_co_isid, ex2_intro/
 101 qed-.
 102
 103 (* Basic inversion lemmas ***************************************************)
 104
 105 lemma lfxs_inv_atom_sn: ∀R,Y2,T. ⋆ ⪤*[R, T] Y2 → Y2 = ⋆.
 106 #R #Y2 #T * /2 width=4 by lexs_inv_atom1/
 107 qed-.
 108
 109 lemma lfxs_inv_atom_dx: ∀R,Y1,T. Y1 ⪤*[R, T] ⋆ → Y1 = ⋆.
 110 #R #I #Y1 * /2 width=4 by lexs_inv_atom2/
 111 qed-.
 112
 113 lemma lfxs_inv_sort: ∀R,Y1,Y2,s. Y1 ⪤*[R, ⋆s] Y2 →
 114                      (Y1 = ⋆ ∧ Y2 = ⋆) ∨
 115                      ∃∃I,L1,L2,V1,V2. L1 ⪤*[R, ⋆s] L2 &
 116                                       Y1 = L1.ⓑ{I}V1 & Y2 = L2.ⓑ{I}V2.
 117 #R * [ | #Y1 #I #V1 ] #Y2 #s * #f #H1 #H2
 118 [ lapply (lexs_inv_atom1 … H2) -H2 /3 width=1 by or_introl, conj/
 119 | lapply (frees_inv_sort … H1) -H1 #Hf
 120   elim (isid_inv_gen … Hf) -Hf #g #Hg #H destruct
 121   elim (lexs_inv_push1 … H2) -H2 #L2 #V2 #H12 #_ #H destruct
 122   /5 width=8 by frees_sort_gen, ex3_5_intro, ex2_intro, or_intror/
 123 ]
 124 qed-.
 125
 126 lemma lfxs_inv_zero: ∀R,Y1,Y2. Y1 ⪤*[R, #0] Y2 →
 127                      (Y1 = ⋆ ∧ Y2 = ⋆) ∨
 128                      ∃∃I,L1,L2,V1,V2. L1 ⪤*[R, V1] L2 & R L1 V1 V2 &
 129                                       Y1 = L1.ⓑ{I}V1 & Y2 = L2.ⓑ{I}V2.
 130 #R #Y1 #Y2 * #f #H1 #H2 elim (frees_inv_zero … H1) -H1 *
 131 [ #H #_ lapply (lexs_inv_atom1_aux … H2 H) -H2 /3 width=1 by or_introl, conj/
 132 | #I1 #L1 #V1 #g #HV1 #HY1 #Hg elim (lexs_inv_next1_aux … H2 … HY1 Hg) -H2 -Hg
 133   /4 width=9 by ex4_5_intro, ex2_intro, or_intror/
 134 ]
 135 qed-.
 136
 137 lemma lfxs_inv_lref: ∀R,Y1,Y2,i. Y1 ⪤*[R, #⫯i] Y2 →
 138                      (Y1 = ⋆ ∧ Y2 = ⋆) ∨
 139                      ∃∃I,L1,L2,V1,V2. L1 ⪤*[R, #i] L2 &
 140                                       Y1 = L1.ⓑ{I}V1 & Y2 = L2.ⓑ{I}V2.
 141 #R #Y1 #Y2 #i * #f #H1 #H2 elim (frees_inv_lref … H1) -H1 *
 142 [ #H #_ lapply (lexs_inv_atom1_aux … H2 H) -H2 /3 width=1 by or_introl, conj/
 143 | #I1 #L1 #V1 #g #HV1 #HY1 #Hg elim (lexs_inv_push1_aux … H2 … HY1 Hg) -H2 -Hg
 144   /4 width=8 by ex3_5_intro, ex2_intro, or_intror/
 145 ]
 146 qed-.
 147
 148 lemma lfxs_inv_gref: ∀R,Y1,Y2,l. Y1 ⪤*[R, §l] Y2 →
 149                      (Y1 = ⋆ ∧ Y2 = ⋆) ∨
 150                      ∃∃I,L1,L2,V1,V2. L1 ⪤*[R, §l] L2 &
 151                                       Y1 = L1.ⓑ{I}V1 & Y2 = L2.ⓑ{I}V2.
 152 #R * [ | #Y1 #I #V1 ] #Y2 #l * #f #H1 #H2
 153 [ lapply (lexs_inv_atom1 … H2) -H2 /3 width=1 by or_introl, conj/
 154 | lapply (frees_inv_gref … H1) -H1 #Hf
 155   elim (isid_inv_gen … Hf) -Hf #g #Hg #H destruct
 156   elim (lexs_inv_push1 … H2) -H2 #L2 #V2 #H12 #_ #H destruct
 157   /5 width=8 by frees_gref_gen, ex3_5_intro, ex2_intro, or_intror/
 158 ]
 159 qed-.
 160
 161 (* Basic_2A1: uses: llpx_sn_inv_bind llpx_sn_inv_bind_O *)
 162 lemma lfxs_inv_bind: ∀R,p,I,L1,L2,V1,V2,T. L1 ⪤*[R, ⓑ{p,I}V1.T] L2 → R L1 V1 V2 →
 163                      L1 ⪤*[R, V1] L2 ∧ L1.ⓑ{I}V1 ⪤*[R, T] L2.ⓑ{I}V2.
 164 #R #p #I #L1 #L2 #V1 #V2 #T * #f #Hf #HL #HV elim (frees_inv_bind … Hf) -Hf
 165 /6 width=6 by sle_lexs_trans, lexs_inv_tl, sor_inv_sle_dx, sor_inv_sle_sn, ex2_intro, conj/
 166 qed-.
 167
 168 (* Basic_2A1: uses: llpx_sn_inv_flat *)
 169 lemma lfxs_inv_flat: ∀R,I,L1,L2,V,T. L1 ⪤*[R, ⓕ{I}V.T] L2 →
 170                      L1 ⪤*[R, V] L2 ∧ L1 ⪤*[R, T] L2.
 171 #R #I #L1 #L2 #V #T * #f #Hf #HL elim (frees_inv_flat … Hf) -Hf
 172 /5 width=6 by sle_lexs_trans, sor_inv_sle_dx, sor_inv_sle_sn, ex2_intro, conj/
 173 qed-.
 174
 175 (* Advanced inversion lemmas ************************************************)
 176
 177 lemma lfxs_inv_sort_pair_sn: ∀R,I,Y2,L1,V1,s. L1.ⓑ{I}V1 ⪤*[R, ⋆s] Y2 →
 178                              ∃∃L2,V2. L1 ⪤*[R, ⋆s] L2 & Y2 = L2.ⓑ{I}V2.
 179 #R #I #Y2 #L1 #V1 #s #H elim (lfxs_inv_sort … H) -H *
 180 [ #H destruct
 181 | #J #Y1 #L2 #X1 #V2 #Hs #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 182 ]
 183 qed-.
 184
 185 lemma lfxs_inv_sort_pair_dx: ∀R,I,Y1,L2,V2,s. Y1 ⪤*[R, ⋆s] L2.ⓑ{I}V2 →
 186                              ∃∃L1,V1. L1 ⪤*[R, ⋆s] L2 & Y1 = L1.ⓑ{I}V1.
 187 #R #I #Y1 #L2 #V2 #s #H elim (lfxs_inv_sort … H) -H *
 188 [ #_ #H destruct
 189 | #J #L1 #Y2 #V1 #X2 #Hs #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 190 ]
 191 qed-.
 192
 193 lemma lfxs_inv_zero_pair_sn: ∀R,I,Y2,L1,V1. L1.ⓑ{I}V1 ⪤*[R, #0] Y2 →
 194                              ∃∃L2,V2. L1 ⪤*[R, V1] L2 & R L1 V1 V2 &
 195                                       Y2 = L2.ⓑ{I}V2.
 196 #R #I #Y2 #L1 #V1 #H elim (lfxs_inv_zero … H) -H *
 197 [ #H destruct
 198 | #J #Y1 #L2 #X1 #V2 #HV1 #HV12 #H1 #H2 destruct
 199   /2 width=5 by ex3_2_intro/
 200 ]
 201 qed-.
 202
 203 lemma lfxs_inv_zero_pair_dx: ∀R,I,Y1,L2,V2. Y1 ⪤*[R, #0] L2.ⓑ{I}V2 →
 204                              ∃∃L1,V1. L1 ⪤*[R, V1] L2 & R L1 V1 V2 &
 205                                       Y1 = L1.ⓑ{I}V1.
 206 #R #I #Y1 #L2 #V2 #H elim (lfxs_inv_zero … H) -H *
 207 [ #_ #H destruct
 208 | #J #L1 #Y2 #V1 #X2 #HV1 #HV12 #H1 #H2 destruct
 209   /2 width=5 by ex3_2_intro/
 210 ]
 211 qed-.
 212
 213 lemma lfxs_inv_lref_pair_sn: ∀R,I,Y2,L1,V1,i. L1.ⓑ{I}V1 ⪤*[R, #⫯i] Y2 →
 214                              ∃∃L2,V2. L1 ⪤*[R, #i] L2 & Y2 = L2.ⓑ{I}V2.
 215 #R #I #Y2 #L1 #V1 #i #H elim (lfxs_inv_lref … H) -H *
 216 [ #H destruct
 217 | #J #Y1 #L2 #X1 #V2 #Hi #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 218 ]
 219 qed-.
 220
 221 lemma lfxs_inv_lref_pair_dx: ∀R,I,Y1,L2,V2,i. Y1 ⪤*[R, #⫯i] L2.ⓑ{I}V2 →
 222                              ∃∃L1,V1. L1 ⪤*[R, #i] L2 & Y1 = L1.ⓑ{I}V1.
 223 #R #I #Y1 #L2 #V2 #i #H elim (lfxs_inv_lref … H) -H *
 224 [ #_ #H destruct
 225 | #J #L1 #Y2 #V1 #X2 #Hi #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 226 ]
 227 qed-.
 228
 229 lemma lfxs_inv_gref_pair_sn: ∀R,I,Y2,L1,V1,l. L1.ⓑ{I}V1 ⪤*[R, §l] Y2 →
 230                              ∃∃L2,V2. L1 ⪤*[R, §l] L2 & Y2 = L2.ⓑ{I}V2.
 231 #R #I #Y2 #L1 #V1 #l #H elim (lfxs_inv_gref … H) -H *
 232 [ #H destruct
 233 | #J #Y1 #L2 #X1 #V2 #Hl #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 234 ]
 235 qed-.
 236
 237 lemma lfxs_inv_gref_pair_dx: ∀R,I,Y1,L2,V2,l. Y1 ⪤*[R, §l] L2.ⓑ{I}V2 →
 238                              ∃∃L1,V1. L1 ⪤*[R, §l] L2 & Y1 = L1.ⓑ{I}V1.
 239 #R #I #Y1 #L2 #V2 #l #H elim (lfxs_inv_gref … H) -H *
 240 [ #_ #H destruct
 241 | #J #L1 #Y2 #V1 #X2 #Hl #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 242 ]
 243 qed-.
 244
 245 (* Basic forward lemmas *****************************************************)
 246
 247 (* Basic_2A1: uses: llpx_sn_fwd_pair_sn llpx_sn_fwd_bind_sn llpx_sn_fwd_flat_sn *)
 248 lemma lfxs_fwd_pair_sn: ∀R,I,L1,L2,V,T. L1 ⪤*[R, ②{I}V.T] L2 → L1 ⪤*[R, V] L2.
 249 #R * [ #p ] #I #L1 #L2 #V #T * #f #Hf #HL
 250 [ elim (frees_inv_bind … Hf) | elim (frees_inv_flat … Hf) ] -Hf
 251 /4 width=6 by sle_lexs_trans, sor_inv_sle_sn, ex2_intro/
 252 qed-.
 253
 254 (* Basic_2A1: uses: llpx_sn_fwd_bind_dx llpx_sn_fwd_bind_O_dx *)
 255 lemma lfxs_fwd_bind_dx: ∀R,p,I,L1,L2,V1,V2,T. L1 ⪤*[R, ⓑ{p,I}V1.T] L2 →
 256                         R L1 V1 V2 → L1.ⓑ{I}V1 ⪤*[R, T] L2.ⓑ{I}V2.
 257 #R #p #I #L1 #L2 #V1 #V2 #T #H #HV elim (lfxs_inv_bind … H HV) -H -HV //
 258 qed-.
 259
 260 (* Basic_2A1: uses: llpx_sn_fwd_flat_dx *)
 261 lemma lfxs_fwd_flat_dx: ∀R,I,L1,L2,V,T. L1 ⪤*[R, ⓕ{I}V.T] L2 → L1 ⪤*[R, T] L2.
 262 #R #I #L1 #L2 #V #T #H elim (lfxs_inv_flat … H) -H //
 263 qed-.
 264
 265 lemma lfxs_fwd_dx: ∀R,I,L1,K2,T,V2. L1 ⪤*[R, T] K2.ⓑ{I}V2 →
 266                    ∃∃K1,V1. L1 = K1.ⓑ{I}V1.
 267 #R #I #L1 #K2 #T #V2 * #f elim (pn_split f) * #g #Hg #_ #Hf destruct
 268 [ elim (lexs_inv_push2 … Hf) | elim (lexs_inv_next2 … Hf) ] -Hf #K1 #V1 #_ #_ #H destruct
 269 /2 width=3 by ex1_2_intro/
 270 qed-.
 271
 272 (* Basic_2A1: removed theorems 9:
 273               llpx_sn_skip llpx_sn_lref llpx_sn_free
 274               llpx_sn_fwd_lref
 275               llpx_sn_Y llpx_sn_ge_up llpx_sn_ge
 276               llpx_sn_fwd_drop_sn llpx_sn_fwd_drop_dx
 277 *)