matita/matita/contribs/lambdadelta/basic_2/static/lfxs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/relocation/rtmap_id.ma".
  16 include "basic_2/notation/relations/relationstar_4.ma".
  17 include "basic_2/relocation/lexs.ma".
  18 include "basic_2/static/frees.ma".
  19
  20 (* GENERIC EXTENSION ON REFERRED ENTRIES OF A CONTEXT-SENSITIVE REALTION ****)
  21
  22 definition lfxs (R) (T): relation lenv ≝
  23                 λL1,L2. ∃∃f. L1 ⊢ 𝐅*⦃T⦄ ≡ f & L1 ⦻*[R, cfull, f] L2.
  24
  25 interpretation "generic extension on referred entries (local environment)"
  26    'RelationStar R T L1 L2 = (lfxs R T L1 L2).
  27
  28 definition R_frees_confluent: predicate (relation3 lenv term term) ≝
  29                               λRN.
  30                               ∀f1,L,T1. L ⊢ 𝐅*⦃T1⦄ ≡ f1 → ∀T2. RN L T1 T2 →
  31                               ∃∃f2. L ⊢ 𝐅*⦃T2⦄ ≡ f2 & f2 ⊆ f1.
  32
  33 definition lexs_frees_confluent: relation (relation3 lenv term term) ≝
  34                                  λRN,RP.
  35                                  ∀f1,L1,T. L1 ⊢ 𝐅*⦃T⦄ ≡ f1 →
  36                                  ∀L2. L1 ⦻*[RN, RP, f1] L2 →
  37                                  ∃∃f2. L2 ⊢ 𝐅*⦃T⦄ ≡ f2 & f2 ⊆ f1.
  38
  39 definition R_confluent2_lfxs: relation4 (relation3 lenv term term)
  40                                         (relation3 lenv term term) … ≝
  41                               λR1,R2,RP1,RP2.
  42                               ∀L0,T0,T1. R1 L0 T0 T1 → ∀T2. R2 L0 T0 T2 →
  43                               ∀L1. L0 ⦻*[RP1, T0] L1 → ∀L2. L0 ⦻*[RP2, T0] L2 →
  44                               ∃∃T. R2 L1 T1 T & R1 L2 T2 T.
  45
  46 (* Basic properties ***********************************************************)
  47
  48 lemma lfxs_atom: ∀R,I. ⋆ ⦻*[R, ⓪{I}] ⋆.
  49 /3 width=3 by lexs_atom, frees_atom, ex2_intro/
  50 qed.
  51
  52 lemma lfxs_sort: ∀R,I,L1,L2,V1,V2,s.
  53                  L1 ⦻*[R, ⋆s] L2 → L1.ⓑ{I}V1 ⦻*[R, ⋆s] L2.ⓑ{I}V2.
  54 #R #I #L1 #L2 #V1 #V2 #s * /3 width=3 by lexs_push, frees_sort, ex2_intro/
  55 qed.
  56
  57 lemma lfxs_zero: ∀R,I,L1,L2,V1,V2. L1 ⦻*[R, V1] L2 →
  58                  R L1 V1 V2 → L1.ⓑ{I}V1 ⦻*[R, #0] L2.ⓑ{I}V2.
  59 #R #I #L1 #L2 #V1 #V2 * /3 width=3 by lexs_next, frees_zero, ex2_intro/
  60 qed.
  61
  62 lemma lfxs_lref: ∀R,I,L1,L2,V1,V2,i.
  63                  L1 ⦻*[R, #i] L2 → L1.ⓑ{I}V1 ⦻*[R, #⫯i] L2.ⓑ{I}V2.
  64 #R #I #L1 #L2 #V1 #V2 #i * /3 width=3 by lexs_push, frees_lref, ex2_intro/
  65 qed.
  66
  67 lemma lfxs_gref: ∀R,I,L1,L2,V1,V2,l.
  68                  L1 ⦻*[R, §l] L2 → L1.ⓑ{I}V1 ⦻*[R, §l] L2.ⓑ{I}V2.
  69 #R #I #L1 #L2 #V1 #V2 #l * /3 width=3 by lexs_push, frees_gref, ex2_intro/
  70 qed.
  71
  72 lemma lfxs_pair_repl_dx: ∀R,I,L1,L2,T,V,V1.
  73                          L1.ⓑ{I}V ⦻*[R, T] L2.ⓑ{I}V1 →
  74                          ∀V2. R L1 V V2 →
  75                          L1.ⓑ{I}V ⦻*[R, T] L2.ⓑ{I}V2.
  76 #R #I #L1 #L2 #T #V #V1 * #f #Hf #HL12 #V2 #HR
  77 /3 width=5 by lexs_pair_repl, ex2_intro/
  78 qed-.
  79
  80 lemma lfxs_sym: ∀R. lexs_frees_confluent R cfull →
  81                 (∀L1,L2,T1,T2. R L1 T1 T2 → R L2 T2 T1) →
  82                 ∀T. symmetric … (lfxs R T).
  83 #R #H1R #H2R #T #L1 #L2 * #f1 #Hf1 #HL12 elim (H1R … Hf1 … HL12) -Hf1
  84 /4 width=5 by sle_lexs_trans, lexs_sym, ex2_intro/
  85 qed-.
  86
  87 lemma lfxs_co: ∀R1,R2. (∀L,T1,T2. R1 L T1 T2 → R2 L T1 T2) →
  88                ∀L1,L2,T. L1 ⦻*[R1, T] L2 → L1 ⦻*[R2, T] L2.
  89 #R1 #R2 #HR #L1 #L2 #T * /4 width=7 by lexs_co, ex2_intro/
  90 qed-.
  91
  92 (* Basic inversion lemmas ***************************************************)
  93
  94 lemma lfxs_inv_atom_sn: ∀R,I,Y2. ⋆ ⦻*[R, ⓪{I}] Y2 → Y2 = ⋆.
  95 #R #I #Y2 * /2 width=4 by lexs_inv_atom1/
  96 qed-.
  97
  98 lemma lfxs_inv_atom_dx: ∀R,I,Y1. Y1 ⦻*[R, ⓪{I}] ⋆ → Y1 = ⋆.
  99 #R #I #Y1 * /2 width=4 by lexs_inv_atom2/
 100 qed-.
 101
 102 lemma lfxs_inv_sort: ∀R,Y1,Y2,s. Y1 ⦻*[R, ⋆s] Y2 →
 103                      (Y1 = ⋆ ∧ Y2 = ⋆) ∨
 104                      ∃∃I,L1,L2,V1,V2. L1 ⦻*[R, ⋆s] L2 &
 105                                       Y1 = L1.ⓑ{I}V1 & Y2 = L2.ⓑ{I}V2.
 106 #R * [ | #Y1 #I #V1 ] #Y2 #s * #f #H1 #H2
 107 [ lapply (lexs_inv_atom1 … H2) -H2 /3 width=1 by or_introl, conj/
 108 | lapply (frees_inv_sort … H1) -H1 #Hf
 109   elim (isid_inv_gen … Hf) -Hf #g #Hg #H destruct
 110   elim (lexs_inv_push1 … H2) -H2 #L2 #V2 #H12 #_ #H destruct
 111   /5 width=8 by frees_sort_gen, ex3_5_intro, ex2_intro, or_intror/
 112 ]
 113 qed-.
 114
 115 lemma lfxs_inv_zero: ∀R,Y1,Y2. Y1 ⦻*[R, #0] Y2 →
 116                      (Y1 = ⋆ ∧ Y2 = ⋆) ∨
 117                      ∃∃I,L1,L2,V1,V2. L1 ⦻*[R, V1] L2 & R L1 V1 V2 &
 118                                       Y1 = L1.ⓑ{I}V1 & Y2 = L2.ⓑ{I}V2.
 119 #R #Y1 #Y2 * #f #H1 #H2 elim (frees_inv_zero … H1) -H1 *
 120 [ #H #_ lapply (lexs_inv_atom1_aux … H2 H) -H2 /3 width=1 by or_introl, conj/
 121 | #I1 #L1 #V1 #g #HV1 #HY1 #Hg elim (lexs_inv_next1_aux … H2 … HY1 Hg) -H2 -Hg
 122   /4 width=9 by ex4_5_intro, ex2_intro, or_intror/
 123 ]
 124 qed-.
 125
 126 lemma lfxs_inv_lref: ∀R,Y1,Y2,i. Y1 ⦻*[R, #⫯i] Y2 →
 127                      (Y1 = ⋆ ∧ Y2 = ⋆) ∨
 128                      ∃∃I,L1,L2,V1,V2. L1 ⦻*[R, #i] L2 &
 129                                       Y1 = L1.ⓑ{I}V1 & Y2 = L2.ⓑ{I}V2.
 130 #R #Y1 #Y2 #i * #f #H1 #H2 elim (frees_inv_lref … H1) -H1 *
 131 [ #H #_ lapply (lexs_inv_atom1_aux … H2 H) -H2 /3 width=1 by or_introl, conj/
 132 | #I1 #L1 #V1 #g #HV1 #HY1 #Hg elim (lexs_inv_push1_aux … H2 … HY1 Hg) -H2 -Hg
 133   /4 width=8 by ex3_5_intro, ex2_intro, or_intror/
 134 ]
 135 qed-.
 136
 137 lemma lfxs_inv_gref: ∀R,Y1,Y2,l. Y1 ⦻*[R, §l] Y2 →
 138                      (Y1 = ⋆ ∧ Y2 = ⋆) ∨
 139                      ∃∃I,L1,L2,V1,V2. L1 ⦻*[R, §l] L2 &
 140                                       Y1 = L1.ⓑ{I}V1 & Y2 = L2.ⓑ{I}V2.
 141 #R * [ | #Y1 #I #V1 ] #Y2 #l * #f #H1 #H2
 142 [ lapply (lexs_inv_atom1 … H2) -H2 /3 width=1 by or_introl, conj/
 143 | lapply (frees_inv_gref … H1) -H1 #Hf
 144   elim (isid_inv_gen … Hf) -Hf #g #Hg #H destruct
 145   elim (lexs_inv_push1 … H2) -H2 #L2 #V2 #H12 #_ #H destruct
 146   /5 width=8 by frees_gref_gen, ex3_5_intro, ex2_intro, or_intror/
 147 ]
 148 qed-.
 149
 150 lemma lfxs_inv_bind: ∀R,p,I,L1,L2,V1,V2,T. L1 ⦻*[R, ⓑ{p,I}V1.T] L2 → R L1 V1 V2 →
 151                      L1 ⦻*[R, V1] L2 ∧ L1.ⓑ{I}V1 ⦻*[R, T] L2.ⓑ{I}V2.
 152 #R #p #I #L1 #L2 #V1 #V2 #T * #f #Hf #HL #HV elim (frees_inv_bind … Hf) -Hf
 153 /6 width=6 by sle_lexs_trans, lexs_inv_tl, sor_inv_sle_dx, sor_inv_sle_sn, ex2_intro, conj/
 154 qed-.
 155
 156 lemma lfxs_inv_flat: ∀R,I,L1,L2,V,T. L1 ⦻*[R, ⓕ{I}V.T] L2 →
 157                      L1 ⦻*[R, V] L2 ∧ L1 ⦻*[R, T] L2.
 158 #R #I #L1 #L2 #V #T * #f #Hf #HL elim (frees_inv_flat … Hf) -Hf
 159 /5 width=6 by sle_lexs_trans, sor_inv_sle_dx, sor_inv_sle_sn, ex2_intro, conj/
 160 qed-.
 161
 162 (* Advanced inversion lemmas ************************************************)
 163
 164 lemma lfxs_inv_sort_pair_sn: ∀R,I,Y2,L1,V1,s. L1.ⓑ{I}V1 ⦻*[R, ⋆s] Y2 →
 165                              ∃∃L2,V2. L1 ⦻*[R, ⋆s] L2 & Y2 = L2.ⓑ{I}V2.
 166 #R #I #Y2 #L1 #V1 #s #H elim (lfxs_inv_sort … H) -H *
 167 [ #H destruct
 168 | #J #Y1 #L2 #X1 #V2 #Hs #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 169 ]
 170 qed-.
 171
 172 lemma lfxs_inv_sort_pair_dx: ∀R,I,Y1,L2,V2,s. Y1 ⦻*[R, ⋆s] L2.ⓑ{I}V2 →
 173                              ∃∃L1,V1. L1 ⦻*[R, ⋆s] L2 & Y1 = L1.ⓑ{I}V1.
 174 #R #I #Y1 #L2 #V2 #s #H elim (lfxs_inv_sort … H) -H *
 175 [ #_ #H destruct
 176 | #J #L1 #Y2 #V1 #X2 #Hs #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 177 ]
 178 qed-.
 179
 180 lemma lfxs_inv_zero_pair_sn: ∀R,I,Y2,L1,V1. L1.ⓑ{I}V1 ⦻*[R, #0] Y2 →
 181                              ∃∃L2,V2. L1 ⦻*[R, V1] L2 & R L1 V1 V2 &
 182                                       Y2 = L2.ⓑ{I}V2.
 183 #R #I #Y2 #L1 #V1 #H elim (lfxs_inv_zero … H) -H *
 184 [ #H destruct
 185 | #J #Y1 #L2 #X1 #V2 #HV1 #HV12 #H1 #H2 destruct
 186   /2 width=5 by ex3_2_intro/
 187 ]
 188 qed-.
 189
 190 lemma lfxs_inv_zero_pair_dx: ∀R,I,Y1,L2,V2. Y1 ⦻*[R, #0] L2.ⓑ{I}V2 →
 191                              ∃∃L1,V1. L1 ⦻*[R, V1] L2 & R L1 V1 V2 &
 192                                       Y1 = L1.ⓑ{I}V1.
 193 #R #I #Y1 #L2 #V2 #H elim (lfxs_inv_zero … H) -H *
 194 [ #_ #H destruct
 195 | #J #L1 #Y2 #V1 #X2 #HV1 #HV12 #H1 #H2 destruct
 196   /2 width=5 by ex3_2_intro/
 197 ]
 198 qed-.
 199
 200 lemma lfxs_inv_lref_pair_sn: ∀R,I,Y2,L1,V1,i. L1.ⓑ{I}V1 ⦻*[R, #⫯i] Y2 →
 201                              ∃∃L2,V2. L1 ⦻*[R, #i] L2 & Y2 = L2.ⓑ{I}V2.
 202 #R #I #Y2 #L1 #V1 #i #H elim (lfxs_inv_lref … H) -H *
 203 [ #H destruct
 204 | #J #Y1 #L2 #X1 #V2 #Hi #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 205 ]
 206 qed-.
 207
 208 lemma lfxs_inv_lref_pair_dx: ∀R,I,Y1,L2,V2,i. Y1 ⦻*[R, #⫯i] L2.ⓑ{I}V2 →
 209                              ∃∃L1,V1. L1 ⦻*[R, #i] L2 & Y1 = L1.ⓑ{I}V1.
 210 #R #I #Y1 #L2 #V2 #i #H elim (lfxs_inv_lref … H) -H *
 211 [ #_ #H destruct
 212 | #J #L1 #Y2 #V1 #X2 #Hi #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 213 ]
 214 qed-.
 215
 216 lemma lfxs_inv_gref_pair_sn: ∀R,I,Y2,L1,V1,l. L1.ⓑ{I}V1 ⦻*[R, §l] Y2 →
 217                              ∃∃L2,V2. L1 ⦻*[R, §l] L2 & Y2 = L2.ⓑ{I}V2.
 218 #R #I #Y2 #L1 #V1 #l #H elim (lfxs_inv_gref … H) -H *
 219 [ #H destruct
 220 | #J #Y1 #L2 #X1 #V2 #Hl #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 221 ]
 222 qed-.
 223
 224 lemma lfxs_inv_gref_pair_dx: ∀R,I,Y1,L2,V2,l. Y1 ⦻*[R, §l] L2.ⓑ{I}V2 →
 225                              ∃∃L1,V1. L1 ⦻*[R, §l] L2 & Y1 = L1.ⓑ{I}V1.
 226 #R #I #Y1 #L2 #V2 #l #H elim (lfxs_inv_gref … H) -H *
 227 [ #_ #H destruct
 228 | #J #L1 #Y2 #V1 #X2 #Hl #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 229 ]
 230 qed-.
 231
 232 (* Basic forward lemmas *****************************************************)
 233
 234 lemma lfxs_fwd_bind_sn: ∀R,p,I,L1,L2,V,T. L1 ⦻*[R, ⓑ{p,I}V.T] L2 → L1 ⦻*[R, V] L2.
 235 #R #p #I #L1 #L2 #V #T * #f #Hf #HL elim (frees_inv_bind … Hf) -Hf
 236 /4 width=6 by sle_lexs_trans, sor_inv_sle_sn, ex2_intro/
 237 qed-.
 238
 239 lemma lfxs_fwd_bind_dx: ∀R,p,I,L1,L2,V1,V2,T. L1 ⦻*[R, ⓑ{p,I}V1.T] L2 →
 240                         R L1 V1 V2 → L1.ⓑ{I}V1 ⦻*[R, T] L2.ⓑ{I}V2.
 241 #R #p #I #L1 #L2 #V1 #V2 #T #H #HV elim (lfxs_inv_bind … H HV) -H -HV //
 242 qed-.
 243
 244 lemma lfxs_fwd_flat_sn: ∀R,I,L1,L2,V,T. L1 ⦻*[R, ⓕ{I}V.T] L2 → L1 ⦻*[R, V] L2.
 245 #R #I #L1 #L2 #V #T #H elim (lfxs_inv_flat … H) -H //
 246 qed-.
 247
 248 lemma lfxs_fwd_flat_dx: ∀R,I,L1,L2,V,T. L1 ⦻*[R, ⓕ{I}V.T] L2 → L1 ⦻*[R, T] L2.
 249 #R #I #L1 #L2 #V #T #H elim (lfxs_inv_flat … H) -H //
 250 qed-.
 251
 252 lemma lfxs_fwd_pair_sn: ∀R,I,L1,L2,V,T. L1 ⦻*[R, ②{I}V.T] L2 → L1 ⦻*[R, V] L2.
 253 #R * /2 width=4 by lfxs_fwd_flat_sn, lfxs_fwd_bind_sn/
 254 qed-.
 255
 256 (* Basic_2A1: removed theorems 24:
 257               llpx_sn_sort llpx_sn_skip llpx_sn_lref llpx_sn_free llpx_sn_gref
 258               llpx_sn_bind llpx_sn_flat
 259               llpx_sn_inv_bind llpx_sn_inv_flat
 260               llpx_sn_fwd_lref llpx_sn_fwd_pair_sn llpx_sn_fwd_length
 261               llpx_sn_fwd_bind_sn llpx_sn_fwd_bind_dx llpx_sn_fwd_flat_sn llpx_sn_fwd_flat_dx
 262               llpx_sn_refl llpx_sn_Y llpx_sn_bind_O llpx_sn_ge_up llpx_sn_ge llpx_sn_co
 263               llpx_sn_fwd_drop_sn llpx_sn_fwd_drop_dx
 264 *)