matita/matita/contribs/lambdadelta/basic_2/static/lfxs_lfxs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/relocation/lexs_lexs.ma".
  16 include "basic_2/static/frees_fqup.ma".
  17 include "basic_2/static/frees_frees.ma".
  18 include "basic_2/static/lfxs.ma".
  19
  20 (* GENERIC EXTENSION ON REFERRED ENTRIES OF A CONTEXT-SENSITIVE REALTION ****)
  21
  22 (* Advanced properties ******************************************************)
  23
  24 lemma lfxs_pair_sn_split: ∀R1,R2. (∀L. reflexive … (R1 L)) → (∀L. reflexive … (R2 L)) →
  25                           lexs_frees_confluent … R1 cfull →
  26                           ∀L1,L2,V. L1 ⦻*[R1, V] L2 → ∀I,T.
  27                           ∃∃L. L1 ⦻*[R1, ②{I}V.T] L & L ⦻*[R2, V] L2.
  28 #R1 #R2 #HR1 #HR2 #HR #L1 #L2 #V * #f #Hf #HL12 * [ #p ] #I #T
  29 [ elim (frees_total L1 (ⓑ{p,I}V.T)) #g #Hg
  30   elim (frees_inv_bind … Hg) #y1 #y2 #H #_ #Hy
  31 | elim (frees_total L1 (ⓕ{I}V.T)) #g #Hg
  32   elim (frees_inv_flat … Hg) #y1 #y2 #H #_ #Hy
  33 ]
  34 lapply(frees_mono … H … Hf) -H #H1
  35 lapply (sor_eq_repl_back1 … Hy … H1) -y1 #Hy
  36 lapply (sor_inv_sle_sn … Hy) -y2 #Hfg
  37 elim (lexs_sle_split … HR1 HR2 … HL12 … Hfg) -HL12 #L #HL1 #HL2
  38 lapply (sle_lexs_trans … HL1 … Hfg) // #H
  39 elim (HR … Hf … H) -HR -Hf -H
  40 /4 width=7 by sle_lexs_trans, ex2_intro/
  41 qed-.
  42
  43 lemma lfxs_flat_dx_split: ∀R1,R2. (∀L. reflexive … (R1 L)) → (∀L. reflexive … (R2 L)) →
  44                           lexs_frees_confluent … R1 cfull →
  45                           ∀L1,L2,T. L1 ⦻*[R1, T] L2 → ∀I,V.
  46                           ∃∃L. L1 ⦻*[R1, ⓕ{I}V.T] L & L ⦻*[R2, T] L2.
  47 #R1 #R2 #HR1 #HR2 #HR #L1 #L2 #T * #f #Hf #HL12 #I #V
  48 elim (frees_total L1 (ⓕ{I}V.T)) #g #Hg
  49 elim (frees_inv_flat … Hg) #y1 #y2 #_ #H #Hy
  50 lapply(frees_mono … H … Hf) -H #H2
  51 lapply (sor_eq_repl_back2 … Hy … H2) -y2 #Hy
  52 lapply (sor_inv_sle_dx … Hy) -y1 #Hfg
  53 elim (lexs_sle_split … HR1 HR2 … HL12 … Hfg) -HL12 #L #HL1 #HL2
  54 lapply (sle_lexs_trans … HL1 … Hfg) // #H
  55 elim (HR … Hf … H) -HR -Hf -H
  56 /4 width=7 by sle_lexs_trans, ex2_intro/
  57 qed-.
  58
  59 (* Main properties **********************************************************)
  60
  61 theorem lfxs_bind: ∀R,p,I,L1,L2,V1,V2,T.
  62                    L1 ⦻*[R, V1] L2 → L1.ⓑ{I}V1 ⦻*[R, T] L2.ⓑ{I}V2 →
  63                    L1 ⦻*[R, ⓑ{p,I}V1.T] L2.
  64 #R #p #I #L1 #L2 #V1 #V2 #T * #f1 #HV #Hf1 * #f2 #HT #Hf2
  65 elim (lexs_fwd_pair … Hf2) -Hf2 #Hf2 #_ elim (sor_isfin_ex f1 (⫱f2))
  66 /3 width=7 by frees_fwd_isfin, frees_bind, lexs_join, isfin_tl, ex2_intro/
  67 qed.
  68
  69 theorem lfxs_flat: ∀R,I,L1,L2,V,T.
  70                    L1 ⦻*[R, V] L2 → L1 ⦻*[R, T] L2 →
  71                    L1 ⦻*[R, ⓕ{I}V.T] L2.
  72 #R #I #L1 #L2 #V #T * #f1 #HV #Hf1 * #f2 #HT #Hf2 elim (sor_isfin_ex f1 f2)
  73 /3 width=7 by frees_fwd_isfin, frees_flat, lexs_join, ex2_intro/
  74 qed.
  75
  76 theorem lfxs_conf: ∀R1,R2.
  77                    lexs_frees_confluent R1 cfull →
  78                    lexs_frees_confluent R2 cfull →
  79                    R_confluent2_lfxs R1 R2 R1 R2 →
  80                    ∀T. confluent2 … (lfxs R1 T) (lfxs R2 T).
  81 #R1 #R2 #HR1 #HR2 #HR12 #T #L0 #L1 * #f1 #Hf1 #HL01 #L2 * #f #Hf #HL02
  82 lapply (frees_mono … Hf1 … Hf) -Hf1 #Hf12
  83 lapply (lexs_eq_repl_back … HL01 … Hf12) -f1 #HL01
  84 elim (lexs_conf … HL01 … HL02) /2 width=3 by ex2_intro/ [ | -HL01 -HL02 ]
  85 [ #L #HL1 #HL2
  86   elim (HR1 … Hf … HL01) -HL01 #f1 #Hf1 #H1
  87   elim (HR2 … Hf … HL02) -HL02 #f2 #Hf2 #H2
  88   lapply (sle_lexs_trans … HL1 … H1) // -HL1 -H1 #HL1
  89   lapply (sle_lexs_trans … HL2 … H2) // -HL2 -H2 #HL2
  90   /3 width=5 by ex2_intro/
  91 | #g #I #K0 #V0 #n #HLK0 #Hgf #V1 #HV01 #V2 #HV02 #K1 #HK01 #K2 #HK02
  92   elim (frees_drops_next … Hf … HLK0 … Hgf) -Hf -HLK0 -Hgf #g0 #Hg0 #H0
  93   lapply (sle_lexs_trans … HK01 … H0) // -HK01 #HK01
  94   lapply (sle_lexs_trans … HK02 … H0) // -HK02 #HK02
  95   elim (HR12 … HV01 … HV02 K1 … K2) /2 width=3 by ex2_intro/
  96 ]
  97 qed-.