matita/matita/contribs/lambdadelta/basic_2/static/lfxs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/relocation/rtmap_id.ma".
  16 include "basic_2/notation/relations/relationstar_4.ma".
  17 include "basic_2/syntax/lenv_ext2.ma".
  18 include "basic_2/relocation/lexs.ma".
  19 include "basic_2/static/frees.ma".
  20
  21 (* GENERIC EXTENSION ON REFERRED ENTRIES OF A CONTEXT-SENSITIVE REALTION ****)
  22
  23 definition lfxs (R) (T): relation lenv ≝
  24                 λL1,L2. ∃∃f. L1 ⊢ 𝐅*⦃T⦄ ≡ f & L1 ⪤*[cext2 R, cfull, f] L2.
  25
  26 interpretation "generic extension on referred entries (local environment)"
  27    'RelationStar R T L1 L2 = (lfxs R T L1 L2).
  28
  29 definition R_frees_confluent: predicate (relation3 …) ≝
  30                               λRN.
  31                               ∀f1,L,T1. L ⊢ 𝐅*⦃T1⦄ ≡ f1 → ∀T2. RN L T1 T2 →
  32                               ∃∃f2. L ⊢ 𝐅*⦃T2⦄ ≡ f2 & f2 ⊆ f1.
  33
  34 definition lexs_frees_confluent: relation (relation3 …) ≝
  35                                  λRN,RP.
  36                                  ∀f1,L1,T. L1 ⊢ 𝐅*⦃T⦄ ≡ f1 →
  37                                  ∀L2. L1 ⪤*[RN, RP, f1] L2 →
  38                                  ∃∃f2. L2 ⊢ 𝐅*⦃T⦄ ≡ f2 & f2 ⊆ f1.
  39
  40 definition R_confluent2_lfxs: relation4 (relation3 lenv term term)
  41                                         (relation3 lenv term term) … ≝
  42                               λR1,R2,RP1,RP2.
  43                               ∀L0,T0,T1. R1 L0 T0 T1 → ∀T2. R2 L0 T0 T2 →
  44                               ∀L1. L0 ⪤*[RP1, T0] L1 → ∀L2. L0 ⪤*[RP2, T0] L2 →
  45                               ∃∃T. R2 L1 T1 T & R1 L2 T2 T.
  46
  47 (* Basic inversion lemmas ***************************************************)
  48
  49 lemma lfxs_inv_atom_sn: ∀R,Y2,T. ⋆ ⪤*[R, T] Y2 → Y2 = ⋆.
  50 #R #Y2 #T * /2 width=4 by lexs_inv_atom1/
  51 qed-.
  52
  53 lemma lfxs_inv_atom_dx: ∀R,Y1,T. Y1 ⪤*[R, T] ⋆ → Y1 = ⋆.
  54 #R #I #Y1 * /2 width=4 by lexs_inv_atom2/
  55 qed-.
  56
  57 lemma lfxs_inv_sort: ∀R,Y1,Y2,s. Y1 ⪤*[R, ⋆s] Y2 →
  58                      ∨∨ Y1 = ⋆ ∧ Y2 = ⋆
  59                       | ∃∃I1,I2,L1,L2. L1 ⪤*[R, ⋆s] L2 &
  60                                        Y1 = L1.ⓘ{I1} & Y2 = L2.ⓘ{I2}.
  61 #R * [ | #Y1 #I1 ] #Y2 #s * #f #H1 #H2
  62 [ lapply (lexs_inv_atom1 … H2) -H2 /3 width=1 by or_introl, conj/
  63 | lapply (frees_inv_sort … H1) -H1 #Hf
  64   elim (isid_inv_gen … Hf) -Hf #g #Hg #H destruct
  65   elim (lexs_inv_push1 … H2) -H2 #I2 #L2 #H12 #_ #H destruct
  66   /5 width=7 by frees_sort, ex3_4_intro, ex2_intro, or_intror/
  67 ]
  68 qed-.
  69
  70 lemma lfxs_inv_zero: ∀R,Y1,Y2. Y1 ⪤*[R, #0] Y2 →
  71                      ∨∨ Y1 = ⋆ ∧ Y2 = ⋆
  72                       | ∃∃I,L1,L2,V1,V2. L1 ⪤*[R, V1] L2 & R L1 V1 V2 &
  73                                          Y1 = L1.ⓑ{I}V1 & Y2 = L2.ⓑ{I}V2
  74                       | ∃∃f,I,L1,L2. 𝐈⦃f⦄ & L1 ⪤*[cext2 R, cfull, f] L2 &
  75                                      Y1 = L1.ⓤ{I} & Y2 = L2.ⓤ{I}.
  76 #R * [ | #Y1 * #I1 [ | #X ] ] #Y2 * #f #H1 #H2
  77 [ lapply (lexs_inv_atom1 … H2) -H2 /3 width=1 by or3_intro0, conj/
  78 | elim (frees_inv_unit … H1) -H1 #g #HX #H destruct
  79   elim (lexs_inv_next1 … H2) -H2 #I2 #L2 #HL12 #H #H2 destruct
  80   >(ext2_inv_unit_sn … H) -H /3 width=8 by or3_intro2, ex4_4_intro/
  81 | elim (frees_inv_pair … H1) -H1 #g #Hg #H destruct
  82   elim (lexs_inv_next1 … H2) -H2 #Z2 #L2 #HL12 #H
  83   elim (ext2_inv_pair_sn … H) -H
  84   /4 width=9 by or3_intro1, ex4_5_intro, ex2_intro/
  85 ]
  86 qed-.
  87
  88 lemma lfxs_inv_lref: ∀R,Y1,Y2,i. Y1 ⪤*[R, #⫯i] Y2 →
  89                      ∨∨ Y1 = ⋆ ∧ Y2 = ⋆
  90                       | ∃∃I1,I2,L1,L2. L1 ⪤*[R, #i] L2 &
  91                                        Y1 = L1.ⓘ{I1} & Y2 = L2.ⓘ{I2}.
  92 #R * [ | #Y1 #I1 ] #Y2 #i * #f #H1 #H2
  93 [ lapply (lexs_inv_atom1 … H2) -H2 /3 width=1 by or_introl, conj/
  94 | elim (frees_inv_lref … H1) -H1 #g #Hg #H destruct
  95   elim (lexs_inv_push1 … H2) -H2
  96   /4 width=7 by ex3_4_intro, ex2_intro, or_intror/
  97 ]
  98 qed-.
  99
 100 lemma lfxs_inv_gref: ∀R,Y1,Y2,l. Y1 ⪤*[R, §l] Y2 →
 101                      ∨∨ Y1 = ⋆ ∧ Y2 = ⋆
 102                       | ∃∃I1,I2,L1,L2. L1 ⪤*[R, §l] L2 &
 103                                        Y1 = L1.ⓘ{I1} & Y2 = L2.ⓘ{I2}.
 104 #R * [ | #Y1 #I1 ] #Y2 #l * #f #H1 #H2
 105 [ lapply (lexs_inv_atom1 … H2) -H2 /3 width=1 by or_introl, conj/
 106 | lapply (frees_inv_gref … H1) -H1 #Hf
 107   elim (isid_inv_gen … Hf) -Hf #g #Hg #H destruct
 108   elim (lexs_inv_push1 … H2) -H2 #I2 #L2 #H12 #_ #H destruct
 109   /5 width=7 by frees_gref, ex3_4_intro, ex2_intro, or_intror/
 110 ]
 111 qed-.
 112
 113 (* Basic_2A1: uses: llpx_sn_inv_bind llpx_sn_inv_bind_O *)
 114 lemma lfxs_inv_bind: ∀R,p,I,L1,L2,V1,V2,T. L1 ⪤*[R, ⓑ{p,I}V1.T] L2 → R L1 V1 V2 →
 115                      L1 ⪤*[R, V1] L2 ∧ L1.ⓑ{I}V1 ⪤*[R, T] L2.ⓑ{I}V2.
 116 #R #p #I #L1 #L2 #V1 #V2 #T * #f #Hf #HL #HV elim (frees_inv_bind … Hf) -Hf
 117 /6 width=6 by sle_lexs_trans, lexs_inv_tl, ext2_pair, sor_inv_sle_dx, sor_inv_sle_sn, ex2_intro, conj/
 118 qed-.
 119
 120 (* Basic_2A1: uses: llpx_sn_inv_flat *)
 121 lemma lfxs_inv_flat: ∀R,I,L1,L2,V,T. L1 ⪤*[R, ⓕ{I}V.T] L2 →
 122                      L1 ⪤*[R, V] L2 ∧ L1 ⪤*[R, T] L2.
 123 #R #I #L1 #L2 #V #T * #f #Hf #HL elim (frees_inv_flat … Hf) -Hf
 124 /5 width=6 by sle_lexs_trans, sor_inv_sle_dx, sor_inv_sle_sn, ex2_intro, conj/
 125 qed-.
 126
 127 (* Advanced inversion lemmas ************************************************)
 128
 129 lemma lfxs_inv_sort_bind_sn: ∀R,I1,K1,L2,s. K1.ⓘ{I1} ⪤*[R, ⋆s] L2 →
 130                              ∃∃I2,K2. K1 ⪤*[R, ⋆s] K2 & L2 = K2.ⓘ{I2}.
 131 #R #I1 #K1 #L2 #s #H elim (lfxs_inv_sort … H) -H *
 132 [ #H destruct
 133 | #Z1 #I2 #Y1 #K2 #Hs #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 134 ]
 135 qed-.
 136
 137 lemma lfxs_inv_sort_bind_dx: ∀R,I2,K2,L1,s. L1 ⪤*[R, ⋆s] K2.ⓘ{I2} →
 138                              ∃∃I1,K1. K1 ⪤*[R, ⋆s] K2 & L1 = K1.ⓘ{I1}.
 139 #R #I2 #K2 #L1 #s #H elim (lfxs_inv_sort … H) -H *
 140 [ #_ #H destruct
 141 | #I1 #Z2 #K1 #Y2 #Hs #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 142 ]
 143 qed-.
 144
 145 lemma lfxs_inv_zero_pair_sn: ∀R,I,L2,K1,V1. K1.ⓑ{I}V1 ⪤*[R, #0] L2 →
 146                              ∃∃K2,V2. K1 ⪤*[R, V1] K2 & R K1 V1 V2 &
 147                                       L2 = K2.ⓑ{I}V2.
 148 #R #I #L2 #K1 #V1 #H elim (lfxs_inv_zero … H) -H *
 149 [ #H destruct
 150 | #Z #Y1 #K2 #X1 #V2 #HK12 #HV12 #H1 #H2 destruct
 151   /2 width=5 by ex3_2_intro/
 152 | #f #Z #Y1 #Y2 #_ #_ #H destruct
 153 ]
 154 qed-.
 155
 156 lemma lfxs_inv_zero_pair_dx: ∀R,I,L1,K2,V2. L1 ⪤*[R, #0] K2.ⓑ{I}V2 →
 157                              ∃∃K1,V1. K1 ⪤*[R, V1] K2 & R K1 V1 V2 &
 158                                       L1 = K1.ⓑ{I}V1.
 159 #R #I #L1 #K2 #V2 #H elim (lfxs_inv_zero … H) -H *
 160 [ #_ #H destruct
 161 | #Z #K1 #Y2 #V1 #X2 #HK12 #HV12 #H1 #H2 destruct
 162   /2 width=5 by ex3_2_intro/
 163 | #f #Z #Y1 #Y2 #_ #_ #_ #H destruct
 164 ]
 165 qed-.
 166
 167 lemma lfxs_inv_zero_unit_sn: ∀R,I,K1,L2. K1.ⓤ{I} ⪤*[R, #0] L2 →
 168                              ∃∃f,K2. 𝐈⦃f⦄ & K1 ⪤*[cext2 R, cfull, f] K2 &
 169                                      L2 = K2.ⓤ{I}.
 170 #R #I #K1 #L2 #H elim (lfxs_inv_zero … H) -H *
 171 [ #H destruct
 172 | #Z #Y1 #Y2 #X1 #X2 #_ #_ #H destruct
 173 | #f #Z #Y1 #K2 #Hf #HK12 #H1 #H2 destruct /2 width=5 by ex3_2_intro/
 174 ]
 175 qed-.
 176
 177 lemma lfxs_inv_zero_unit_dx: ∀R,I,L1,K2. L1 ⪤*[R, #0] K2.ⓤ{I} →
 178                              ∃∃f,K1. 𝐈⦃f⦄ & K1 ⪤*[cext2 R, cfull, f] K2 &
 179                                      L1 = K1.ⓤ{I}.
 180 #R #I #L1 #K2 #H elim (lfxs_inv_zero … H) -H *
 181 [ #_ #H destruct
 182 | #Z #Y1 #Y2 #X1 #X2 #_ #_ #_ #H destruct
 183 | #f #Z #K1 #Y2 #Hf #HK12 #H1 #H2 destruct /2 width=5 by ex3_2_intro/
 184 ]
 185 qed-.
 186
 187 lemma lfxs_inv_lref_bind_sn: ∀R,I1,K1,L2,i. K1.ⓘ{I1} ⪤*[R, #⫯i] L2 →
 188                              ∃∃I2,K2. K1 ⪤*[R, #i] K2 & L2 = K2.ⓘ{I2}.
 189 #R #I1 #K1 #L2 #i #H elim (lfxs_inv_lref … H) -H *
 190 [ #H destruct
 191 | #Z1 #I2 #Y1 #K2 #Hi #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 192 ]
 193 qed-.
 194
 195 lemma lfxs_inv_lref_bind_dx: ∀R,I2,K2,L1,i. L1 ⪤*[R, #⫯i] K2.ⓘ{I2} →
 196                              ∃∃I1,K1. K1 ⪤*[R, #i] K2 & L1 = K1.ⓘ{I1}.
 197 #R #I2 #K2 #L1 #i #H elim (lfxs_inv_lref … H) -H *
 198 [ #_ #H destruct
 199 | #I1 #Z2 #K1 #Y2 #Hi #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 200 ]
 201 qed-.
 202
 203 lemma lfxs_inv_gref_bind_sn: ∀R,I1,K1,L2,l. K1.ⓘ{I1} ⪤*[R, §l] L2 →
 204                              ∃∃I2,K2. K1 ⪤*[R, §l] K2 & L2 = K2.ⓘ{I2}.
 205 #R #I1 #K1 #L2 #l #H elim (lfxs_inv_gref … H) -H *
 206 [ #H destruct
 207 | #Z1 #I2 #Y1 #K2 #Hl #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 208 ]
 209 qed-.
 210
 211 lemma lfxs_inv_gref_bind_dx: ∀R,I2,K2,L1,l. L1 ⪤*[R, §l] K2.ⓘ{I2} →
 212                              ∃∃I1,K1. K1 ⪤*[R, §l] K2 & L1 = K1.ⓘ{I1}.
 213 #R #I2 #K2 #L1 #l #H elim (lfxs_inv_gref … H) -H *
 214 [ #_ #H destruct
 215 | #I1 #Z2 #K1 #Y2 #Hl #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 216 ]
 217 qed-.
 218
 219 (* Basic forward lemmas *****************************************************)
 220
 221 lemma lfxs_fwd_zero_pair: ∀R,I,K1,K2,V1,V2.
 222                           K1.ⓑ{I}V1 ⪤*[R, #0] K2.ⓑ{I}V2 → K1 ⪤*[R, V1] K2.
 223 #R #I #K1 #K2 #V1 #V2 #H
 224 elim (lfxs_inv_zero_pair_sn … H) -H #Y #X #HK12 #_ #H destruct //
 225 qed-.
 226
 227 (* Basic_2A1: uses: llpx_sn_fwd_pair_sn llpx_sn_fwd_bind_sn llpx_sn_fwd_flat_sn *)
 228 lemma lfxs_fwd_pair_sn: ∀R,I,L1,L2,V,T. L1 ⪤*[R, ②{I}V.T] L2 → L1 ⪤*[R, V] L2.
 229 #R * [ #p ] #I #L1 #L2 #V #T * #f #Hf #HL
 230 [ elim (frees_inv_bind … Hf) | elim (frees_inv_flat … Hf) ] -Hf
 231 /4 width=6 by sle_lexs_trans, sor_inv_sle_sn, ex2_intro/
 232 qed-.
 233
 234 (* Basic_2A1: uses: llpx_sn_fwd_bind_dx llpx_sn_fwd_bind_O_dx *)
 235 lemma lfxs_fwd_bind_dx: ∀R,p,I,L1,L2,V1,V2,T. L1 ⪤*[R, ⓑ{p,I}V1.T] L2 →
 236                         R L1 V1 V2 → L1.ⓑ{I}V1 ⪤*[R, T] L2.ⓑ{I}V2.
 237 #R #p #I #L1 #L2 #V1 #V2 #T #H #HV elim (lfxs_inv_bind … H HV) -H -HV //
 238 qed-.
 239
 240 (* Basic_2A1: uses: llpx_sn_fwd_flat_dx *)
 241 lemma lfxs_fwd_flat_dx: ∀R,I,L1,L2,V,T. L1 ⪤*[R, ⓕ{I}V.T] L2 → L1 ⪤*[R, T] L2.
 242 #R #I #L1 #L2 #V #T #H elim (lfxs_inv_flat … H) -H //
 243 qed-.
 244
 245 lemma lfxs_fwd_dx: ∀R,I2,L1,K2,T. L1 ⪤*[R, T] K2.ⓘ{I2} →
 246                    ∃∃I1,K1. L1 = K1.ⓘ{I1}.
 247 #R #I2 #L1 #K2 #T * #f elim (pn_split f) * #g #Hg #_ #Hf destruct
 248 [ elim (lexs_inv_push2 … Hf) | elim (lexs_inv_next2 … Hf) ] -Hf #I1 #K1 #_ #_ #H destruct
 249 /2 width=3 by ex1_2_intro/
 250 qed-.
 251
 252 (* Basic properties *********************************************************)
 253
 254 lemma lfxs_atom: ∀R,I. ⋆ ⪤*[R, ⓪{I}] ⋆.
 255 #R * /3 width=3 by frees_sort, frees_atom, frees_gref, lexs_atom, ex2_intro/
 256 qed.
 257
 258 (* Basic_2A1: uses: llpx_sn_sort *)
 259 lemma lfxs_sort: ∀R,I1,I2,L1,L2,s.
 260                  L1 ⪤*[R, ⋆s] L2 → L1.ⓘ{I1} ⪤*[R, ⋆s] L2.ⓘ{I2}.
 261 #R #I1 #I2 #L1 #L2 #s * #f #Hf #H12
 262 lapply (frees_inv_sort … Hf) -Hf
 263 /4 width=3 by frees_sort, lexs_push, isid_push, ex2_intro/
 264 qed.
 265
 266 lemma lfxs_pair: ∀R,I,L1,L2,V1,V2. L1 ⪤*[R, V1] L2 →
 267                  R L1 V1 V2 → L1.ⓑ{I}V1 ⪤*[R, #0] L2.ⓑ{I}V2.
 268 #R #I1 #I2 #L1 #L2 #V1 *
 269 /4 width=3 by ext2_pair, frees_pair, lexs_next, ex2_intro/
 270 qed.
 271
 272 lemma lfxs_unit: ∀R,f,I,L1,L2. 𝐈⦃f⦄ → L1 ⪤*[cext2 R, cfull, f] L2 →
 273                  L1.ⓤ{I} ⪤*[R, #0] L2.ⓤ{I}.
 274 /4 width=3 by frees_unit, lexs_next, ext2_unit, ex2_intro/ qed.
 275
 276 lemma lfxs_lref: ∀R,I1,I2,L1,L2,i.
 277                  L1 ⪤*[R, #i] L2 → L1.ⓘ{I1} ⪤*[R, #⫯i] L2.ⓘ{I2}.
 278 #R #I1 #I2 #L1 #L2 #i * /3 width=3 by lexs_push, frees_lref, ex2_intro/
 279 qed.
 280
 281 (* Basic_2A1: uses: llpx_sn_gref *)
 282 lemma lfxs_gref: ∀R,I1,I2,L1,L2,l.
 283                  L1 ⪤*[R, §l] L2 → L1.ⓘ{I1} ⪤*[R, §l] L2.ⓘ{I2}.
 284 #R #I1 #I2 #L1 #L2 #l * #f #Hf #H12
 285 lapply (frees_inv_gref … Hf) -Hf
 286 /4 width=3 by frees_gref, lexs_push, isid_push, ex2_intro/
 287 qed.
 288
 289 lemma lfxs_bind_repl_dx: ∀R,I,I1,L1,L2,T.
 290                          L1.ⓘ{I} ⪤*[R, T] L2.ⓘ{I1} →
 291                          ∀I2. cext2 R L1 I I2 →
 292                          L1.ⓘ{I} ⪤*[R, T] L2.ⓘ{I2}.
 293 #R #I #I1 #L1 #L2 #T * #f #Hf #HL12 #I2 #HR
 294 /3 width=5 by lexs_pair_repl, ex2_intro/
 295 qed-.
 296
 297 lemma lfxs_sym: ∀R. lexs_frees_confluent (cext2 R) cfull →
 298                 (∀L1,L2,T1,T2. R L1 T1 T2 → R L2 T2 T1) →
 299                 ∀T. symmetric … (lfxs R T).
 300 #R #H1R #H2R #T #L1 #L2 * #f1 #Hf1 #HL12 elim (H1R … Hf1 … HL12) -Hf1
 301 /5 width=5 by sle_lexs_trans, lexs_sym, cext2_sym, ex2_intro/
 302 qed-.
 303
 304 (* Basic_2A1: uses: llpx_sn_co *)
 305 lemma lfxs_co: ∀R1,R2. (∀L,T1,T2. R1 L T1 T2 → R2 L T1 T2) →
 306                ∀L1,L2,T. L1 ⪤*[R1, T] L2 → L1 ⪤*[R2, T] L2.
 307 #R1 #R2 #HR #L1 #L2 #T * /5 width=7 by lexs_co, cext2_co, ex2_intro/
 308 qed-.
 309
 310 lemma lfxs_isid: ∀R1,R2,L1,L2,T1,T2.
 311                  (∀f. L1 ⊢ 𝐅*⦃T1⦄ ≡ f → 𝐈⦃f⦄) →
 312                  (∀f. 𝐈⦃f⦄ → L1 ⊢ 𝐅*⦃T2⦄ ≡ f) →
 313                  L1 ⪤*[R1, T1] L2 → L1 ⪤*[R2, T2] L2.
 314 #R1 #R2 #L1 #L2 #T1 #T2 #H1 #H2 *
 315 /4 width=7 by lexs_co_isid, ex2_intro/
 316 qed-.
 317
 318 lemma lfxs_unit_sn: ∀R1,R2,I,K1,L2.
 319                     K1.ⓤ{I} ⪤*[R1, #0] L2 → K1.ⓤ{I} ⪤*[R2, #0] L2.
 320 #R1 #R2 #I #K1 #L2 #H
 321 elim (lfxs_inv_zero_unit_sn … H) -H #f #K2 #Hf #HK12 #H destruct
 322 /3 width=7 by lfxs_unit, lexs_co_isid/
 323 qed-.
 324
 325 (* Basic_2A1: removed theorems 9:
 326               llpx_sn_skip llpx_sn_lref llpx_sn_free
 327               llpx_sn_fwd_lref
 328               llpx_sn_Y llpx_sn_ge_up llpx_sn_ge
 329               llpx_sn_fwd_drop_sn llpx_sn_fwd_drop_dx
 330 *)