matita/matita/contribs/lambdadelta/basic_2/static/lfxs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/relocation/rtmap_id.ma".
  16 include "basic_2/notation/relations/relationstar_4.ma".
  17 include "basic_2/grammar/ceq.ma".
  18 include "basic_2/relocation/lexs.ma".
  19 include "basic_2/static/frees.ma".
  20
  21 (* GENERIC EXTENSION ON REFERRED ENTRIES OF A CONTEXT-SENSITIVE REALTION ****)
  22
  23 definition lfxs (R) (T): relation lenv ≝
  24                 λL1,L2. ∃∃f. L1 ⊢ 𝐅*⦃T⦄ ≡ f & L1 ⦻*[R, cfull, f] L2.
  25
  26 interpretation "generic extension on referred entries (local environment)"
  27    'RelationStar R T L1 L2 = (lfxs R T L1 L2).
  28
  29 definition R_frees_confluent: predicate (relation3 lenv term term) ≝
  30                               λRN.
  31                               ∀f1,L,T1. L ⊢ 𝐅*⦃T1⦄ ≡ f1 → ∀T2. RN L T1 T2 →
  32                               ∃∃f2. L ⊢ 𝐅*⦃T2⦄ ≡ f2 & f2 ⊆ f1.
  33
  34 definition lexs_frees_confluent: relation (relation3 lenv term term) ≝
  35                                  λRN,RP.
  36                                  ∀f1,L1,T. L1 ⊢ 𝐅*⦃T⦄ ≡ f1 →
  37                                  ∀L2. L1 ⦻*[RN, RP, f1] L2 →
  38                                  ∃∃f2. L2 ⊢ 𝐅*⦃T⦄ ≡ f2 & f2 ⊆ f1.
  39
  40 definition R_confluent2_lfxs: relation4 (relation3 lenv term term)
  41                                         (relation3 lenv term term) … ≝
  42                               λR1,R2,RP1,RP2.
  43                               ∀L0,T0,T1. R1 L0 T0 T1 → ∀T2. R2 L0 T0 T2 →
  44                               ∀L1. L0 ⦻*[RP1, T0] L1 → ∀L2. L0 ⦻*[RP2, T0] L2 →
  45                               ∃∃T. R2 L1 T1 T & R1 L2 T2 T.
  46
  47 (* Basic properties ***********************************************************)
  48
  49 lemma lfxs_atom: ∀R,I. ⋆ ⦻*[R, ⓪{I}] ⋆.
  50 /3 width=3 by lexs_atom, frees_atom, ex2_intro/
  51 qed.
  52
  53 lemma lfxs_sort: ∀R,I,L1,L2,V1,V2,s.
  54                  L1 ⦻*[R, ⋆s] L2 → L1.ⓑ{I}V1 ⦻*[R, ⋆s] L2.ⓑ{I}V2.
  55 #R #I #L1 #L2 #V1 #V2 #s * /3 width=3 by lexs_push, frees_sort, ex2_intro/
  56 qed.
  57
  58 lemma lfxs_zero: ∀R,I,L1,L2,V1,V2. L1 ⦻*[R, V1] L2 →
  59                  R L1 V1 V2 → L1.ⓑ{I}V1 ⦻*[R, #0] L2.ⓑ{I}V2.
  60 #R #I #L1 #L2 #V1 #V2 * /3 width=3 by lexs_next, frees_zero, ex2_intro/
  61 qed.
  62
  63 lemma lfxs_lref: ∀R,I,L1,L2,V1,V2,i.
  64                  L1 ⦻*[R, #i] L2 → L1.ⓑ{I}V1 ⦻*[R, #⫯i] L2.ⓑ{I}V2.
  65 #R #I #L1 #L2 #V1 #V2 #i * /3 width=3 by lexs_push, frees_lref, ex2_intro/
  66 qed.
  67
  68 lemma lfxs_gref: ∀R,I,L1,L2,V1,V2,l.
  69                  L1 ⦻*[R, §l] L2 → L1.ⓑ{I}V1 ⦻*[R, §l] L2.ⓑ{I}V2.
  70 #R #I #L1 #L2 #V1 #V2 #l * /3 width=3 by lexs_push, frees_gref, ex2_intro/
  71 qed.
  72
  73 lemma lfxs_pair_repl_dx: ∀R,I,L1,L2,T,V,V1.
  74                          L1.ⓑ{I}V ⦻*[R, T] L2.ⓑ{I}V1 →
  75                          ∀V2. R L1 V V2 →
  76                          L1.ⓑ{I}V ⦻*[R, T] L2.ⓑ{I}V2.
  77 #R #I #L1 #L2 #T #V #V1 * #f #Hf #HL12 #V2 #HR
  78 /3 width=5 by lexs_pair_repl, ex2_intro/
  79 qed-.
  80
  81 lemma lfxs_co: ∀R1,R2. (∀L,T1,T2. R1 L T1 T2 → R2 L T1 T2) →
  82                ∀L1,L2,T. L1 ⦻*[R1, T] L2 → L1 ⦻*[R2, T] L2.
  83 #R1 #R2 #HR #L1 #L2 #T * /4 width=7 by lexs_co, ex2_intro/
  84 qed-.
  85
  86 (* Basic inversion lemmas ***************************************************)
  87
  88 lemma lfxs_inv_atom_sn: ∀R,I,Y2. ⋆ ⦻*[R, ⓪{I}] Y2 → Y2 = ⋆.
  89 #R #I #Y2 * /2 width=4 by lexs_inv_atom1/
  90 qed-.
  91
  92 lemma lfxs_inv_atom_dx: ∀R,I,Y1. Y1 ⦻*[R, ⓪{I}] ⋆ → Y1 = ⋆.
  93 #R #I #Y1 * /2 width=4 by lexs_inv_atom2/
  94 qed-.
  95
  96 lemma lfxs_inv_sort: ∀R,Y1,Y2,s. Y1 ⦻*[R, ⋆s] Y2 →
  97                      (Y1 = ⋆ ∧ Y2 = ⋆) ∨
  98                      ∃∃I,L1,L2,V1,V2. L1 ⦻*[R, ⋆s] L2 &
  99                                       Y1 = L1.ⓑ{I}V1 & Y2 = L2.ⓑ{I}V2.
 100 #R * [ | #Y1 #I #V1 ] #Y2 #s * #f #H1 #H2
 101 [ lapply (lexs_inv_atom1 … H2) -H2 /3 width=1 by or_introl, conj/
 102 | lapply (frees_inv_sort … H1) -H1 #Hf
 103   elim (isid_inv_gen … Hf) -Hf #g #Hg #H destruct
 104   elim (lexs_inv_push1 … H2) -H2 #L2 #V2 #H12 #_ #H destruct
 105   /5 width=8 by frees_sort_gen, ex3_5_intro, ex2_intro, or_intror/
 106 ]
 107 qed-.
 108
 109 lemma lfxs_inv_zero: ∀R,Y1,Y2. Y1 ⦻*[R, #0] Y2 →
 110                      (Y1 = ⋆ ∧ Y2 = ⋆) ∨
 111                      ∃∃I,L1,L2,V1,V2. L1 ⦻*[R, V1] L2 & R L1 V1 V2 &
 112                                       Y1 = L1.ⓑ{I}V1 & Y2 = L2.ⓑ{I}V2.
 113 #R #Y1 #Y2 * #f #H1 #H2 elim (frees_inv_zero … H1) -H1 *
 114 [ #H #_ lapply (lexs_inv_atom1_aux … H2 H) -H2 /3 width=1 by or_introl, conj/
 115 | #I1 #L1 #V1 #g #HV1 #HY1 #Hg elim (lexs_inv_next1_aux … H2 … HY1 Hg) -H2 -Hg
 116   /4 width=9 by ex4_5_intro, ex2_intro, or_intror/
 117 ]
 118 qed-.
 119
 120 lemma lfxs_inv_lref: ∀R,Y1,Y2,i. Y1 ⦻*[R, #⫯i] Y2 →
 121                      (Y1 = ⋆ ∧ Y2 = ⋆) ∨
 122                      ∃∃I,L1,L2,V1,V2. L1 ⦻*[R, #i] L2 &
 123                                       Y1 = L1.ⓑ{I}V1 & Y2 = L2.ⓑ{I}V2.
 124 #R #Y1 #Y2 #i * #f #H1 #H2 elim (frees_inv_lref … H1) -H1 *
 125 [ #H #_ lapply (lexs_inv_atom1_aux … H2 H) -H2 /3 width=1 by or_introl, conj/
 126 | #I1 #L1 #V1 #g #HV1 #HY1 #Hg elim (lexs_inv_push1_aux … H2 … HY1 Hg) -H2 -Hg
 127   /4 width=8 by ex3_5_intro, ex2_intro, or_intror/
 128 ]
 129 qed-.
 130
 131 lemma lfxs_inv_gref: ∀R,Y1,Y2,l. Y1 ⦻*[R, §l] Y2 →
 132                      (Y1 = ⋆ ∧ Y2 = ⋆) ∨
 133                      ∃∃I,L1,L2,V1,V2. L1 ⦻*[R, §l] L2 &
 134                                       Y1 = L1.ⓑ{I}V1 & Y2 = L2.ⓑ{I}V2.
 135 #R * [ | #Y1 #I #V1 ] #Y2 #l * #f #H1 #H2
 136 [ lapply (lexs_inv_atom1 … H2) -H2 /3 width=1 by or_introl, conj/
 137 | lapply (frees_inv_gref … H1) -H1 #Hf
 138   elim (isid_inv_gen … Hf) -Hf #g #Hg #H destruct
 139   elim (lexs_inv_push1 … H2) -H2 #L2 #V2 #H12 #_ #H destruct
 140   /5 width=8 by frees_gref_gen, ex3_5_intro, ex2_intro, or_intror/
 141 ]
 142 qed-.
 143
 144 lemma lfxs_inv_bind: ∀R,p,I,L1,L2,V1,V2,T. L1 ⦻*[R, ⓑ{p,I}V1.T] L2 → R L1 V1 V2 →
 145                      L1 ⦻*[R, V1] L2 ∧ L1.ⓑ{I}V1 ⦻*[R, T] L2.ⓑ{I}V2.
 146 #R #p #I #L1 #L2 #V1 #V2 #T * #f #Hf #HL #HV elim (frees_inv_bind … Hf) -Hf
 147 /6 width=6 by sle_lexs_trans, lexs_inv_tl, sor_inv_sle_dx, sor_inv_sle_sn, ex2_intro, conj/
 148 qed-.
 149
 150 lemma lfxs_inv_flat: ∀R,I,L1,L2,V,T. L1 ⦻*[R, ⓕ{I}V.T] L2 →
 151                      L1 ⦻*[R, V] L2 ∧ L1 ⦻*[R, T] L2.
 152 #R #I #L1 #L2 #V #T * #f #Hf #HL elim (frees_inv_flat … Hf) -Hf
 153 /5 width=6 by sle_lexs_trans, sor_inv_sle_dx, sor_inv_sle_sn, ex2_intro, conj/
 154 qed-.
 155
 156 (* Advanced inversion lemmas ************************************************)
 157
 158 lemma lfxs_inv_sort_pair_sn: ∀R,I,Y2,L1,V1,s. L1.ⓑ{I}V1 ⦻*[R, ⋆s] Y2 →
 159                              ∃∃L2,V2. L1 ⦻*[R, ⋆s] L2 & Y2 = L2.ⓑ{I}V2.
 160 #R #I #Y2 #L1 #V1 #s #H elim (lfxs_inv_sort … H) -H *
 161 [ #H destruct
 162 | #J #Y1 #L2 #X1 #V2 #Hs #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 163 ]
 164 qed-.
 165
 166 lemma lfxs_inv_sort_pair_dx: ∀R,I,Y1,L2,V2,s. Y1 ⦻*[R, ⋆s] L2.ⓑ{I}V2 →
 167                              ∃∃L1,V1. L1 ⦻*[R, ⋆s] L2 & Y1 = L1.ⓑ{I}V1.
 168 #R #I #Y1 #L2 #V2 #s #H elim (lfxs_inv_sort … H) -H *
 169 [ #_ #H destruct
 170 | #J #L1 #Y2 #V1 #X2 #Hs #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 171 ]
 172 qed-.
 173
 174 lemma lfxs_inv_zero_pair_sn: ∀R,I,Y2,L1,V1. L1.ⓑ{I}V1 ⦻*[R, #0] Y2 →
 175                              ∃∃L2,V2. L1 ⦻*[R, V1] L2 & R L1 V1 V2 &
 176                                       Y2 = L2.ⓑ{I}V2.
 177 #R #I #Y2 #L1 #V1 #H elim (lfxs_inv_zero … H) -H *
 178 [ #H destruct
 179 | #J #Y1 #L2 #X1 #V2 #HV1 #HV12 #H1 #H2 destruct
 180   /2 width=5 by ex3_2_intro/
 181 ]
 182 qed-.
 183
 184 lemma lfxs_inv_zero_pair_dx: ∀R,I,Y1,L2,V2. Y1 ⦻*[R, #0] L2.ⓑ{I}V2 →
 185                              ∃∃L1,V1. L1 ⦻*[R, V1] L2 & R L1 V1 V2 &
 186                                       Y1 = L1.ⓑ{I}V1.
 187 #R #I #Y1 #L2 #V2 #H elim (lfxs_inv_zero … H) -H *
 188 [ #_ #H destruct
 189 | #J #L1 #Y2 #V1 #X2 #HV1 #HV12 #H1 #H2 destruct
 190   /2 width=5 by ex3_2_intro/
 191 ]
 192 qed-.
 193
 194 lemma lfxs_inv_lref_pair_sn: ∀R,I,Y2,L1,V1,i. L1.ⓑ{I}V1 ⦻*[R, #⫯i] Y2 →
 195                              ∃∃L2,V2. L1 ⦻*[R, #i] L2 & Y2 = L2.ⓑ{I}V2.
 196 #R #I #Y2 #L1 #V1 #i #H elim (lfxs_inv_lref … H) -H *
 197 [ #H destruct
 198 | #J #Y1 #L2 #X1 #V2 #Hi #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 199 ]
 200 qed-.
 201
 202 lemma lfxs_inv_lref_pair_dx: ∀R,I,Y1,L2,V2,i. Y1 ⦻*[R, #⫯i] L2.ⓑ{I}V2 →
 203                              ∃∃L1,V1. L1 ⦻*[R, #i] L2 & Y1 = L1.ⓑ{I}V1.
 204 #R #I #Y1 #L2 #V2 #i #H elim (lfxs_inv_lref … H) -H *
 205 [ #_ #H destruct
 206 | #J #L1 #Y2 #V1 #X2 #Hi #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 207 ]
 208 qed-.
 209
 210 lemma lfxs_inv_gref_pair_sn: ∀R,I,Y2,L1,V1,l. L1.ⓑ{I}V1 ⦻*[R, §l] Y2 →
 211                              ∃∃L2,V2. L1 ⦻*[R, §l] L2 & Y2 = L2.ⓑ{I}V2.
 212 #R #I #Y2 #L1 #V1 #l #H elim (lfxs_inv_gref … H) -H *
 213 [ #H destruct
 214 | #J #Y1 #L2 #X1 #V2 #Hl #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 215 ]
 216 qed-.
 217
 218 lemma lfxs_inv_gref_pair_dx: ∀R,I,Y1,L2,V2,l. Y1 ⦻*[R, §l] L2.ⓑ{I}V2 →
 219                              ∃∃L1,V1. L1 ⦻*[R, §l] L2 & Y1 = L1.ⓑ{I}V1.
 220 #R #I #Y1 #L2 #V2 #l #H elim (lfxs_inv_gref … H) -H *
 221 [ #_ #H destruct
 222 | #J #L1 #Y2 #V1 #X2 #Hl #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 223 ]
 224 qed-.
 225
 226 (* Basic forward lemmas *****************************************************)
 227
 228 lemma lfxs_fwd_bind_sn: ∀R,p,I,L1,L2,V,T. L1 ⦻*[R, ⓑ{p,I}V.T] L2 → L1 ⦻*[R, V] L2.
 229 #R #p #I #L1 #L2 #V #T * #f #Hf #HL elim (frees_inv_bind … Hf) -Hf
 230 /4 width=6 by sle_lexs_trans, sor_inv_sle_sn, ex2_intro/
 231 qed-.
 232
 233 lemma lfxs_fwd_bind_dx: ∀R,p,I,L1,L2,V1,V2,T. L1 ⦻*[R, ⓑ{p,I}V1.T] L2 →
 234                         R L1 V1 V2 → L1.ⓑ{I}V1 ⦻*[R, T] L2.ⓑ{I}V2.
 235 #R #p #I #L1 #L2 #V1 #V2 #T #H #HV elim (lfxs_inv_bind … H HV) -H -HV //
 236 qed-.
 237
 238 lemma lfxs_fwd_flat_sn: ∀R,I,L1,L2,V,T. L1 ⦻*[R, ⓕ{I}V.T] L2 → L1 ⦻*[R, V] L2.
 239 #R #I #L1 #L2 #V #T #H elim (lfxs_inv_flat … H) -H //
 240 qed-.
 241
 242 lemma lfxs_fwd_flat_dx: ∀R,I,L1,L2,V,T. L1 ⦻*[R, ⓕ{I}V.T] L2 → L1 ⦻*[R, T] L2.
 243 #R #I #L1 #L2 #V #T #H elim (lfxs_inv_flat … H) -H //
 244 qed-.
 245
 246 lemma lfxs_fwd_pair_sn: ∀R,I,L1,L2,V,T. L1 ⦻*[R, ②{I}V.T] L2 → L1 ⦻*[R, V] L2.
 247 #R * /2 width=4 by lfxs_fwd_flat_sn, lfxs_fwd_bind_sn/
 248 qed-.
 249
 250 (* Basic_2A1: removed theorems 24:
 251               llpx_sn_sort llpx_sn_skip llpx_sn_lref llpx_sn_free llpx_sn_gref
 252               llpx_sn_bind llpx_sn_flat
 253               llpx_sn_inv_bind llpx_sn_inv_flat
 254               llpx_sn_fwd_lref llpx_sn_fwd_pair_sn llpx_sn_fwd_length
 255               llpx_sn_fwd_bind_sn llpx_sn_fwd_bind_dx llpx_sn_fwd_flat_sn llpx_sn_fwd_flat_dx
 256               llpx_sn_refl llpx_sn_Y llpx_sn_bind_O llpx_sn_ge_up llpx_sn_ge llpx_sn_co
 257               llpx_sn_fwd_drop_sn llpx_sn_fwd_drop_dx
 258 *)