matita/matita/contribs/lambdadelta/basic_2/static/lfxs_lfxs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/relocation/lexs_lexs.ma".
  16 include "basic_2/static/frees_fqup.ma".
  17 include "basic_2/static/frees_frees.ma".
  18 include "basic_2/static/lfxs.ma".
  19
  20 (* GENERIC EXTENSION ON REFERRED ENTRIES OF A CONTEXT-SENSITIVE REALTION ****)
  21
  22 (* Advanced properties ******************************************************)
  23
  24 lemma lfxs_inv_frees: ∀R,L1,L2,T. L1 ⦻*[R, T] L2 →
  25                       ∀f. L1 ⊢ 𝐅*⦃T⦄ ≡ f → L1 ⦻*[R, cfull, f] L2.
  26 #R #L1 #L2 #T * /3 width=6 by frees_mono, lexs_eq_repl_back/
  27 qed-.
  28
  29 lemma lfxs_dec: ∀R. (∀L,T1,T2. Decidable (R L T1 T2)) →
  30                 ∀L1,L2,T. Decidable (L1 ⦻*[R, T] L2).
  31 #R #HR #L1 #L2 #T
  32 elim (frees_total L1 T) #f #Hf
  33 elim (lexs_dec R cfull HR … L1 L2 f)
  34 /4 width=3 by lfxs_inv_frees, cfull_dec, ex2_intro, or_intror, or_introl/
  35 qed-.
  36
  37 lemma lfxs_pair_sn_split: ∀R1,R2. (∀L. reflexive … (R1 L)) → (∀L. reflexive … (R2 L)) →
  38                           lexs_frees_confluent … R1 cfull →
  39                           ∀L1,L2,V. L1 ⦻*[R1, V] L2 → ∀I,T.
  40                           ∃∃L. L1 ⦻*[R1, ②{I}V.T] L & L ⦻*[R2, V] L2.
  41 #R1 #R2 #HR1 #HR2 #HR #L1 #L2 #V * #f #Hf #HL12 * [ #p ] #I #T
  42 [ elim (frees_total L1 (ⓑ{p,I}V.T)) #g #Hg
  43   elim (frees_inv_bind … Hg) #y1 #y2 #H #_ #Hy
  44 | elim (frees_total L1 (ⓕ{I}V.T)) #g #Hg
  45   elim (frees_inv_flat … Hg) #y1 #y2 #H #_ #Hy
  46 ]
  47 lapply(frees_mono … H … Hf) -H #H1
  48 lapply (sor_eq_repl_back1 … Hy … H1) -y1 #Hy
  49 lapply (sor_inv_sle_sn … Hy) -y2 #Hfg
  50 elim (lexs_sle_split … HR1 HR2 … HL12 … Hfg) -HL12 #L #HL1 #HL2
  51 lapply (sle_lexs_trans … HL1 … Hfg) // #H
  52 elim (HR … Hf … H) -HR -Hf -H
  53 /4 width=7 by sle_lexs_trans, ex2_intro/
  54 qed-.
  55
  56 lemma lfxs_flat_dx_split: ∀R1,R2. (∀L. reflexive … (R1 L)) → (∀L. reflexive … (R2 L)) →
  57                           lexs_frees_confluent … R1 cfull →
  58                           ∀L1,L2,T. L1 ⦻*[R1, T] L2 → ∀I,V.
  59                           ∃∃L. L1 ⦻*[R1, ⓕ{I}V.T] L & L ⦻*[R2, T] L2.
  60 #R1 #R2 #HR1 #HR2 #HR #L1 #L2 #T * #f #Hf #HL12 #I #V
  61 elim (frees_total L1 (ⓕ{I}V.T)) #g #Hg
  62 elim (frees_inv_flat … Hg) #y1 #y2 #_ #H #Hy
  63 lapply(frees_mono … H … Hf) -H #H2
  64 lapply (sor_eq_repl_back2 … Hy … H2) -y2 #Hy
  65 lapply (sor_inv_sle_dx … Hy) -y1 #Hfg
  66 elim (lexs_sle_split … HR1 HR2 … HL12 … Hfg) -HL12 #L #HL1 #HL2
  67 lapply (sle_lexs_trans … HL1 … Hfg) // #H
  68 elim (HR … Hf … H) -HR -Hf -H
  69 /4 width=7 by sle_lexs_trans, ex2_intro/
  70 qed-.
  71
  72 (* Main properties **********************************************************)
  73
  74 theorem lfxs_bind: ∀R,p,I,L1,L2,V1,V2,T.
  75                    L1 ⦻*[R, V1] L2 → L1.ⓑ{I}V1 ⦻*[R, T] L2.ⓑ{I}V2 →
  76                    L1 ⦻*[R, ⓑ{p,I}V1.T] L2.
  77 #R #p #I #L1 #L2 #V1 #V2 #T * #f1 #HV #Hf1 * #f2 #HT #Hf2
  78 elim (lexs_fwd_pair … Hf2) -Hf2 #Hf2 #_ elim (sor_isfin_ex f1 (⫱f2))
  79 /3 width=7 by frees_fwd_isfin, frees_bind, lexs_join, isfin_tl, ex2_intro/
  80 qed.
  81
  82 theorem lfxs_flat: ∀R,I,L1,L2,V,T.
  83                    L1 ⦻*[R, V] L2 → L1 ⦻*[R, T] L2 →
  84                    L1 ⦻*[R, ⓕ{I}V.T] L2.
  85 #R #I #L1 #L2 #V #T * #f1 #HV #Hf1 * #f2 #HT #Hf2 elim (sor_isfin_ex f1 f2)
  86 /3 width=7 by frees_fwd_isfin, frees_flat, lexs_join, ex2_intro/
  87 qed.
  88
  89 theorem lfxs_conf: ∀R1,R2.
  90                    lexs_frees_confluent R1 cfull →
  91                    lexs_frees_confluent R2 cfull →
  92                    R_confluent2_lfxs R1 R2 R1 R2 →
  93                    ∀T. confluent2 … (lfxs R1 T) (lfxs R2 T).
  94 #R1 #R2 #HR1 #HR2 #HR12 #T #L0 #L1 * #f1 #Hf1 #HL01 #L2 * #f #Hf #HL02
  95 lapply (frees_mono … Hf1 … Hf) -Hf1 #Hf12
  96 lapply (lexs_eq_repl_back … HL01 … Hf12) -f1 #HL01
  97 elim (lexs_conf … HL01 … HL02) /2 width=3 by ex2_intro/ [ | -HL01 -HL02 ]
  98 [ #L #HL1 #HL2
  99   elim (HR1 … Hf … HL01) -HL01 #f1 #Hf1 #H1
 100   elim (HR2 … Hf … HL02) -HL02 #f2 #Hf2 #H2
 101   lapply (sle_lexs_trans … HL1 … H1) // -HL1 -H1 #HL1
 102   lapply (sle_lexs_trans … HL2 … H2) // -HL2 -H2 #HL2
 103   /3 width=5 by ex2_intro/
 104 | #g #I #K0 #V0 #n #HLK0 #Hgf #V1 #HV01 #V2 #HV02 #K1 #HK01 #K2 #HK02
 105   elim (frees_drops_next … Hf … HLK0 … Hgf) -Hf -HLK0 -Hgf #g0 #Hg0 #H0
 106   lapply (sle_lexs_trans … HK01 … H0) // -HK01 #HK01
 107   lapply (sle_lexs_trans … HK02 … H0) // -HK02 #HK02
 108   elim (HR12 … HV01 … HV02 K1 … K2) /2 width=3 by ex2_intro/
 109 ]
 110 qed-.