matita/matita/contribs/lambdadelta/basic_2/static/lfxs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/relocation/rtmap_id.ma".
  16 include "basic_2/notation/relations/relationstar_4.ma".
  17 include "basic_2/syntax/lenv_ext2.ma".
  18 include "basic_2/relocation/lexs.ma".
  19 include "basic_2/static/frees.ma".
  20
  21 (* GENERIC EXTENSION ON REFERRED ENTRIES OF A CONTEXT-SENSITIVE REALTION ****)
  22
  23 definition lfxs (R) (T): relation lenv ≝
  24                 λL1,L2. ∃∃f. L1 ⊢ 𝐅*⦃T⦄ ≡ f & L1 ⪤*[cext2 R, cfull, f] L2.
  25
  26 interpretation "generic extension on referred entries (local environment)"
  27    'RelationStar R T L1 L2 = (lfxs R T L1 L2).
  28
  29 definition R_frees_confluent: predicate (relation3 …) ≝
  30                               λRN.
  31                               ∀f1,L,T1. L ⊢ 𝐅*⦃T1⦄ ≡ f1 → ∀T2. RN L T1 T2 →
  32                               ∃∃f2. L ⊢ 𝐅*⦃T2⦄ ≡ f2 & f2 ⊆ f1.
  33
  34 definition lexs_frees_confluent: relation (relation3 …) ≝
  35                                  λRN,RP.
  36                                  ∀f1,L1,T. L1 ⊢ 𝐅*⦃T⦄ ≡ f1 →
  37                                  ∀L2. L1 ⪤*[RN, RP, f1] L2 →
  38                                  ∃∃f2. L2 ⊢ 𝐅*⦃T⦄ ≡ f2 & f2 ⊆ f1.
  39
  40 definition R_confluent2_lfxs: relation4 (relation3 lenv term term)
  41                                         (relation3 lenv term term) … ≝
  42                               λR1,R2,RP1,RP2.
  43                               ∀L0,T0,T1. R1 L0 T0 T1 → ∀T2. R2 L0 T0 T2 →
  44                               ∀L1. L0 ⪤*[RP1, T0] L1 → ∀L2. L0 ⪤*[RP2, T0] L2 →
  45                               ∃∃T. R2 L1 T1 T & R1 L2 T2 T.
  46
  47 (* Basic properties *********************************************************)
  48
  49 lemma lfxs_atom: ∀R,I. ⋆ ⪤*[R, ⓪{I}] ⋆.
  50 #R * /3 width=3 by frees_sort, frees_atom, frees_gref, lexs_atom, ex2_intro/
  51 qed.
  52
  53 (* Basic_2A1: uses: llpx_sn_sort *)
  54 lemma lfxs_sort: ∀R,I1,I2,L1,L2,s.
  55                  L1 ⪤*[R, ⋆s] L2 → L1.ⓘ{I1} ⪤*[R, ⋆s] L2.ⓘ{I2}.
  56 #R #I1 #I2 #L1 #L2 #s * #f #Hf #H12
  57 lapply (frees_inv_sort … Hf) -Hf
  58 /4 width=3 by frees_sort, lexs_push, isid_push, ex2_intro/
  59 qed.
  60
  61 lemma lfxs_pair: ∀R,I,L1,L2,V1,V2. L1 ⪤*[R, V1] L2 →
  62                  R L1 V1 V2 → L1.ⓑ{I}V1 ⪤*[R, #0] L2.ⓑ{I}V2.
  63 #R #I1 #I2 #L1 #L2 #V1 *
  64 /4 width=3 by ext2_pair, frees_pair, lexs_next, ex2_intro/
  65 qed.
  66
  67 lemma lfxs_unit: ∀R,f,I,L1,L2. 𝐈⦃f⦄ → L1 ⪤*[cext2 R, cfull, f] L2 →
  68                  L1.ⓤ{I} ⪤*[R, #0] L2.ⓤ{I}.
  69 /4 width=3 by frees_unit, lexs_next, ext2_unit, ex2_intro/ qed.
  70
  71 lemma lfxs_lref: ∀R,I1,I2,L1,L2,i.
  72                  L1 ⪤*[R, #i] L2 → L1.ⓘ{I1} ⪤*[R, #⫯i] L2.ⓘ{I2}.
  73 #R #I1 #I2 #L1 #L2 #i * /3 width=3 by lexs_push, frees_lref, ex2_intro/
  74 qed.
  75
  76 (* Basic_2A1: uses: llpx_sn_gref *)
  77 lemma lfxs_gref: ∀R,I1,I2,L1,L2,l.
  78                  L1 ⪤*[R, §l] L2 → L1.ⓘ{I1} ⪤*[R, §l] L2.ⓘ{I2}.
  79 #R #I1 #I2 #L1 #L2 #l * #f #Hf #H12
  80 lapply (frees_inv_gref … Hf) -Hf
  81 /4 width=3 by frees_gref, lexs_push, isid_push, ex2_intro/
  82 qed.
  83
  84 lemma lfxs_bind_repl_dx: ∀R,I,I1,L1,L2,T.
  85                          L1.ⓘ{I} ⪤*[R, T] L2.ⓘ{I1} →
  86                          ∀I2. cext2 R L1 I I2 →
  87                          L1.ⓘ{I} ⪤*[R, T] L2.ⓘ{I2}.
  88 #R #I #I1 #L1 #L2 #T * #f #Hf #HL12 #I2 #HR
  89 /3 width=5 by lexs_pair_repl, ex2_intro/
  90 qed-.
  91
  92 lemma lfxs_sym: ∀R. lexs_frees_confluent (cext2 R) cfull →
  93                 (∀L1,L2,T1,T2. R L1 T1 T2 → R L2 T2 T1) →
  94                 ∀T. symmetric … (lfxs R T).
  95 #R #H1R #H2R #T #L1 #L2 * #f1 #Hf1 #HL12 elim (H1R … Hf1 … HL12) -Hf1
  96 /5 width=5 by sle_lexs_trans, lexs_sym, cext2_sym, ex2_intro/
  97 qed-.
  98
  99 (* Basic_2A1: uses: llpx_sn_co *)
 100 lemma lfxs_co: ∀R1,R2. (∀L,T1,T2. R1 L T1 T2 → R2 L T1 T2) →
 101                ∀L1,L2,T. L1 ⪤*[R1, T] L2 → L1 ⪤*[R2, T] L2.
 102 #R1 #R2 #HR #L1 #L2 #T * /5 width=7 by lexs_co, cext2_co, ex2_intro/
 103 qed-.
 104
 105 lemma lfxs_isid: ∀R1,R2,L1,L2,T1,T2.
 106                  (∀f. L1 ⊢ 𝐅*⦃T1⦄ ≡ f → 𝐈⦃f⦄) →
 107                  (∀f. 𝐈⦃f⦄ → L1 ⊢ 𝐅*⦃T2⦄ ≡ f) →
 108                  L1 ⪤*[R1, T1] L2 → L1 ⪤*[R2, T2] L2.
 109 #R1 #R2 #L1 #L2 #T1 #T2 #H1 #H2 *
 110 /4 width=7 by lexs_co_isid, ex2_intro/
 111 qed-.
 112
 113 (* Basic inversion lemmas ***************************************************)
 114
 115 lemma lfxs_inv_atom_sn: ∀R,Y2,T. ⋆ ⪤*[R, T] Y2 → Y2 = ⋆.
 116 #R #Y2 #T * /2 width=4 by lexs_inv_atom1/
 117 qed-.
 118
 119 lemma lfxs_inv_atom_dx: ∀R,Y1,T. Y1 ⪤*[R, T] ⋆ → Y1 = ⋆.
 120 #R #I #Y1 * /2 width=4 by lexs_inv_atom2/
 121 qed-.
 122
 123 lemma lfxs_inv_sort: ∀R,Y1,Y2,s. Y1 ⪤*[R, ⋆s] Y2 →
 124                      ∨∨ Y1 = ⋆ ∧ Y2 = ⋆
 125                       | ∃∃I1,I2,L1,L2. L1 ⪤*[R, ⋆s] L2 &
 126                                        Y1 = L1.ⓘ{I1} & Y2 = L2.ⓘ{I2}.
 127 #R * [ | #Y1 #I1 ] #Y2 #s * #f #H1 #H2
 128 [ lapply (lexs_inv_atom1 … H2) -H2 /3 width=1 by or_introl, conj/
 129 | lapply (frees_inv_sort … H1) -H1 #Hf
 130   elim (isid_inv_gen … Hf) -Hf #g #Hg #H destruct
 131   elim (lexs_inv_push1 … H2) -H2 #I2 #L2 #H12 #_ #H destruct
 132   /5 width=7 by frees_sort, ex3_4_intro, ex2_intro, or_intror/
 133 ]
 134 qed-.
 135
 136 lemma lfxs_inv_zero: ∀R,Y1,Y2. Y1 ⪤*[R, #0] Y2 →
 137                      ∨∨ Y1 = ⋆ ∧ Y2 = ⋆
 138                       | ∃∃I,L1,L2,V1,V2. L1 ⪤*[R, V1] L2 & R L1 V1 V2 &
 139                                          Y1 = L1.ⓑ{I}V1 & Y2 = L2.ⓑ{I}V2
 140                       | ∃∃f,I,L1,L2. 𝐈⦃f⦄ & L1 ⪤*[cext2 R, cfull, f] L2 &
 141                                      Y1 = L1.ⓤ{I} & Y2 = L2.ⓤ{I}.
 142 #R * [ | #Y1 * #I1 [ | #X ] ] #Y2 * #f #H1 #H2
 143 [ lapply (lexs_inv_atom1 … H2) -H2 /3 width=1 by or3_intro0, conj/
 144 | elim (frees_inv_unit … H1) -H1 #g #HX #H destruct
 145   elim (lexs_inv_next1 … H2) -H2 #I2 #L2 #HL12 #H #H2 destruct
 146   >(ext2_inv_unit_sn … H) -H /3 width=8 by or3_intro2, ex4_4_intro/
 147 | elim (frees_inv_pair … H1) -H1 #g #Hg #H destruct
 148   elim (lexs_inv_next1 … H2) -H2 #Z2 #L2 #HL12 #H
 149   elim (ext2_inv_pair_sn … H) -H
 150   /4 width=9 by or3_intro1, ex4_5_intro, ex2_intro/
 151 ]
 152 qed-.
 153
 154 lemma lfxs_inv_lref: ∀R,Y1,Y2,i. Y1 ⪤*[R, #⫯i] Y2 →
 155                      ∨∨ Y1 = ⋆ ∧ Y2 = ⋆
 156                       | ∃∃I1,I2,L1,L2. L1 ⪤*[R, #i] L2 &
 157                                        Y1 = L1.ⓘ{I1} & Y2 = L2.ⓘ{I2}.
 158 #R * [ | #Y1 #I1 ] #Y2 #i * #f #H1 #H2
 159 [ lapply (lexs_inv_atom1 … H2) -H2 /3 width=1 by or_introl, conj/
 160 | elim (frees_inv_lref … H1) -H1 #g #Hg #H destruct
 161   elim (lexs_inv_push1 … H2) -H2
 162   /4 width=7 by ex3_4_intro, ex2_intro, or_intror/
 163 ]
 164 qed-.
 165
 166 lemma lfxs_inv_gref: ∀R,Y1,Y2,l. Y1 ⪤*[R, §l] Y2 →
 167                      ∨∨ Y1 = ⋆ ∧ Y2 = ⋆
 168                       | ∃∃I1,I2,L1,L2. L1 ⪤*[R, §l] L2 &
 169                                        Y1 = L1.ⓘ{I1} & Y2 = L2.ⓘ{I2}.
 170 #R * [ | #Y1 #I1 ] #Y2 #l * #f #H1 #H2
 171 [ lapply (lexs_inv_atom1 … H2) -H2 /3 width=1 by or_introl, conj/
 172 | lapply (frees_inv_gref … H1) -H1 #Hf
 173   elim (isid_inv_gen … Hf) -Hf #g #Hg #H destruct
 174   elim (lexs_inv_push1 … H2) -H2 #I2 #L2 #H12 #_ #H destruct
 175   /5 width=7 by frees_gref, ex3_4_intro, ex2_intro, or_intror/
 176 ]
 177 qed-.
 178
 179 (* Basic_2A1: uses: llpx_sn_inv_bind llpx_sn_inv_bind_O *)
 180 lemma lfxs_inv_bind: ∀R,p,I,L1,L2,V1,V2,T. L1 ⪤*[R, ⓑ{p,I}V1.T] L2 → R L1 V1 V2 →
 181                      L1 ⪤*[R, V1] L2 ∧ L1.ⓑ{I}V1 ⪤*[R, T] L2.ⓑ{I}V2.
 182 #R #p #I #L1 #L2 #V1 #V2 #T * #f #Hf #HL #HV elim (frees_inv_bind … Hf) -Hf
 183 /6 width=6 by sle_lexs_trans, lexs_inv_tl, ext2_pair, sor_inv_sle_dx, sor_inv_sle_sn, ex2_intro, conj/
 184 qed-.
 185
 186 (* Basic_2A1: uses: llpx_sn_inv_flat *)
 187 lemma lfxs_inv_flat: ∀R,I,L1,L2,V,T. L1 ⪤*[R, ⓕ{I}V.T] L2 →
 188                      L1 ⪤*[R, V] L2 ∧ L1 ⪤*[R, T] L2.
 189 #R #I #L1 #L2 #V #T * #f #Hf #HL elim (frees_inv_flat … Hf) -Hf
 190 /5 width=6 by sle_lexs_trans, sor_inv_sle_dx, sor_inv_sle_sn, ex2_intro, conj/
 191 qed-.
 192
 193 (* Advanced inversion lemmas ************************************************)
 194
 195 lemma lfxs_inv_sort_bind_sn: ∀R,I1,K1,L2,s. K1.ⓘ{I1} ⪤*[R, ⋆s] L2 →
 196                              ∃∃I2,K2. K1 ⪤*[R, ⋆s] K2 & L2 = K2.ⓘ{I2}.
 197 #R #I1 #K1 #L2 #s #H elim (lfxs_inv_sort … H) -H *
 198 [ #H destruct
 199 | #Z1 #I2 #Y1 #K2 #Hs #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 200 ]
 201 qed-.
 202
 203 lemma lfxs_inv_sort_bind_dx: ∀R,I2,K2,L1,s. L1 ⪤*[R, ⋆s] K2.ⓘ{I2} →
 204                              ∃∃I1,K1. K1 ⪤*[R, ⋆s] K2 & L1 = K1.ⓘ{I1}.
 205 #R #I2 #K2 #L1 #s #H elim (lfxs_inv_sort … H) -H *
 206 [ #_ #H destruct
 207 | #I1 #Z2 #K1 #Y2 #Hs #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 208 ]
 209 qed-.
 210
 211 lemma lfxs_inv_zero_pair_sn: ∀R,I,L2,K1,V1. K1.ⓑ{I}V1 ⪤*[R, #0] L2 →
 212                              ∃∃K2,V2. K1 ⪤*[R, V1] K2 & R K1 V1 V2 &
 213                                       L2 = K2.ⓑ{I}V2.
 214 #R #I #L2 #K1 #V1 #H elim (lfxs_inv_zero … H) -H *
 215 [ #H destruct
 216 | #Z #Y1 #K2 #X1 #V2 #HK12 #HV12 #H1 #H2 destruct
 217   /2 width=5 by ex3_2_intro/
 218 | #f #Z #Y1 #Y2 #_ #_ #H destruct
 219 ]
 220 qed-.
 221
 222 lemma lfxs_inv_zero_pair_dx: ∀R,I,L1,K2,V2. L1 ⪤*[R, #0] K2.ⓑ{I}V2 →
 223                              ∃∃K1,V1. K1 ⪤*[R, V1] K2 & R K1 V1 V2 &
 224                                       L1 = K1.ⓑ{I}V1.
 225 #R #I #L1 #K2 #V2 #H elim (lfxs_inv_zero … H) -H *
 226 [ #_ #H destruct
 227 | #Z #K1 #Y2 #V1 #X2 #HK12 #HV12 #H1 #H2 destruct
 228   /2 width=5 by ex3_2_intro/
 229 | #f #Z #Y1 #Y2 #_ #_ #_ #H destruct
 230 ]
 231 qed-.
 232
 233 lemma lfxs_inv_zero_unit_sn: ∀R,I,K1,L2. K1.ⓤ{I} ⪤*[R, #0] L2 →
 234                              ∃∃f,K2. 𝐈⦃f⦄ & K1 ⪤*[cext2 R, cfull, f] K2 &
 235                                      L2 = K2.ⓤ{I}.
 236 #R #I #K1 #L2 #H elim (lfxs_inv_zero … H) -H *
 237 [ #H destruct
 238 | #Z #Y1 #Y2 #X1 #X2 #_ #_ #H destruct
 239 | #f #Z #Y1 #K2 #Hf #HK12 #H1 #H2 destruct /2 width=5 by ex3_2_intro/
 240 ]
 241 qed-.
 242
 243 lemma lfxs_inv_zero_unit_dx: ∀R,I,L1,K2. L1 ⪤*[R, #0] K2.ⓤ{I} →
 244                              ∃∃f,K1. 𝐈⦃f⦄ & K1 ⪤*[cext2 R, cfull, f] K2 &
 245                                      L1 = K1.ⓤ{I}.
 246 #R #I #L1 #K2 #H elim (lfxs_inv_zero … H) -H *
 247 [ #_ #H destruct
 248 | #Z #Y1 #Y2 #X1 #X2 #_ #_ #_ #H destruct
 249 | #f #Z #K1 #Y2 #Hf #HK12 #H1 #H2 destruct /2 width=5 by ex3_2_intro/
 250 ]
 251 qed-.
 252
 253 lemma lfxs_inv_lref_bind_sn: ∀R,I1,K1,L2,i. K1.ⓘ{I1} ⪤*[R, #⫯i] L2 →
 254                              ∃∃I2,K2. K1 ⪤*[R, #i] K2 & L2 = K2.ⓘ{I2}.
 255 #R #I1 #K1 #L2 #i #H elim (lfxs_inv_lref … H) -H *
 256 [ #H destruct
 257 | #Z1 #I2 #Y1 #K2 #Hi #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 258 ]
 259 qed-.
 260
 261 lemma lfxs_inv_lref_bind_dx: ∀R,I2,K2,L1,i. L1 ⪤*[R, #⫯i] K2.ⓘ{I2} →
 262                              ∃∃I1,K1. K1 ⪤*[R, #i] K2 & L1 = K1.ⓘ{I1}.
 263 #R #I2 #K2 #L1 #i #H elim (lfxs_inv_lref … H) -H *
 264 [ #_ #H destruct
 265 | #I1 #Z2 #K1 #Y2 #Hi #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 266 ]
 267 qed-.
 268
 269 lemma lfxs_inv_gref_bind_sn: ∀R,I1,K1,L2,l. K1.ⓘ{I1} ⪤*[R, §l] L2 →
 270                              ∃∃I2,K2. K1 ⪤*[R, §l] K2 & L2 = K2.ⓘ{I2}.
 271 #R #I1 #K1 #L2 #l #H elim (lfxs_inv_gref … H) -H *
 272 [ #H destruct
 273 | #Z1 #I2 #Y1 #K2 #Hl #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 274 ]
 275 qed-.
 276
 277 lemma lfxs_inv_gref_bind_dx: ∀R,I2,K2,L1,l. L1 ⪤*[R, §l] K2.ⓘ{I2} →
 278                              ∃∃I1,K1. K1 ⪤*[R, §l] K2 & L1 = K1.ⓘ{I1}.
 279 #R #I2 #K2 #L1 #l #H elim (lfxs_inv_gref … H) -H *
 280 [ #_ #H destruct
 281 | #I1 #Z2 #K1 #Y2 #Hl #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 282 ]
 283 qed-.
 284
 285 (* Basic forward lemmas *****************************************************)
 286
 287 (* Basic_2A1: uses: llpx_sn_fwd_pair_sn llpx_sn_fwd_bind_sn llpx_sn_fwd_flat_sn *)
 288 lemma lfxs_fwd_pair_sn: ∀R,I,L1,L2,V,T. L1 ⪤*[R, ②{I}V.T] L2 → L1 ⪤*[R, V] L2.
 289 #R * [ #p ] #I #L1 #L2 #V #T * #f #Hf #HL
 290 [ elim (frees_inv_bind … Hf) | elim (frees_inv_flat … Hf) ] -Hf
 291 /4 width=6 by sle_lexs_trans, sor_inv_sle_sn, ex2_intro/
 292 qed-.
 293
 294 (* Basic_2A1: uses: llpx_sn_fwd_bind_dx llpx_sn_fwd_bind_O_dx *)
 295 lemma lfxs_fwd_bind_dx: ∀R,p,I,L1,L2,V1,V2,T. L1 ⪤*[R, ⓑ{p,I}V1.T] L2 →
 296                         R L1 V1 V2 → L1.ⓑ{I}V1 ⪤*[R, T] L2.ⓑ{I}V2.
 297 #R #p #I #L1 #L2 #V1 #V2 #T #H #HV elim (lfxs_inv_bind … H HV) -H -HV //
 298 qed-.
 299
 300 (* Basic_2A1: uses: llpx_sn_fwd_flat_dx *)
 301 lemma lfxs_fwd_flat_dx: ∀R,I,L1,L2,V,T. L1 ⪤*[R, ⓕ{I}V.T] L2 → L1 ⪤*[R, T] L2.
 302 #R #I #L1 #L2 #V #T #H elim (lfxs_inv_flat … H) -H //
 303 qed-.
 304
 305 lemma lfxs_fwd_dx: ∀R,I2,L1,K2,T. L1 ⪤*[R, T] K2.ⓘ{I2} →
 306                    ∃∃I1,K1. L1 = K1.ⓘ{I1}.
 307 #R #I2 #L1 #K2 #T * #f elim (pn_split f) * #g #Hg #_ #Hf destruct
 308 [ elim (lexs_inv_push2 … Hf) | elim (lexs_inv_next2 … Hf) ] -Hf #I1 #K1 #_ #_ #H destruct
 309 /2 width=3 by ex1_2_intro/
 310 qed-.
 311
 312 (* Basic_2A1: removed theorems 9:
 313               llpx_sn_skip llpx_sn_lref llpx_sn_free
 314               llpx_sn_fwd_lref
 315               llpx_sn_Y llpx_sn_ge_up llpx_sn_ge
 316               llpx_sn_fwd_drop_sn llpx_sn_fwd_drop_dx
 317 *)