matita/matita/contribs/lambdadelta/basic_2/static/lfxs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/relocation/rtmap_id.ma".
  16 include "basic_2/notation/relations/relationstar_4.ma".
  17 include "basic_2/grammar/ceq.ma".
  18 include "basic_2/relocation/lexs.ma".
  19 include "basic_2/static/frees.ma".
  20
  21 (* GENERIC EXTENSION ON REFERRED ENTRIES OF A CONTEXT-SENSITIVE REALTION ****)
  22
  23 definition lfxs (R) (T): relation lenv ≝
  24                 λL1,L2. ∃∃f. L1 ⊢ 𝐅*⦃T⦄ ≡ f & L1 ⦻*[R, cfull, f] L2.
  25
  26 interpretation "generic extension on referred entries (local environment)"
  27    'RelationStar R T L1 L2 = (lfxs R T L1 L2).
  28
  29 definition lfxs_confluent: relation4 (relation3 lenv term term)
  30                                      (relation3 lenv term term) … ≝
  31                            λR1,R2,RP1,RP2.
  32                            ∀L0,T0,T1. R1 L0 T0 T1 → ∀T2. R2 L0 T0 T2 →
  33                            ∀L1. L0 ⦻*[RP1, T0] L1 → ∀L2. L0 ⦻*[RP2, T0] L2 →
  34                            ∃∃T. R2 L1 T1 T & R1 L2 T2 T.
  35
  36 (* Basic properties ***********************************************************)
  37
  38 lemma lfxs_atom: ∀R,I. ⋆ ⦻*[R, ⓪{I}] ⋆.
  39 /3 width=3 by lexs_atom, frees_atom, ex2_intro/
  40 qed.
  41
  42 lemma lfxs_sort: ∀R,I,L1,L2,V1,V2,s.
  43                  L1 ⦻*[R, ⋆s] L2 → L1.ⓑ{I}V1 ⦻*[R, ⋆s] L2.ⓑ{I}V2.
  44 #R #I #L1 #L2 #V1 #V2 #s * /3 width=3 by lexs_push, frees_sort, ex2_intro/
  45 qed.
  46
  47 lemma lfxs_zero: ∀R,I,L1,L2,V1,V2. L1 ⦻*[R, V1] L2 →
  48                  R L1 V1 V2 → L1.ⓑ{I}V1 ⦻*[R, #0] L2.ⓑ{I}V2.
  49 #R #I #L1 #L2 #V1 #V2 * /3 width=3 by lexs_next, frees_zero, ex2_intro/
  50 qed.
  51
  52 lemma lfxs_lref: ∀R,I,L1,L2,V1,V2,i.
  53                  L1 ⦻*[R, #i] L2 → L1.ⓑ{I}V1 ⦻*[R, #⫯i] L2.ⓑ{I}V2.
  54 #R #I #L1 #L2 #V1 #V2 #i * /3 width=3 by lexs_push, frees_lref, ex2_intro/
  55 qed.
  56
  57 lemma lfxs_gref: ∀R,I,L1,L2,V1,V2,l.
  58                  L1 ⦻*[R, §l] L2 → L1.ⓑ{I}V1 ⦻*[R, §l] L2.ⓑ{I}V2.
  59 #R #I #L1 #L2 #V1 #V2 #l * /3 width=3 by lexs_push, frees_gref, ex2_intro/
  60 qed.
  61
  62 lemma lfxs_pair_repl_dx: ∀R,I,L1,L2,T,V,V1.
  63                          L1.ⓑ{I}V ⦻*[R, T] L2.ⓑ{I}V1 →
  64                          ∀V2. R L1 V V2 →
  65                          L1.ⓑ{I}V ⦻*[R, T] L2.ⓑ{I}V2.
  66 #R #I #L1 #L2 #T #V #V1 * #f #Hf #HL12 #V2 #HR
  67 /3 width=5 by lexs_pair_repl, ex2_intro/
  68 qed-.
  69
  70 lemma lfxs_co: ∀R1,R2. (∀L,T1,T2. R1 L T1 T2 → R2 L T1 T2) →
  71                ∀L1,L2,T. L1 ⦻*[R1, T] L2 → L1 ⦻*[R2, T] L2.
  72 #R1 #R2 #HR #L1 #L2 #T * /4 width=7 by lexs_co, ex2_intro/
  73 qed-.
  74
  75 (* Basic inversion lemmas ***************************************************)
  76
  77 lemma lfxs_inv_atom_sn: ∀R,I,Y2. ⋆ ⦻*[R, ⓪{I}] Y2 → Y2 = ⋆.
  78 #R #I #Y2 * /2 width=4 by lexs_inv_atom1/
  79 qed-.
  80
  81 lemma lfxs_inv_atom_dx: ∀R,I,Y1. Y1 ⦻*[R, ⓪{I}] ⋆ → Y1 = ⋆.
  82 #R #I #Y1 * /2 width=4 by lexs_inv_atom2/
  83 qed-.
  84
  85 lemma lfxs_inv_zero: ∀R,Y1,Y2. Y1 ⦻*[R, #0] Y2 →
  86                      (Y1 = ⋆ ∧ Y2 = ⋆) ∨
  87                      ∃∃I,L1,L2,V1,V2. L1 ⦻*[R, V1] L2 & R L1 V1 V2 &
  88                                       Y1 = L1.ⓑ{I}V1 & Y2 = L2.ⓑ{I}V2.
  89 #R #Y1 #Y2 * #f #H1 #H2 elim (frees_inv_zero … H1) -H1 *
  90 [ #H #_ lapply (lexs_inv_atom1_aux … H2 H) -H2 /3 width=1 by or_introl, conj/
  91 | #I1 #L1 #V1 #g #HV1 #HY1 #Hg elim (lexs_inv_next1_aux … H2 … HY1 Hg) -H2 -Hg
  92   /4 width=9 by ex4_5_intro, ex2_intro, or_intror/
  93 ]
  94 qed-.
  95
  96 lemma lfxs_inv_lref: ∀R,Y1,Y2,i. Y1 ⦻*[R, #⫯i] Y2 →
  97                      (Y1 = ⋆ ∧ Y2 = ⋆) ∨
  98                      ∃∃I,L1,L2,V1,V2. L1 ⦻*[R, #i] L2 &
  99                                       Y1 = L1.ⓑ{I}V1 & Y2 = L2.ⓑ{I}V2.
 100 #R #Y1 #Y2 #i * #f #H1 #H2 elim (frees_inv_lref … H1) -H1 *
 101 [ #H #_ lapply (lexs_inv_atom1_aux … H2 H) -H2 /3 width=1 by or_introl, conj/
 102 | #I1 #L1 #V1 #g #HV1 #HY1 #Hg elim (lexs_inv_push1_aux … H2 … HY1 Hg) -H2 -Hg
 103   /4 width=8 by ex3_5_intro, ex2_intro, or_intror/
 104 ]
 105 qed-.
 106
 107 lemma lfxs_inv_bind: ∀R,p,I,L1,L2,V1,V2,T. L1 ⦻*[R, ⓑ{p,I}V1.T] L2 → R L1 V1 V2 →
 108                      L1 ⦻*[R, V1] L2 ∧ L1.ⓑ{I}V1 ⦻*[R, T] L2.ⓑ{I}V2.
 109 #R #p #I #L1 #L2 #V1 #V2 #T * #f #Hf #HL #HV elim (frees_inv_bind … Hf) -Hf
 110 /6 width=6 by sle_lexs_trans, lexs_inv_tl, sor_inv_sle_dx, sor_inv_sle_sn, ex2_intro, conj/
 111 qed-.
 112
 113 lemma lfxs_inv_flat: ∀R,I,L1,L2,V,T. L1 ⦻*[R, ⓕ{I}V.T] L2 →
 114                      L1 ⦻*[R, V] L2 ∧ L1 ⦻*[R, T] L2.
 115 #R #I #L1 #L2 #V #T * #f #Hf #HL elim (frees_inv_flat … Hf) -Hf
 116 /5 width=6 by sle_lexs_trans, sor_inv_sle_dx, sor_inv_sle_sn, ex2_intro, conj/
 117 qed-.
 118
 119 (* Advanced inversion lemmas ************************************************)
 120
 121 lemma lfxs_inv_zero_pair_sn: ∀R,I,Y2,L1,V1. L1.ⓑ{I}V1 ⦻*[R, #0] Y2 →
 122                              ∃∃L2,V2. L1 ⦻*[R, V1] L2 & R L1 V1 V2 &
 123                                       Y2 = L2.ⓑ{I}V2.
 124 #R #I #Y2 #L1 #V1 #H elim (lfxs_inv_zero … H) -H *
 125 [ #H destruct
 126 | #J #Y1 #L2 #X1 #V2 #HV1 #HV12 #H1 #H2 destruct
 127   /2 width=5 by ex3_2_intro/
 128 ]
 129 qed-.
 130
 131 lemma lfxs_inv_zero_pair_dx: ∀R,I,Y1,L2,V2. Y1 ⦻*[R, #0] L2.ⓑ{I}V2 →
 132                              ∃∃L1,V1. L1 ⦻*[R, V1] L2 & R L1 V1 V2 &
 133                                       Y1 = L1.ⓑ{I}V1.
 134 #R #I #Y1 #L2 #V2 #H elim (lfxs_inv_zero … H) -H *
 135 [ #_ #H destruct
 136 | #J #L1 #Y2 #V1 #X2 #HV1 #HV12 #H1 #H2 destruct
 137   /2 width=5 by ex3_2_intro/
 138 ]
 139 qed-.
 140
 141 lemma lfxs_inv_lref_pair_sn: ∀R,I,Y2,L1,V1,i. L1.ⓑ{I}V1 ⦻*[R, #⫯i] Y2 →
 142                              ∃∃L2,V2. L1 ⦻*[R, #i] L2 & Y2 = L2.ⓑ{I}V2.
 143 #R #I #Y2 #L1 #V1 #i #H elim (lfxs_inv_lref … H) -H *
 144 [ #H destruct
 145 | #J #Y1 #L2 #X1 #V2 #Hi #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 146 ]
 147 qed-.
 148
 149 lemma lfxs_inv_lref_pair_dx: ∀R,I,Y1,L2,V2,i. Y1 ⦻*[R, #⫯i] L2.ⓑ{I}V2 →
 150                              ∃∃L1,V1. L1 ⦻*[R, #i] L2 & Y1 = L1.ⓑ{I}V1.
 151 #R #I #Y1 #L2 #V2 #i #H elim (lfxs_inv_lref … H) -H *
 152 [ #_ #H destruct
 153 | #J #L1 #Y2 #V1 #X2 #Hi #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 154 ]
 155 qed-.
 156
 157 (* Basic forward lemmas *****************************************************)
 158
 159 lemma lfxs_fwd_bind_sn: ∀R,p,I,L1,L2,V,T. L1 ⦻*[R, ⓑ{p,I}V.T] L2 → L1 ⦻*[R, V] L2.
 160 #R #p #I #L1 #L2 #V #T * #f #Hf #HL elim (frees_inv_bind … Hf) -Hf
 161 /4 width=6 by sle_lexs_trans, sor_inv_sle_sn, ex2_intro/
 162 qed-.
 163
 164 lemma lfxs_fwd_bind_dx: ∀R,p,I,L1,L2,V1,V2,T. L1 ⦻*[R, ⓑ{p,I}V1.T] L2 →
 165                         R L1 V1 V2 → L1.ⓑ{I}V1 ⦻*[R, T] L2.ⓑ{I}V2.
 166 #R #p #I #L1 #L2 #V1 #V2 #T #H #HV elim (lfxs_inv_bind … H HV) -H -HV //
 167 qed-.
 168
 169 lemma lfxs_fwd_flat_sn: ∀R,I,L1,L2,V,T. L1 ⦻*[R, ⓕ{I}V.T] L2 → L1 ⦻*[R, V] L2.
 170 #R #I #L1 #L2 #V #T #H elim (lfxs_inv_flat … H) -H //
 171 qed-.
 172
 173 lemma lfxs_fwd_flat_dx: ∀R,I,L1,L2,V,T. L1 ⦻*[R, ⓕ{I}V.T] L2 → L1 ⦻*[R, T] L2.
 174 #R #I #L1 #L2 #V #T #H elim (lfxs_inv_flat … H) -H //
 175 qed-.
 176
 177 lemma lfxs_fwd_pair_sn: ∀R,I,L1,L2,V,T. L1 ⦻*[R, ②{I}V.T] L2 → L1 ⦻*[R, V] L2.
 178 #R * /2 width=4 by lfxs_fwd_flat_sn, lfxs_fwd_bind_sn/
 179 qed-.
 180
 181 (* Basic_2A1: removed theorems 24:
 182               llpx_sn_sort llpx_sn_skip llpx_sn_lref llpx_sn_free llpx_sn_gref
 183               llpx_sn_bind llpx_sn_flat
 184               llpx_sn_inv_bind llpx_sn_inv_flat
 185               llpx_sn_fwd_lref llpx_sn_fwd_pair_sn llpx_sn_fwd_length
 186               llpx_sn_fwd_bind_sn llpx_sn_fwd_bind_dx llpx_sn_fwd_flat_sn llpx_sn_fwd_flat_dx
 187               llpx_sn_refl llpx_sn_Y llpx_sn_bind_O llpx_sn_ge_up llpx_sn_ge llpx_sn_co
 188               llpx_sn_fwd_drop_sn llpx_sn_fwd_drop_dx
 189 *)